let Omega be non empty set ; :: thesis: for Sigma being SigmaField of Omega
for T being Nat
for MyFunc being Filtration of StoppingSet T,Sigma
for k being Function of Omega,(StoppingSetExt T) holds
( k is_StoppingTime_wrt MyFunc,T iff for t being Element of StoppingSet T holds { w where w is Element of Omega : k . w <= t } in MyFunc . t )
let Sigma be SigmaField of Omega; :: thesis: for T being Nat
for MyFunc being Filtration of StoppingSet T,Sigma
for k being Function of Omega,(StoppingSetExt T) holds
( k is_StoppingTime_wrt MyFunc,T iff for t being Element of StoppingSet T holds { w where w is Element of Omega : k . w <= t } in MyFunc . t )
let T be Nat; :: thesis: for MyFunc being Filtration of StoppingSet T,Sigma
for k being Function of Omega,(StoppingSetExt T) holds
( k is_StoppingTime_wrt MyFunc,T iff for t being Element of StoppingSet T holds { w where w is Element of Omega : k . w <= t } in MyFunc . t )
let MyFunc be Filtration of StoppingSet T,Sigma; :: thesis: for k being Function of Omega,(StoppingSetExt T) holds
( k is_StoppingTime_wrt MyFunc,T iff for t being Element of StoppingSet T holds { w where w is Element of Omega : k . w <= t } in MyFunc . t )
let k be Function of Omega,(StoppingSetExt T); :: thesis: ( k is_StoppingTime_wrt MyFunc,T iff for t being Element of StoppingSet T holds { w where w is Element of Omega : k . w <= t } in MyFunc . t )
thus ( k is_StoppingTime_wrt MyFunc,T implies for t being Element of StoppingSet T holds { w where w is Element of Omega : k . w <= t } in MyFunc . t ) :: thesis: ( ( for t being Element of StoppingSet T holds { w where w is Element of Omega : k . w <= t } in MyFunc . t ) implies k is_StoppingTime_wrt MyFunc,T )

proof

assume ASS: k is_StoppingTime_wrt MyFunc,T ; :: thesis: for t being Element of StoppingSet T holds { w where w is Element of Omega : k . w <= t } in MyFunc . t
for t being Element of StoppingSet T holds { w where w is Element of Omega : k . w <= t } in MyFunc . t

proof

defpred S₁[ Nat] means ( $1 in StoppingSet T implies { w where w is Element of Omega : k . w <= $1 } in MyFunc . $1 );
K1: { w where w is Element of Omega : k . w <= 0 } = { w where w is Element of Omega : k . w = 0 }

proof

for q being object holds
( q in { w where w is Element of Omega : k . w <= 0 } iff q in { w where w is Element of Omega : k . w = 0 } )

proof

let q be object ; :: thesis: ( q in { w where w is Element of Omega : k . w <= 0 } iff q in { w where w is Element of Omega : k . w = 0 } )
I1: ( ex q1 being Element of Omega st
( q = q1 & k . q1 <= 0 ) implies ex q2 being Element of Omega st
( q = q2 & k . q2 = 0 ) )

proof

given q2 being Element of Omega such that II: ( q = q2 & k . q2 <= 0 ) ; :: thesis: ex q2 being Element of Omega st
( q = q2 & k . q2 = 0 )
k . q2 = 0

proof

per cases ( k . q2 in StoppingSet T or k . q2 in {+infty} ) by XBOOLE_0:def 3;

suppose k . q2 in StoppingSet T ; :: thesis: k . q2 = 0

then ex s being Element of NAT st
( k . q2 = s & 0 <= s & s <= T ) ;
hence k . q2 = 0 by II; :: thesis: verum

end;

suppose k . q2 in {+infty} ; :: thesis: k . q2 = 0

hence k . q2 = 0 by II, TARSKI:def 1; :: thesis: verum

end;

end;

end;

hence ex q2 being Element of Omega st
( q = q2 & k . q2 = 0 ) by II; :: thesis: verum

end;

( ex q2 being Element of Omega st
( q = q2 & k . q2 = 0 ) implies ex q1 being Element of Omega st
( q = q1 & k . q1 <= 0 ) ) ;
hence ( q in { w where w is Element of Omega : k . w <= 0 } iff q in { w where w is Element of Omega : k . w = 0 } ) by I1; :: thesis: verum

end;

hence { w where w is Element of Omega : k . w <= 0 } = { w where w is Element of Omega : k . w = 0 } by TARSKI:2; :: thesis: verum

end;

J0: S₁[ 0 ]

proof

{ w where w is Element of Omega : k . w <= 0 } in MyFunc . 0

proof

0 in StoppingSet T ;
hence { w where w is Element of Omega : k . w <= 0 } in MyFunc . 0 by K1, ASS; :: thesis: verum

end;

hence S₁[ 0 ] ; :: thesis: verum

end;

J1: for n being Nat st S₁[n] holds
S₁[n + 1]

proof

let n be Nat; :: thesis: ( S₁[n] implies S₁[n + 1] )
assume j1: S₁[n] ; :: thesis: S₁[n + 1]
( n + 1 in StoppingSet T implies { w where w is Element of Omega : k . w <= n + 1 } in MyFunc . (n + 1) )

proof

assume ASSJ10: n + 1 in StoppingSet T ; :: thesis: { w where w is Element of Omega : k . w <= n + 1 } in MyFunc . (n + 1)
J10: { w where w is Element of Omega : k . w <= n + 1 } = { w where w is Element of Omega : k . w <= n } \/ { w where w is Element of Omega : k . w = n + 1 }

proof

for x being object holds
( x in { w where w is Element of Omega : k . w <= n + 1 } iff x in { w where w is Element of Omega : k . w <= n } \/ { w where w is Element of Omega : k . w = n + 1 } )

proof

let x be object ; :: thesis: ( x in { w where w is Element of Omega : k . w <= n + 1 } iff x in { w where w is Element of Omega : k . w <= n } \/ { w where w is Element of Omega : k . w = n + 1 } )
thus ( x in { w where w is Element of Omega : k . w <= n + 1 } implies x in { w where w is Element of Omega : k . w <= n } \/ { w where w is Element of Omega : k . w = n + 1 } ) :: thesis: ( x in { w where w is Element of Omega : k . w <= n } \/ { w where w is Element of Omega : k . w = n + 1 } implies x in { w where w is Element of Omega : k . w <= n + 1 } )

proof

assume x in { w where w is Element of Omega : k . w <= n + 1 } ; :: thesis: x in { w where w is Element of Omega : k . w <= n } \/ { w where w is Element of Omega : k . w = n + 1 }
then consider w being Element of Omega such that
XX: ( x = w & k . w <= n + 1 ) ;
set KW = k . w;

per cases ( ( x = w & k . w <= n ) or ( x = w & not k . w <= n ) ) by XX;

suppose ( x = w & k . w <= n ) ; :: thesis: x in { w where w is Element of Omega : k . w <= n } \/ { w where w is Element of Omega : k . w = n + 1 }

then x in { w where w is Element of Omega : k . w <= n } ;
hence x in { w where w is Element of Omega : k . w <= n } \/ { w where w is Element of Omega : k . w = n + 1 } by XBOOLE_0:def 3; :: thesis: verum

end;

suppose S1: ( x = w & not k . w <= n ) ; :: thesis: x in { w where w is Element of Omega : k . w <= n } \/ { w where w is Element of Omega : k . w = n + 1 }

k . w = n + 1

proof

( k . w is Element of NAT or k . w = +infty )

proof

( k . w in StoppingSet T or k . w in {+infty} ) by XBOOLE_0:def 3;

per cases then ( k . w = +infty or k . w in StoppingSet T ) by TARSKI:def 1;

suppose k . w = +infty ; :: thesis: ( k . w is Element of NAT or k . w = +infty )

hence ( k . w is Element of NAT or k . w = +infty ) ; :: thesis: verum

end;

suppose k . w in StoppingSet T ; :: thesis: ( k . w is Element of NAT or k . w = +infty )

then ex q being Element of NAT st
( k . w = q & 0 <= q & q <= T ) ;
hence ( k . w is Element of NAT or k . w = +infty ) ; :: thesis: verum

end;

end;

end;

then reconsider KW = k . w as Element of NAT by NUMBERS:19, XX, XXREAL_0:9;

per cases ( KW <= n or KW = n + 1 ) by XX, NAT_1:8;

suppose KW <= n ; :: thesis: k . w = n + 1

hence k . w = n + 1 by S1; :: thesis: verum

end;

suppose KW = n + 1 ; :: thesis: k . w = n + 1

hence k . w = n + 1 ; :: thesis: verum

end;

end;

end;

then x in { w where w is Element of Omega : k . w = n + 1 } by XX;
hence x in { w where w is Element of Omega : k . w <= n } \/ { w where w is Element of Omega : k . w = n + 1 } by XBOOLE_0:def 3; :: thesis: verum

end;

end;

end;

assume x in { w where w is Element of Omega : k . w <= n } \/ { w where w is Element of Omega : k . w = n + 1 } ; :: thesis: x in { w where w is Element of Omega : k . w <= n + 1 }

per cases then ( x in { w where w is Element of Omega : k . w <= n } or x in { w where w is Element of Omega : k . w = n + 1 } ) by XBOOLE_0:def 3;

suppose JP: x in { w where w is Element of Omega : k . w <= n } ; :: thesis: x in { w where w is Element of Omega : k . w <= n + 1 }

x in { w where w is Element of Omega : k . w <= n + 1 }

proof

consider q being Element of Omega such that
Q1: ( x = q & k . q <= n ) by JP;
set KJ = k . q;
( k . q is Element of NAT or k . q = +infty )

proof

( k . q in StoppingSet T or k . q in {+infty} ) by XBOOLE_0:def 3;

per cases then ( k . q = +infty or k . q in StoppingSet T ) by TARSKI:def 1;

suppose k . q = +infty ; :: thesis: ( k . q is Element of NAT or k . q = +infty )

hence ( k . q is Element of NAT or k . q = +infty ) ; :: thesis: verum

end;

suppose k . q in StoppingSet T ; :: thesis: ( k . q is Element of NAT or k . q = +infty )

then ex q1 being Element of NAT st
( k . q = q1 & 0 <= q1 & q1 <= T ) ;
hence ( k . q is Element of NAT or k . q = +infty ) ; :: thesis: verum

end;

end;

end;

then reconsider KJ = k . q as Element of NAT by XREAL_0:def 1, Q1, XXREAL_0:9;
( KJ <= n implies KJ <= n + 1 ) by NAT_1:12;
hence x in { w where w is Element of Omega : k . w <= n + 1 } by Q1; :: thesis: verum

end;

hence x in { w where w is Element of Omega : k . w <= n + 1 } ; :: thesis: verum

end;

suppose JP: x in { w where w is Element of Omega : k . w = n + 1 } ; :: thesis: x in { w where w is Element of Omega : k . w <= n + 1 }

x in { w where w is Element of Omega : k . w <= n + 1 }

proof

ex q being Element of Omega st
( x = q & k . q = n + 1 ) by JP;
hence x in { w where w is Element of Omega : k . w <= n + 1 } ; :: thesis: verum

end;

hence x in { w where w is Element of Omega : k . w <= n + 1 } ; :: thesis: verum

end;

end;

end;

hence { w where w is Element of Omega : k . w <= n + 1 } = { w where w is Element of Omega : k . w <= n } \/ { w where w is Element of Omega : k . w = n + 1 } by TARSKI:2; :: thesis: verum

end;

reconsider n = n as Element of NAT by ORDINAL1:def 12;
{ w where w is Element of Omega : k . w <= n } \/ { w where w is Element of Omega : k . w = n + 1 } in MyFunc . (n + 1)

proof

set A = { w where w is Element of Omega : k . w <= n } ;
set B = { w where w is Element of Omega : k . w = n + 1 } ;
set C = MyFunc . (n + 1);
reconsider C = MyFunc . (n + 1) as SigmaField of Omega by ASSJ10, KOLMOG01:def 2;
n in StoppingSet T

proof

consider t being Element of NAT such that
Y20: ( n + 1 = t & 0 <= t & t <= T ) by ASSJ10;
( 0 <= n & n <= T ) by Y20, NAT_1:13;
hence n in StoppingSet T ; :: thesis: verum

end;

then reconsider n = n as Element of StoppingSet T ;
h2: { w where w is Element of Omega : k . w <= n } is Element of C

proof

for x being set st x in MyFunc . n holds
x in MyFunc . (n + 1)

proof

MyFunc . n is Subset of (MyFunc . (n + 1)) by FINANCE3:def 9, NAT_1:12, ASSJ10;
hence for x being set st x in MyFunc . n holds
x in MyFunc . (n + 1) ; :: thesis: verum

end;

hence { w where w is Element of Omega : k . w <= n } is Element of C by j1; :: thesis: verum

end;

{ w where w is Element of Omega : k . w = n + 1 } is Event of C by ASSJ10, ASS;
then { w where w is Element of Omega : k . w <= n } \/ { w where w is Element of Omega : k . w = n + 1 } is Event of C by h2, PROB_1:21;
hence { w where w is Element of Omega : k . w <= n } \/ { w where w is Element of Omega : k . w = n + 1 } in MyFunc . (n + 1) ; :: thesis: verum

end;

hence { w where w is Element of Omega : k . w <= n + 1 } in MyFunc . (n + 1) by J10; :: thesis: verum

end;

hence S₁[n + 1] ; :: thesis: verum

end;

Q1: for n being Nat holds S₁[n] from NAT_1:sch 2(J0, J1);
for t being Element of StoppingSet T holds { w where w is Element of Omega : k . w <= t } in MyFunc . t

proof

let t be Element of StoppingSet T; :: thesis: { w where w is Element of Omega : k . w <= t } in MyFunc . t
t in StoppingSet T ;
then ex s being Element of NAT st
( t = s & 0 <= s & s <= T ) ;
hence { w where w is Element of Omega : k . w <= t } in MyFunc . t by Q1; :: thesis: verum

end;

hence for t being Element of StoppingSet T holds { w where w is Element of Omega : k . w <= t } in MyFunc . t ; :: thesis: verum

end;

hence for t being Element of StoppingSet T holds { w where w is Element of Omega : k . w <= t } in MyFunc . t ; :: thesis: verum

end;

assume ASSJ1: for t being Element of StoppingSet T holds { w where w is Element of Omega : k . w <= t } in MyFunc . t ; :: thesis: k is_StoppingTime_wrt MyFunc,T
for t being Element of StoppingSet T holds { w where w is Element of Omega : k . w = t } in MyFunc . t

proof

let t be Element of StoppingSet T; :: thesis: { w where w is Element of Omega : k . w = t } in MyFunc . t
defpred S₁[ Nat] means ( $1 + 1 in StoppingSet T implies { w where w is Element of Omega : k . w < $1 + 1 } in MyFunc . ($1 + 1) );
J01: S₁[ 0 ]

proof

( 0 + 1 in StoppingSet T implies { w where w is Element of Omega : k . w < 0 + 1 } in MyFunc . (0 + 1) )

proof

assume ASS: 0 + 1 in StoppingSet T ; :: thesis: { w where w is Element of Omega : k . w < 0 + 1 } in MyFunc . (0 + 1)
{ w where w is Element of Omega : k . w < 0 + 1 } in MyFunc . (0 + 1)

proof

H1: { w where w is Element of Omega : k . w <= 0 } = { w where w is Element of Omega : k . w < 0 + 1 }

proof

for x being object holds
( x in { w where w is Element of Omega : k . w <= 0 } iff x in { w where w is Element of Omega : k . w < 0 + 1 } )

proof

let x be object ; :: thesis: ( x in { w where w is Element of Omega : k . w <= 0 } iff x in { w where w is Element of Omega : k . w < 0 + 1 } )
thus ( x in { w where w is Element of Omega : k . w <= 0 } implies x in { w where w is Element of Omega : k . w < 0 + 1 } ) :: thesis: ( x in { w where w is Element of Omega : k . w < 0 + 1 } implies x in { w where w is Element of Omega : k . w <= 0 } )

proof

assume x in { w where w is Element of Omega : k . w <= 0 } ; :: thesis: x in { w where w is Element of Omega : k . w < 0 + 1 }
then consider w1 being Element of Omega such that
W1: ( x = w1 & k . w1 <= 0 ) ;
thus x in { w where w is Element of Omega : k . w < 0 + 1 } by W1; :: thesis: verum

end;

assume x in { w where w is Element of Omega : k . w < 0 + 1 } ; :: thesis: x in { w where w is Element of Omega : k . w <= 0 }
then consider w1 being Element of Omega such that
W1: ( x = w1 & k . w1 < 0 + 1 ) ;
set KWJ = k . w1;
( k . w1 is Element of NAT or k . w1 = +infty )

proof

( k . w1 in StoppingSet T or k . w1 in {+infty} ) by XBOOLE_0:def 3;

per cases then ( k . w1 = +infty or k . w1 in StoppingSet T ) by TARSKI:def 1;

suppose k . w1 = +infty ; :: thesis: ( k . w1 is Element of NAT or k . w1 = +infty )

hence ( k . w1 is Element of NAT or k . w1 = +infty ) ; :: thesis: verum

end;

suppose k . w1 in StoppingSet T ; :: thesis: ( k . w1 is Element of NAT or k . w1 = +infty )

then ex q1 being Element of NAT st
( k . w1 = q1 & 0 <= q1 & q1 <= T ) ;
hence ( k . w1 is Element of NAT or k . w1 = +infty ) ; :: thesis: verum

end;

end;

end;

then reconsider KWJ = k . w1 as Nat by NUMBERS:19, W1, XXREAL_0:9;
KWJ <= 0 by NAT_1:13, W1;
hence x in { w where w is Element of Omega : k . w <= 0 } by W1; :: thesis: verum

end;

hence { w where w is Element of Omega : k . w <= 0 } = { w where w is Element of Omega : k . w < 0 + 1 } by TARSKI:2; :: thesis: verum

end;

T1: 0 in StoppingSet T ;
then reconsider JA = 0 as Element of StoppingSet T ;
reconsider JB = 0 + 1 as Element of StoppingSet T by ASS;
h2: MyFunc . JA is Subset of (MyFunc . JB) by FINANCE3:def 9;
{ w where w is Element of Omega : k . w <= 0 } in MyFunc . 0 by ASSJ1, T1;
hence { w where w is Element of Omega : k . w < 0 + 1 } in MyFunc . (0 + 1) by H1, h2; :: thesis: verum

end;

hence { w where w is Element of Omega : k . w < 0 + 1 } in MyFunc . (0 + 1) ; :: thesis: verum

end;

hence S₁[ 0 ] ; :: thesis: verum

end;

J11: for n being Nat st S₁[n] holds
S₁[n + 1]

proof

let n be Nat; :: thesis: ( S₁[n] implies S₁[n + 1] )
assume S₁[n] ; :: thesis: S₁[n + 1]
( (n + 1) + 1 in StoppingSet T implies { w where w is Element of Omega : k . w < (n + 1) + 1 } in MyFunc . ((n + 1) + 1) )

proof

assume N01: (n + 1) + 1 in StoppingSet T ; :: thesis: { w where w is Element of Omega : k . w < (n + 1) + 1 } in MyFunc . ((n + 1) + 1)
M10: { w where w is Element of Omega : k . w < (n + 1) + 1 } = { w where w is Element of Omega : k . w <= n + 1 }

proof

for x being object holds
( x in { w where w is Element of Omega : k . w < (n + 1) + 1 } iff x in { w where w is Element of Omega : k . w <= n + 1 } )

proof

let x be object ; :: thesis: ( x in { w where w is Element of Omega : k . w < (n + 1) + 1 } iff x in { w where w is Element of Omega : k . w <= n + 1 } )
thus ( x in { w where w is Element of Omega : k . w < (n + 1) + 1 } implies x in { w where w is Element of Omega : k . w <= n + 1 } ) :: thesis: ( x in { w where w is Element of Omega : k . w <= n + 1 } implies x in { w where w is Element of Omega : k . w < (n + 1) + 1 } )

proof

assume x in { w where w is Element of Omega : k . w < (n + 1) + 1 } ; :: thesis: x in { w where w is Element of Omega : k . w <= n + 1 }
then consider w being Element of Omega such that
F11: ( x = w & k . w < (n + 1) + 1 ) ;
set KW = k . w;
a1: k . w in StoppingSet T

proof

(n + 1) + 1 in REAL by NUMBERS:19;
then k . w < +infty by F11, XXREAL_0:2, XXREAL_0:9;
then not k . w in {+infty} by TARSKI:def 1;
hence k . w in StoppingSet T by XBOOLE_0:def 3; :: thesis: verum

end;

consider w2 being Element of NAT such that
L21: ( k . w = w2 & 0 <= w2 & w2 <= T ) by a1;
( k . w < (n + 1) + 1 iff k . w <= n + 1 ) by NAT_1:13, L21;
hence x in { w where w is Element of Omega : k . w <= n + 1 } by F11; :: thesis: verum

end;

assume x in { w where w is Element of Omega : k . w <= n + 1 } ; :: thesis: x in { w where w is Element of Omega : k . w < (n + 1) + 1 }
then consider w3 being Element of Omega such that
QZ1: ( x = w3 & k . w3 <= n + 1 ) ;
set KW = k . w3;
k . w3 in StoppingSet T

proof

not k . w3 in {+infty}

proof

n + 1 < +infty by XXREAL_0:9, NUMBERS:19;
hence not k . w3 in {+infty} by TARSKI:def 1, QZ1; :: thesis: verum

end;

hence k . w3 in StoppingSet T by XBOOLE_0:def 3; :: thesis: verum

end;

then consider w2 being Element of NAT such that
L21: ( k . w3 = w2 & 0 <= w2 & w2 <= T ) ;
k . w3 < (n + 1) + 1 by QZ1, NAT_1:13, L21;
hence x in { w where w is Element of Omega : k . w < (n + 1) + 1 } by QZ1; :: thesis: verum

end;

hence { w where w is Element of Omega : k . w < (n + 1) + 1 } = { w where w is Element of Omega : k . w <= n + 1 } by TARSKI:2; :: thesis: verum

end;

s1: n + 1 in StoppingSet T

proof

consider w3 being Element of NAT such that
QZ10: ( w3 = (n + 1) + 1 & 0 <= w3 & w3 <= T ) by N01;
n + 1 < T by NAT_1:13, QZ10;
hence n + 1 in StoppingSet T ; :: thesis: verum

end;

( n + 1 in StoppingSet T & n + 1 <= (n + 1) + 1 ) by NAT_1:13, s1;
then MyFunc . (n + 1) is Subset of (MyFunc . ((n + 1) + 1)) by FINANCE3:def 9, N01;
then MyFunc . (n + 1) c= MyFunc . ((n + 1) + 1) ;
hence { w where w is Element of Omega : k . w < (n + 1) + 1 } in MyFunc . ((n + 1) + 1) by M10, ASSJ1, s1; :: thesis: verum

end;

hence S₁[n + 1] ; :: thesis: verum

end;

Q1: for n being Nat holds S₁[n] from NAT_1:sch 2(J01, J11);
reconsider M = MyFunc . t as SigmaField of Omega by KOLMOG01:def 2;
QH1: { w where w is Element of Omega : k . w <= t } is Element of M by ASSJ1;
t in StoppingSet T ;
then consider q being Element of NAT such that
QH3: ( t = q & 0 <= q & q <= T ) ;
reconsider t = t as Nat by QH3;
Q2: { w where w is Element of Omega : k . w <= t } \ { w where w is Element of Omega : k . w < t } is Event of M

proof

{ w where w is Element of Omega : k . w < t } is Element of M

proof

per cases ( t = 0 or t > 0 ) ;

suppose S1: t = 0 ; :: thesis: { w where w is Element of Omega : k . w < t } is Element of M

s2: { w where w is Element of Omega : k . w < 0 } c= {}

proof

let x be object ; :: according to TARSKI:def 3 :: thesis: ( not x in { w where w is Element of Omega : k . w < 0 } or x in {} )
assume x in { w where w is Element of Omega : k . w < 0 } ; :: thesis: x in {}
then consider w being Element of Omega such that
TT: ( x = w & k . w < 0 ) ;
k . w >= 0

proof

( k . w in StoppingSet T or k . w in {+infty} ) by XBOOLE_0:def 3;

per cases then ( k . w in StoppingSet T or k . w = +infty ) by TARSKI:def 1;

suppose k . w in StoppingSet T ; :: thesis: k . w >= 0

then ex t being Element of NAT st
( t = k . w & 0 <= t & t <= T ) ;
hence k . w >= 0 ; :: thesis: verum

end;

suppose k . w = +infty ; :: thesis: k . w >= 0

hence k . w >= 0 ; :: thesis: verum

end;

end;

end;

hence x in {} by TT; :: thesis: verum

end;

reconsider M = M as SigmaField of Omega ;
{} is Element of M by PROB_1:22;
hence { w where w is Element of Omega : k . w < t } is Element of M by s2, S1; :: thesis: verum

end;

suppose t > 0 ; :: thesis: { w where w is Element of Omega : k . w < t } is Element of M

then { w where w is Element of Omega : k . w < (t - 1) + 1 } is Element of MyFunc . ((t - 1) + 1) by Q1;
hence { w where w is Element of Omega : k . w < t } is Element of M ; :: thesis: verum

end;

end;

end;

hence { w where w is Element of Omega : k . w <= t } \ { w where w is Element of Omega : k . w < t } is Event of M by QH1, PROB_1:24; :: thesis: verum

end;

{ w where w is Element of Omega : k . w <= t } \ { w where w is Element of Omega : k . w < t } = { w where w is Element of Omega : k . w = t }

proof

for x being object holds
( x in { w where w is Element of Omega : k . w <= t } \ { w where w is Element of Omega : k . w < t } iff x in { w where w is Element of Omega : k . w = t } )

proof

let x be object ; :: thesis: ( x in { w where w is Element of Omega : k . w <= t } \ { w where w is Element of Omega : k . w < t } iff x in { w where w is Element of Omega : k . w = t } )
thus ( x in { w where w is Element of Omega : k . w <= t } \ { w where w is Element of Omega : k . w < t } implies x in { w where w is Element of Omega : k . w = t } ) :: thesis: ( x in { w where w is Element of Omega : k . w = t } implies x in { w where w is Element of Omega : k . w <= t } \ { w where w is Element of Omega : k . w < t } )

proof

assume x in { w where w is Element of Omega : k . w <= t } \ { w where w is Element of Omega : k . w < t } ; :: thesis: x in { w where w is Element of Omega : k . w = t }
then JJJ: ( x in { w where w is Element of Omega : k . w <= t } & not x in { w where w is Element of Omega : k . w < t } ) by XBOOLE_0:def 5;
then consider w1 being Element of Omega such that
JJJ1: ( w1 = x & k . w1 <= t ) ;
w1 in { w where w is Element of Omega : k . w = t }

proof

( k . w1 <= t & k . w1 >= t implies k . w1 = t )

proof

assume Q0: ( k . w1 <= t & k . w1 >= t ) ; :: thesis: k . w1 = t
set W = k . w1;
( k . w1 in StoppingSet T or k . w1 in {+infty} ) by XBOOLE_0:def 3;
then ( ex w3 being Element of NAT st
( w3 = k . w1 & 0 <= w3 & w3 <= T ) or k . w1 = +infty ) by TARSKI:def 1;
then reconsider W = k . w1 as Nat by JJJ1, XXREAL_0:9;
W + 1 > t by NAT_1:13, Q0;
hence k . w1 = t by Q0, NAT_1:22; :: thesis: verum

end;

hence w1 in { w where w is Element of Omega : k . w = t } by JJJ1, JJJ; :: thesis: verum

end;

hence x in { w where w is Element of Omega : k . w = t } by JJJ1; :: thesis: verum

end;

assume x in { w where w is Element of Omega : k . w = t } ; :: thesis: x in { w where w is Element of Omega : k . w <= t } \ { w where w is Element of Omega : k . w < t }
then consider w being Element of Omega such that
W1: ( x = w & k . w = t ) ;
( ex w1 being Element of Omega st
( x = w1 & k . w1 <= t ) & ( for w1 being Element of Omega holds
( not x = w1 or not k . w1 < t ) ) ) by W1;
then ( x in { w where w is Element of Omega : k . w <= t } & not x in { w where w is Element of Omega : k . w < t } ) ;
hence x in { w where w is Element of Omega : k . w <= t } \ { w where w is Element of Omega : k . w < t } by XBOOLE_0:def 5; :: thesis: verum

end;

hence { w where w is Element of Omega : k . w <= t } \ { w where w is Element of Omega : k . w < t } = { w where w is Element of Omega : k . w = t } by TARSKI:2; :: thesis: verum

end;

hence { w where w is Element of Omega : k . w = t } in MyFunc . t by Q2; :: thesis: verum

end;

hence k is_StoppingTime_wrt MyFunc,T ; :: thesis: verum