defpred S₁[ Nat] means EvenFibs ((2 * $1) + 2) = (EvenFibs (2 * $1)) ^ <*(Fib ((2 * $1) + 2))*>;
let n be Element of NAT ; :: thesis: EvenFibs ((2 * n) + 2) = (EvenFibs (2 * n)) ^ <*(Fib ((2 * n) + 2))*>
A1: for k being Nat st S₁[k] holds
S₁[k + 1]

proof

let k be Nat; :: thesis: ( S₁[k] implies S₁[k + 1] )
reconsider ARR = {[1,(FIB . ((2 * k) + 4))]} as FinSubsequence by Th17;
assume S₁[k] ; :: thesis: S₁[k + 1]
set LEFTk = EvenFibs ((2 * (k + 1)) + 2);
set RIGHTk = (EvenFibs (2 * (k + 1))) ^ <*(Fib ((2 * (k + 1)) + 2))*>;
reconsider RS = FIB | (EvenNAT /\ (Seg ((2 * k) + 2))) as FinSubsequence ;
set RR = Shift (ARR,((2 * k) + 3));
A2: (2 * k) + 3 > (2 * k) + 2 by XREAL_1:6;
( dom RS c= EvenNAT /\ (Seg ((2 * k) + 2)) & EvenNAT /\ (Seg ((2 * k) + 2)) c= Seg ((2 * k) + 2) ) by RELAT_1:58, XBOOLE_1:17;
then consider p1 being FinSequence such that
A3: RS c= p1 and
A4: dom p1 = Seg ((2 * k) + 3) by A2, Th19, XBOOLE_1:1;
A5: ex p2 being FinSequence st ARR c= p2 by Th20;
1 + ((2 * k) + 3) = (2 * k) + 4 ;
then A6: Shift (ARR,((2 * k) + 3)) = {[((2 * k) + 4),(FIB . ((2 * k) + 4))]} by Th18;
len p1 = (2 * k) + 3 by A4, FINSEQ_1:def 3;
then consider RSR being FinSubsequence such that
A7: RSR = RS \/ (Shift (ARR,((2 * k) + 3))) and
A8: (Seq RS) ^ (Seq ARR) = Seq RSR by A3, A5, VALUED_1:64;
(EvenFibs (2 * (k + 1))) ^ <*(Fib ((2 * (k + 1)) + 2))*> = (Seq (FIB | (EvenNAT /\ (Seg ((2 * k) + 2))))) ^ <*(FIB . ((2 * k) + 4))*> by Def2
.= Seq RSR by A8, FINSEQ_3:157
.= EvenFibs ((2 * (k + 1)) + 2) by A7, A6, Th58 ;
hence S₁[k + 1] ; :: thesis: verum

end;

A9: S₁[ 0 ] by Th21, Th53, Th55, FINSEQ_1:34;
for k being Nat holds S₁[k] from NAT_1:sch 2(A9, A1);
hence EvenFibs ((2 * n) + 2) = (EvenFibs (2 * n)) ^ <*(Fib ((2 * n) + 2))*> ; :: thesis: verum