set G = Aut (E,F);
ex e being Element of (Aut (E,F)) st
for h being Element of (Aut (E,F)) holds
( h * e = h & e * h = h & ex g being Element of (Aut (E,F)) st
( h * g = e & g * h = e ) )
proof
id E in { f where f is F -fixing Automorphism of E : verum } ;
then reconsider e = id E as Element of (Aut (E,F)) ;
take e ; :: thesis: for h being Element of (Aut (E,F)) holds
( h * e = h & e * h = h & ex g being Element of (Aut (E,F)) st
( h * g = e & g * h = e ) )

now :: thesis: for h being Element of (Aut (E,F)) holds
( h * e = h & e * h = h & ex g being Element of (Aut (E,F)) st
( h * g = e & g * h = e ) )
let h be Element of (Aut (E,F)); :: thesis: ( h * e = h & e * h = h & ex g being Element of (Aut (E,F)) st
( h * g = e & g * h = e ) )

h in { f where f is F -fixing Automorphism of E : verum } ;
then consider h1 being F -fixing Automorphism of E such that
A: h1 = h ;
( h1 in Auts (E,F) & id E in Auts (E,F) ) ;
then B: ( [h1,e] in [:(Auts (E,F)),(Auts (E,F)):] & [e,h1] in [:(Auts (E,F)),(Auts (E,F)):] ) by ZFMISC_1:def 2;
thus h * e = (AutComp E) . (h1,e) by A, B, FUNCT_1:49
.= h1 * (id E) by defMult
.= h by A, FUNCT_2:17 ; :: thesis: ( e * h = h & ex g being Element of (Aut (E,F)) st
( h * g = e & g * h = e ) )

thus e * h = (AutComp E) . (e,h1) by A, B, FUNCT_1:49
.= (id E) * h1 by defMult
.= h by A, FUNCT_2:17 ; :: thesis: ex g being Element of (Aut (E,F)) st
( h * g = e & g * h = e )

thus ex g being Element of (Aut (E,F)) st
( h * g = e & g * h = e ) :: thesis: verum
proof
h1 " in { f where f is F -fixing Automorphism of E : verum } ;
then reconsider g = h1 " as Element of (Aut (E,F)) ;
take g ; :: thesis: ( h * g = e & g * h = e )
B: rng h1 = the carrier of E by FUNCT_2:def 3;
C: ( [h,g] in [:(Auts (E,F)),(Auts (E,F)):] & [g,h] in [:(Auts (E,F)),(Auts (E,F)):] ) by ZFMISC_1:def 2;
thus h * g = (AutComp E) . (h,g) by C, FUNCT_1:49
.= h1 * (h1 ") by A, defMult
.= e by B, FUNCT_2:29 ; :: thesis: g * h = e
thus g * h = (AutComp E) . (g,h) by C, FUNCT_1:49
.= (h1 ") * h1 by A, defMult
.= e by B, FUNCT_2:29 ; :: thesis: verum
end;
end;
hence for h being Element of (Aut (E,F)) holds
( h * e = h & e * h = h & ex g being Element of (Aut (E,F)) st
( h * g = e & g * h = e ) ) ; :: thesis: verum
end;
hence Aut (E,F) is Group-like ; :: thesis: Aut (E,F) is associative
now :: thesis: for a, b, c being Element of (Aut (E,F)) holds (a * b) * c = a * (b * c)
let a, b, c be Element of (Aut (E,F)); :: thesis: (a * b) * c = a * (b * c)
a in { f where f is F -fixing Automorphism of E : verum } ;
then consider f being F -fixing Automorphism of E such that
A: f = a ;
b in { f where f is F -fixing Automorphism of E : verum } ;
then consider g being F -fixing Automorphism of E such that
B: g = b ;
c in { f where f is F -fixing Automorphism of E : verum } ;
then consider h being F -fixing Automorphism of E such that
C: h = c ;
H: ( f in Auts (E,F) & g in Auts (E,F) & h in Auts (E,F) ) ;
then I: ( [f,g] in [:(Auts (E,F)),(Auts (E,F)):] & [g,h] in [:(Auts (E,F)),(Auts (E,F)):] ) by ZFMISC_1:def 2;
D: a * b = (AutComp E) . (f,g) by A, B, I, FUNCT_1:49
.= f * g by defMult ;
E: b * c = (AutComp E) . (g,h) by B, C, I, FUNCT_1:49
.= g * h by defMult ;
then J: ( [(f * g),h] in [:(Auts (E,F)),(Auts (E,F)):] & [f,(g * h)] in [:(Auts (E,F)),(Auts (E,F)):] ) by H, D, ZFMISC_1:def 2;
thus (a * b) * c = (AutComp E) . ((f * g),h) by C, D, J, FUNCT_1:49
.= (f * g) * h by defMult
.= f * (g * h) by RELAT_1:36
.= (AutComp E) . (f,(g * h)) by defMult
.= a * (b * c) by A, E, J, FUNCT_1:49 ; :: thesis: verum
end;
hence Aut (E,F) is associative ; :: thesis: verum