let n be Nat; :: thesis: for Z being open Subset of REAL st Z c= dom ((#Z n) * sec) & 1 <= n holds
( (#Z n) * sec is_differentiable_on Z & ( for x being Real st x in Z holds
(((#Z n) * sec) `| Z) . x = (n * (sin . x)) / ((cos . x) #Z (n + 1)) ) )
let Z be open Subset of REAL; :: thesis: ( Z c= dom ((#Z n) * sec) & 1 <= n implies ( (#Z n) * sec is_differentiable_on Z & ( for x being Real st x in Z holds
(((#Z n) * sec) `| Z) . x = (n * (sin . x)) / ((cos . x) #Z (n + 1)) ) ) )
assume that
A1: Z c= dom ((#Z n) * sec) and
A2: 1 <= n ; :: thesis: ( (#Z n) * sec is_differentiable_on Z & ( for x being Real st x in Z holds
(((#Z n) * sec) `| Z) . x = (n * (sin . x)) / ((cos . x) #Z (n + 1)) ) )
dom ((#Z n) * sec) c= dom sec by RELAT_1:25;
then A3: Z c= dom sec by A1, XBOOLE_1:1;
A4: for x being Real st x in Z holds
cos . x <> 0

proof

let x be Real; :: thesis: ( x in Z implies cos . x <> 0 )
assume x in Z ; :: thesis: cos . x <> 0
then x in dom sec by A1, FUNCT_1:11;
hence cos . x <> 0 by RFUNCT_1:3; :: thesis: verum

end;

A5: for x being Real st x in Z holds
(#Z n) * sec is_differentiable_in x

proof

let x be Real; :: thesis: ( x in Z implies (#Z n) * sec is_differentiable_in x )
assume x in Z ; :: thesis: (#Z n) * sec is_differentiable_in x
then cos . x <> 0 by A4;
then sec is_differentiable_in x by Th1;
hence (#Z n) * sec is_differentiable_in x by TAYLOR_1:3; :: thesis: verum

end;

then A6: (#Z n) * sec is_differentiable_on Z by A1, FDIFF_1:9;
for x being Real st x in Z holds
(((#Z n) * sec) `| Z) . x = (n * (sin . x)) / ((cos . x) #Z (n + 1))

proof

set m = n - 1;
let x be Real; :: thesis: ( x in Z implies (((#Z n) * sec) `| Z) . x = (n * (sin . x)) / ((cos . x) #Z (n + 1)) )
A7: ex m being Nat st n = m + 1 by A2, NAT_1:6;
assume A8: x in Z ; :: thesis: (((#Z n) * sec) `| Z) . x = (n * (sin . x)) / ((cos . x) #Z (n + 1))
then A9: cos . x <> 0 by A4;
then A10: sec is_differentiable_in x by Th1;
(((#Z n) * sec) `| Z) . x = diff (((#Z n) * sec),x) by A6, A8, FDIFF_1:def 7
.= (n * ((sec . x) #Z (n - 1))) * (diff (sec,x)) by A10, TAYLOR_1:3
.= (n * ((sec . x) #Z (n - 1))) * ((sin . x) / ((cos . x) ^2)) by A9, Th1
.= (n * ((1 / (cos . x)) #Z (n - 1))) * ((sin . x) / ((cos . x) ^2)) by A3, A8, RFUNCT_1:def 2
.= (n * (1 / ((cos . x) #Z (n - 1)))) * ((sin . x) / ((cos . x) ^2)) by A7, Th3
.= (n / ((cos . x) #Z (n - 1))) * ((sin . x) / ((cos . x) ^2))
.= (n * (sin . x)) / (((cos . x) #Z (n - 1)) * ((cos . x) ^2)) by XCMPLX_1:76
.= (n * (sin . x)) / (((cos . x) #Z (n - 1)) * ((cos . x) #Z 2)) by FDIFF_7:1
.= (n * (sin . x)) / ((cos . x) #Z ((n - 1) + 2)) by A4, A8, PREPOWER:44
.= (n * (sin . x)) / ((cos . x) #Z (n + 1)) ;
hence (((#Z n) * sec) `| Z) . x = (n * (sin . x)) / ((cos . x) #Z (n + 1)) ; :: thesis: verum

end;

hence ( (#Z n) * sec is_differentiable_on Z & ( for x being Real st x in Z holds
(((#Z n) * sec) `| Z) . x = (n * (sin . x)) / ((cos . x) #Z (n + 1)) ) ) by A1, A5, FDIFF_1:9; :: thesis: verum