let p be Prime; :: thesis: for n being non zero Nat
for F being GaloisField of p |^ n holds Aut (F,(Z/ p)) = gr {(Frob F)}

let n be non zero Nat; :: thesis: for F being GaloisField of p |^ n holds Aut (F,(Z/ p)) = gr {(Frob F)}
let F be GaloisField of p |^ n; :: thesis: Aut (F,(Z/ p)) = gr {(Frob F)}
card F = p |^ n by FIELD_16:def 8;
then A: { f where f is Automorphism of F : verum } = { ((Frob F) `^ m) where m is Nat : ( 0 <= m & m <= n - 1 ) } by FIELD_16:65;
now :: thesis: for o being object st o in the carrier of (Aut (F,(Z/ p))) holds
o in the carrier of (gr {(Frob F)})
let o be object ; :: thesis: ( o in the carrier of (Aut (F,(Z/ p))) implies o in the carrier of (gr {(Frob F)}) )
assume o in the carrier of (Aut (F,(Z/ p))) ; :: thesis: o in the carrier of (gr {(Frob F)})
then o in the carrier of (Aut F) ;
then consider m being Nat such that
B: ( o = (Frob F) `^ m & 0 <= m & m <= n - 1 ) by A;
(Frob F) `^ m = (Frob F) |^ m by lemAT2;
then (Frob F) `^ m in gr {(Frob F)} by GR_CY_1:5;
hence o in the carrier of (gr {(Frob F)}) by B; :: thesis: verum
end;
then the carrier of (Aut (F,(Z/ p))) c= the carrier of (gr {(Frob F)}) ;
hence Aut (F,(Z/ p)) = gr {(Frob F)} by GROUP_2:61; :: thesis: verum