let Z be open Subset of REAL; :: thesis: ( Z c= dom (ln * cosec) implies ( ln * cosec is_differentiable_on Z & ( for x being Real st x in Z holds
((ln * cosec) `| Z) . x = - ((cos . x) / (sin . x)) ) ) )
assume A1: Z c= dom (ln * cosec) ; :: thesis: ( ln * cosec is_differentiable_on Z & ( for x being Real st x in Z holds
((ln * cosec) `| Z) . x = - ((cos . x) / (sin . x)) ) )
A2: for x being Real st x in Z holds
cosec . x > 0

proof

let x be Real; :: thesis: ( x in Z implies cosec . x > 0 )
assume x in Z ; :: thesis: cosec . x > 0
then cosec . x in right_open_halfline 0 by A1, FUNCT_1:11, TAYLOR_1:18;
then ex g being Real st
( cosec . x = g & 0 < g ) by Lm1;
hence cosec . x > 0 ; :: thesis: verum

end;

dom (ln * cosec) c= dom cosec by RELAT_1:25;
then A3: Z c= dom cosec by A1, XBOOLE_1:1;
A4: for x being Real st x in Z holds
sin . x <> 0

proof

let x be Real; :: thesis: ( x in Z implies sin . x <> 0 )
assume x in Z ; :: thesis: sin . x <> 0
then x in dom cosec by A1, FUNCT_1:11;
hence sin . x <> 0 by RFUNCT_1:3; :: thesis: verum

end;

A5: for x being Real st x in Z holds
cosec is_differentiable_in x

proof

let x be Real; :: thesis: ( x in Z implies cosec is_differentiable_in x )
assume x in Z ; :: thesis: cosec is_differentiable_in x
then sin . x <> 0 by A4;
hence cosec is_differentiable_in x by Th2; :: thesis: verum

end;

A6: for x being Real st x in Z holds
ln * cosec is_differentiable_in x

proof

let x be Real; :: thesis: ( x in Z implies ln * cosec is_differentiable_in x )
assume x in Z ; :: thesis: ln * cosec is_differentiable_in x
then ( cosec is_differentiable_in x & cosec . x > 0 ) by A2, A5;
hence ln * cosec is_differentiable_in x by TAYLOR_1:20; :: thesis: verum

end;

then A7: ln * cosec is_differentiable_on Z by A1, FDIFF_1:9;
for x being Real st x in Z holds
((ln * cosec) `| Z) . x = - ((cos . x) / (sin . x))

proof

let x be Real; :: thesis: ( x in Z implies ((ln * cosec) `| Z) . x = - ((cos . x) / (sin . x)) )
assume A8: x in Z ; :: thesis: ((ln * cosec) `| Z) . x = - ((cos . x) / (sin . x))
then A9: sin . x <> 0 by A4;
( cosec is_differentiable_in x & cosec . x > 0 ) by A2, A5, A8;
then diff ((ln * cosec),x) = (diff (cosec,x)) / (cosec . x) by TAYLOR_1:20
.= (- ((cos . x) / ((sin . x) ^2))) / (cosec . x) by A9, Th2
.= (- ((cos . x) / ((sin . x) ^2))) / ((sin . x) ") by A3, A8, RFUNCT_1:def 2
.= ((- (cos . x)) * (sin . x)) / ((sin . x) * (sin . x))
.= (- (cos . x)) / (sin . x) by A4, A8, XCMPLX_1:91 ;
hence ((ln * cosec) `| Z) . x = - ((cos . x) / (sin . x)) by A7, A8, FDIFF_1:def 7; :: thesis: verum

end;

hence ( ln * cosec is_differentiable_on Z & ( for x being Real st x in Z holds
((ln * cosec) `| Z) . x = - ((cos . x) / (sin . x)) ) ) by A1, A6, FDIFF_1:9; :: thesis: verum