let S, T be non empty Poset; :: thesis: for g being Function of S,T
for d being Function of T,S st [g,d] is co-Galois holds
( ( for s being Element of S holds
( s in Closed d iff d . (g . s) = s ) ) & ( for t being Element of T holds
( t in Closed g iff g . (d . t) = t ) ) & (g | (Closed d)) " = d | (Closed g) & (d | (Closed g)) " = g | (Closed d) & Restr (g,d) is bijective & Restr (d,g) is bijective )

let g be Function of S,T; :: thesis: for d being Function of T,S st [g,d] is co-Galois holds
( ( for s being Element of S holds
( s in Closed d iff d . (g . s) = s ) ) & ( for t being Element of T holds
( t in Closed g iff g . (d . t) = t ) ) & (g | (Closed d)) " = d | (Closed g) & (d | (Closed g)) " = g | (Closed d) & Restr (g,d) is bijective & Restr (d,g) is bijective )

let d be Function of T,S; :: thesis: ( [g,d] is co-Galois implies ( ( for s being Element of S holds
( s in Closed d iff d . (g . s) = s ) ) & ( for t being Element of T holds
( t in Closed g iff g . (d . t) = t ) ) & (g | (Closed d)) " = d | (Closed g) & (d | (Closed g)) " = g | (Closed d) & Restr (g,d) is bijective & Restr (d,g) is bijective ) )

assume [g,d] is co-Galois ; :: thesis: ( ( for s being Element of S holds
( s in Closed d iff d . (g . s) = s ) ) & ( for t being Element of T holds
( t in Closed g iff g . (d . t) = t ) ) & (g | (Closed d)) " = d | (Closed g) & (d | (Closed g)) " = g | (Closed d) & Restr (g,d) is bijective & Restr (d,g) is bijective )

then consider f1 being Function of S,T, f2 being Function of T,S such that
A: ( [f1,f2] = [g,d] & f1 is antitone & f2 is antitone & ( for p1, p2 being Element of S
for r1, r2 being Element of T holds
( p1 <= f2 . (f1 . p1) & r1 <= f1 . (f2 . r1) ) ) ) by CONLAT_1:def 7;
B: f1 = [g,d] `1 by A
.= g ;
C: f2 = [g,d] `2 by A
.= d ;
reconsider g1 = g | (Closed d) as Function of (Closed d),(Closed g) by mainA;
reconsider d1 = d | (Closed g) as Function of (Closed g),(Closed d) by mainA;
K: now :: thesis: for s being Element of S holds
( s in Closed d iff d . (g . s) = s )
let s be Element of S; :: thesis: ( s in Closed d iff d . (g . s) = s )
now :: thesis: ( s in Closed d implies d . (g . s) = s )
assume s in Closed d ; :: thesis: d . (g . s) = s
then consider t being Element of T such that
F1: s = d . t ;
F2: s <= d . (g . s) by A, B, C;
d . (g . (d . t)) <= d . t by A, B, C, WAYBEL_0:def 5;
hence d . (g . s) = s by F1, F2, ORDERS_2:2; :: thesis: verum
end;
hence ( s in Closed d iff d . (g . s) = s ) ; :: thesis: verum
end;
hence for s being Element of S holds
( s in Closed d iff d . (g . s) = s ) ; :: thesis: ( ( for t being Element of T holds
( t in Closed g iff g . (d . t) = t ) ) & (g | (Closed d)) " = d | (Closed g) & (d | (Closed g)) " = g | (Closed d) & Restr (g,d) is bijective & Restr (d,g) is bijective )

E: now :: thesis: for t being Element of T holds
( t in Closed g iff g . (d . t) = t )
let t be Element of T; :: thesis: ( t in Closed g iff g . (d . t) = t )
now :: thesis: ( t in Closed g implies g . (d . t) = t )
assume t in Closed g ; :: thesis: g . (d . t) = t
then consider s being Element of S such that
F1: t = g . s ;
F2: t <= g . (d . t) by A, B, C;
g . (d . (g . s)) <= g . s by A, B, C, WAYBEL_0:def 5;
hence g . (d . t) = t by F1, F2, ORDERS_2:2; :: thesis: verum
end;
hence ( t in Closed g iff g . (d . t) = t ) ; :: thesis: verum
end;
hence for t being Element of T holds
( t in Closed g iff g . (d . t) = t ) ; :: thesis: ( (g | (Closed d)) " = d | (Closed g) & (d | (Closed g)) " = g | (Closed d) & Restr (g,d) is bijective & Restr (d,g) is bijective )
now :: thesis: for o being object st o in Closed g holds
(g1 * d1) . o = (id (Closed g)) . o
let o be object ; :: thesis: ( o in Closed g implies (g1 * d1) . o = (id (Closed g)) . o )
assume E1: o in Closed g ; :: thesis: (g1 * d1) . o = (id (Closed g)) . o
then reconsider t = o as Element of T ;
E2: d1 . t = d . t by E1, FUNCT_1:49;
dom d1 = Closed g by FUNCT_2:def 1;
then E3: ( d1 . t in rng d1 & rng d1 c= Closed d ) by E1, FUNCT_1:3, RELAT_1:def 19;
thus (g1 * d1) . o = g1 . (d1 . t) by E1, FUNCT_2:15
.= g . (d . t) by E2, E3, FUNCT_1:49
.= t by E1, E
.= (id (Closed g)) . o by E1, FUNCT_1:18 ; :: thesis: verum
end;
then G1: g1 * d1 = id (Closed g) ;
then B1: ( d1 is one-to-one & g1 is onto ) by FUNCT_2:23;
now :: thesis: for o being object st o in Closed d holds
(d1 * g1) . o = (id (Closed d)) . o
let o be object ; :: thesis: ( o in Closed d implies (d1 * g1) . o = (id (Closed d)) . o )
assume E1: o in Closed d ; :: thesis: (d1 * g1) . o = (id (Closed d)) . o
then reconsider s = o as Element of S ;
E2: g1 . s = g . s by E1, FUNCT_1:49;
dom g1 = Closed d by FUNCT_2:def 1;
then E3: ( g1 . s in rng g1 & rng g1 c= Closed g ) by E1, FUNCT_1:3, RELAT_1:def 19;
thus (d1 * g1) . o = d1 . (g1 . s) by E1, FUNCT_2:15
.= d . (g . s) by E2, E3, FUNCT_1:49
.= s by E1, K
.= (id (Closed d)) . o by E1, FUNCT_1:18 ; :: thesis: verum
end;
then G3: d1 * g1 = id (Closed d) ;
then ( g1 is one-to-one & d1 is onto ) by FUNCT_2:23;
hence ( (g | (Closed d)) " = d | (Closed g) & (d | (Closed g)) " = g | (Closed d) ) by G1, B1, G3, FUNCT_2:30; :: thesis: ( Restr (g,d) is bijective & Restr (d,g) is bijective )
thus ( Restr (g,d) is bijective & Restr (d,g) is bijective ) by G3, G1, FUNCT_2:23; :: thesis: verum