set G = Aut S;
ex e being Element of (Aut S) st
for h being Element of (Aut S) holds
( h * e = h & e * h = h & ex g being Element of (Aut S) st
( h * g = e & g * h = e ) )
proof
reconsider e = id E as Element of the carrier of (Aut S) by lemZ1;
take e ; :: thesis: for h being Element of (Aut S) holds
( h * e = h & e * h = h & ex g being Element of (Aut S) st
( h * g = e & g * h = e ) )

now :: thesis: for h being Element of the carrier of (Aut S) holds
( h * e = h & e * h = h & ex g being Element of (Aut S) st
( h * g = e & g * h = e ) )
let h be Element of the carrier of (Aut S); :: thesis: ( h * e = h & e * h = h & ex g being Element of (Aut S) st
( h * g = e & g * h = e ) )

h in { f where f is F -fixing Automorphism of E : f .: S = S } ;
then consider h1 being F -fixing Automorphism of E such that
A: ( h1 = h & h1 .: S = S ) ;
J: Auts S c= Auts (E,F) ;
H: [:(Auts S),(Auts S):] c= [:(Auts (E,F)),(Auts (E,F)):] by ZFMISC_1:96;
K: Auts (E,F) c= Auts E ;
B: ( [h,e] in [:(Auts S),(Auts S):] & [e,h] in [:(Auts S),(Auts S):] ) by ZFMISC_1:def 2;
reconsider h3 = h1 as Automorphism of E ;
id E in Auts E ;
then reconsider h2 = h, e2 = id E as Element of the carrier of (Aut E) by J, K;
thus h * e = (AutComp (E,F)) . (h,e) by B, FUNCT_1:49
.= (AutComp E) . (h2,e2) by B, H, FUNCT_1:49
.= h3 * (id E) by A, defMult
.= h by A, FUNCT_2:17 ; :: thesis: ( e * h = h & ex g being Element of (Aut S) st
( h * g = e & g * h = e ) )

thus e * h = (AutComp (E,F)) . (e,h) by B, FUNCT_1:49
.= (AutComp E) . (e2,h2) by B, H, FUNCT_1:49
.= (id E) * h3 by A, defMult
.= h by A, FUNCT_2:17 ; :: thesis: ex g being Element of (Aut S) st
( h * g = e & g * h = e )

thus ex g being Element of (Aut S) st
( h * g = e & g * h = e ) :: thesis: verum
proof
F: ( dom (h1 | S) = S & rng (h1 | S) = S ) by A, lemZ3;
E: now :: thesis: for o being object st o in S holds
o in (h1 ") .: S
let o be object ; :: thesis: ( o in S implies o in (h1 ") .: S )
assume o in S ; :: thesis: o in (h1 ") .: S
then reconsider y = o as Element of S ;
E2: dom (h1 ") = the carrier of E by FUNCT_2:def 1;
E4: dom h1 = the carrier of E by FUNCT_2:def 1;
then E3: h1 . y in S by F, FUNCT_1:50;
(h1 ") . (h1 . y) = y by E4, FUNCT_1:34;
hence o in (h1 ") .: S by E2, E3, FUNCT_1:def 6; :: thesis: verum
end;
now :: thesis: for o being object st o in (h1 ") .: S holds
o in S
let o be object ; :: thesis: ( o in (h1 ") .: S implies o in S )
assume o in (h1 ") .: S ; :: thesis: o in S
then consider x being object such that
E1: ( x in dom (h1 ") & x in S & o = (h1 ") . x ) by FUNCT_1:def 6;
E2: x in dom ((h1 ") | S) by E1, RELAT_1:57;
then ((h1 ") | S) . x = (h1 ") . x by FUNCT_1:47;
then o in rng ((h1 ") | S) by E1, E2, FUNCT_1:def 3;
hence o in S by A, lemZ3; :: thesis: verum
end;
then (h1 ") .: S = S by E, TARSKI:2;
then h1 " in { f where f is F -fixing Automorphism of E : f .: S = S } ;
then reconsider g = h1 " as Element of the carrier of (Aut S) ;
take g ; :: thesis: ( h * g = e & g * h = e )
R: rng h1 = the carrier of E by FUNCT_2:def 3;
S: ( [h,g] in [:(Auts S),(Auts S):] & [g,h] in [:(Auts S),(Auts S):] ) by ZFMISC_1:def 2;
reconsider g2 = g as Element of the carrier of (Aut E) by J, K;
thus h * g = (AutComp (E,F)) . (h,g) by S, FUNCT_1:49
.= (AutComp E) . (h2,g2) by S, H, FUNCT_1:49
.= h1 * (h1 ") by A, defMult
.= e by R, FUNCT_2:29 ; :: thesis: g * h = e
thus g * h = (AutComp (E,F)) . (g,h) by S, FUNCT_1:49
.= (AutComp E) . (g2,h2) by S, H, FUNCT_1:49
.= (h1 ") * h1 by A, defMult
.= e by R, FUNCT_2:29 ; :: thesis: verum
end;
end;
hence for h being Element of (Aut S) holds
( h * e = h & e * h = h & ex g being Element of (Aut S) st
( h * g = e & g * h = e ) ) ; :: thesis: verum
end;
hence Aut S is Group-like ; :: thesis: Aut S is associative
now :: thesis: for x, y, z being Element of (Aut S) holds (x * y) * z = x * (y * z)
let x, y, z be Element of (Aut S); :: thesis: (x * y) * z = x * (y * z)
x in { f where f is F -fixing Automorphism of E : f .: S = S } ;
then consider f being F -fixing Automorphism of E such that
E1: ( x = f & f .: S = S ) ;
y in { f where f is F -fixing Automorphism of E : f .: S = S } ;
then consider g being F -fixing Automorphism of E such that
E2: ( y = g & g .: S = S ) ;
z in { f where f is F -fixing Automorphism of E : f .: S = S } ;
then consider h being F -fixing Automorphism of E such that
E3: ( z = h & h .: S = S ) ;
H: [:(Auts S),(Auts S):] c= [:(Auts (E,F)),(Auts (E,F)):] by ZFMISC_1:96;
B: ( [f,g] in [:(Auts S),(Auts S):] & [g,h] in [:(Auts S),(Auts S):] ) by E1, E2, E3, ZFMISC_1:def 2;
E4: x * y = (AutComp (E,F)) . (x,y) by E1, E2, B, FUNCT_1:49
.= (AutComp E) . (f,g) by E1, E2, B, H, FUNCT_1:49
.= f * g by defMult ;
E5: y * z = (AutComp (E,F)) . (y,z) by E2, E3, B, FUNCT_1:49
.= (AutComp E) . (g,h) by E2, E3, B, H, FUNCT_1:49
.= g * h by defMult ;
then D: ( [(f * g),h] in [:(Auts S),(Auts S):] & [f,(g * h)] in [:(Auts S),(Auts S):] ) by E1, E3, E4, ZFMISC_1:def 2;
thus (x * y) * z = (AutComp (E,F)) . ((x * y),z) by E3, E4, D, FUNCT_1:49
.= (AutComp E) . ((f * g),h) by E3, E4, D, H, FUNCT_1:49
.= (f * g) * h by defMult
.= f * (g * h) by RELAT_1:36
.= (AutComp E) . (f,(g * h)) by defMult
.= ((AutComp E) || (Auts (E,F))) . (x,(y * z)) by E1, E5, D, H, FUNCT_1:49
.= x * (y * z) by E1, E5, D, FUNCT_1:49 ; :: thesis: verum
end;
hence Aut S is associative ; :: thesis: verum