let F be Field; :: thesis: for E being FieldExtension of F
for a being Element of E holds card (Conj a) = Index (Aut a)

let E be FieldExtension of F; :: thesis: for a being Element of E holds card (Conj a) = Index (Aut a)
let a be Element of E; :: thesis: card (Conj a) = Index (Aut a)
set H = Aut a;
set G = Aut (E,F);
H: ( Auts a = { f where f is F -fixing Automorphism of E : f . a = a } & the carrier of (Aut a) = Auts a ) by lemZ2;
defpred S1[ object , object ] means for f being Element of the carrier of (Aut (E,F)) st $1 = f . a holds
$2 = f * (Aut a);
A: now :: thesis: for x being object st x in Conj a holds
ex y being object st
( y in Left_Cosets (Aut a) & S1[x,y] )
let x be object ; :: thesis: ( x in Conj a implies ex y being object st
( y in Left_Cosets (Aut a) & S1[x,y] ) )

assume x in Conj a ; :: thesis: ex y being object st
( y in Left_Cosets (Aut a) & S1[x,y] )

then consider f being Element of the carrier of (Aut (E,F)) such that
B: x = f . a ;
A1: ( f is one-to-one & rng f = the carrier of E ) by FUNCT_2:def 3;
reconsider f1 = f as F -fixing Automorphism of E ;
thus ex y being object st
( y in Left_Cosets (Aut a) & S1[x,y] ) :: thesis: verum
proof
take y = f * (Aut a); :: thesis: ( y in Left_Cosets (Aut a) & S1[x,y] )
thus y in Left_Cosets (Aut a) by GROUP_2:def 15; :: thesis: S1[x,y]
now :: thesis: for g being Element of the carrier of (Aut (E,F)) st x = g . a holds
y = g * (Aut a)
let g be Element of the carrier of (Aut (E,F)); :: thesis: ( x = g . a implies y = g * (Aut a) )
reconsider g1 = g as F -fixing Automorphism of E ;
f " is Element of the carrier of (Aut (E,F)) ;
then reconsider ff = f " as F -fixing Automorphism of E ;
I: ( [(f "),g] in [:(Auts (E,F)),(Auts (E,F)):] & [(f "),f] in [:(Auts (E,F)),(Auts (E,F)):] ) by ZFMISC_1:def 2;
id E = 1_ (Aut E) by Th1
.= 1_ (Aut (E,F)) by GROUP_2:44
.= (f ") * f by GROUP_1:def 5
.= (AutComp E) . ((f "),f) by I, FUNCT_1:49
.= ff * f1 by defMult ;
then f " = f1 " by A1, FUNCT_2:30;
then A3: (f1 ") * g1 = (AutComp E) . ((f "),g) by defMult
.= (f ") * g by I, FUNCT_1:49 ;
assume x = g . a ; :: thesis: y = g * (Aut a)
then ((f1 ") * g1) . a = (f1 ") . (f1 . a) by B, FUNCT_2:15
.= a by FUNCT_2:26 ;
then (f ") * g in Aut a by H, A3;
hence y = g * (Aut a) by GROUP_2:114; :: thesis: verum
end;
hence S1[x,y] ; :: thesis: verum
end;
end;
consider h being Function of (Conj a),(Left_Cosets (Aut a)) such that
B: for x being object st x in Conj a holds
S1[x,h . x] from FUNCT_2:sch 1(A);
C: dom h = Conj a by FUNCT_2:def 1;
now :: thesis: for x1, x2 being object st x1 in Conj a & x2 in Conj a & h . x1 = h . x2 holds
x1 = x2
let x1, x2 be object ; :: thesis: ( x1 in Conj a & x2 in Conj a & h . x1 = h . x2 implies x1 = x2 )
assume C0: ( x1 in Conj a & x2 in Conj a & h . x1 = h . x2 ) ; :: thesis: x1 = x2
then consider f1 being Element of the carrier of (Aut (E,F)) such that
C1: x1 = f1 . a ;
consider f2 being Element of the carrier of (Aut (E,F)) such that
C2: x2 = f2 . a by C0;
f1 * (Aut a) = h . (f2 . a) by C0, C1, C2, B
.= f2 * (Aut a) by C0, C2, B ;
then consider g being Element of (Aut (E,F)) such that
C3: ( f2 = f1 * g & g in Aut a ) by GROUP_2:103, GROUP_2:108;
g in Auts a by C3;
then g in { f where f is F -fixing Automorphism of E : f . a = a } by lemZ2;
then consider g2 being F -fixing Automorphism of E such that
C5: ( g2 = g & g2 . a = a ) ;
( f1 in Auts (E,F) & g2 in Auts (E,F) ) ;
then [f1,g2] in [:(Auts (E,F)),(Auts (E,F)):] by ZFMISC_1:def 2;
then f2 = (AutComp E) . (f1,g2) by C3, C5, FUNCT_1:49
.= f1 * g2 by defMult ;
hence x1 = x2 by C1, C2, C5, FUNCT_2:15; :: thesis: verum
end;
then h is one-to-one by FUNCT_2:19;
then D: card (dom h) = card (rng h) by CARD_1:70;
rng h = Left_Cosets (Aut a)
proof
D1: rng h c= Left_Cosets (Aut a) by RELAT_1:def 19;
now :: thesis: for o being object st o in Left_Cosets (Aut a) holds
o in rng h
let o be object ; :: thesis: ( o in Left_Cosets (Aut a) implies o in rng h )
assume o in Left_Cosets (Aut a) ; :: thesis: o in rng h
then consider g being Element of the carrier of (Aut (E,F)) such that
D2: o = g * (Aut a) by GROUP_2:def 15;
D3: g . a in Conj a ;
consider g1 being Element of the carrier of (Aut (E,F)) such that
D4: g . a = g1 . a ;
h . (g1 . a) = g * (Aut a) by B, D3, D4;
hence o in rng h by C, D4, D3, D2, FUNCT_1:def 3; :: thesis: verum
end;
then Left_Cosets (Aut a) c= rng h ;
hence rng h = Left_Cosets (Aut a) by D1, XBOOLE_0:def 10; :: thesis: verum
end;
hence card (Conj a) = Index (Aut a) by C, D, GROUP_2:def 17; :: thesis: verum