let Z be open Subset of REAL; :: thesis: ( Z c= dom (sec * ln) implies ( sec * ln is_differentiable_on Z & ( for x being Real st x in Z holds
((sec * ln) `| Z) . x = (sin . (ln . x)) / (x * ((cos . (ln . x)) ^2)) ) ) )
assume A1: Z c= dom (sec * ln) ; :: thesis: ( sec * ln is_differentiable_on Z & ( for x being Real st x in Z holds
((sec * ln) `| Z) . x = (sin . (ln . x)) / (x * ((cos . (ln . x)) ^2)) ) )
dom (sec * ln) c= dom ln by RELAT_1:25;
then A2: Z c= dom ln by A1, XBOOLE_1:1;
A3: for x being Real st x in Z holds
x > 0

proof

let x be Real; :: thesis: ( x in Z implies x > 0 )
assume x in Z ; :: thesis: x > 0
then x in right_open_halfline 0 by A2, TAYLOR_1:18;
then ex g being Real st
( x = g & 0 < g ) by Lm1;
hence x > 0 ; :: thesis: verum

end;

A4: for x being Real st x in Z holds
diff (ln,x) = 1 / x

proof

let x be Real; :: thesis: ( x in Z implies diff (ln,x) = 1 / x )
assume x in Z ; :: thesis: diff (ln,x) = 1 / x
then x > 0 by A3;
then x in right_open_halfline 0 by Lm1;
hence diff (ln,x) = 1 / x by TAYLOR_1:18; :: thesis: verum

end;

A5: for x being Real st x in Z holds
cos . (ln . x) <> 0

proof

let x be Real; :: thesis: ( x in Z implies cos . (ln . x) <> 0 )
assume x in Z ; :: thesis: cos . (ln . x) <> 0
then ln . x in dom sec by A1, FUNCT_1:11;
hence cos . (ln . x) <> 0 by RFUNCT_1:3; :: thesis: verum

end;

A6: for x being Real st x in Z holds
sec * ln is_differentiable_in x

proof

let x be Real; :: thesis: ( x in Z implies sec * ln is_differentiable_in x )
assume A7: x in Z ; :: thesis: sec * ln is_differentiable_in x
then cos . (ln . x) <> 0 by A5;
then A8: sec is_differentiable_in ln . x by Th1;
ln is_differentiable_in x by A3, A7, TAYLOR_1:18;
hence sec * ln is_differentiable_in x by A8, FDIFF_2:13; :: thesis: verum

end;

then A9: sec * ln is_differentiable_on Z by A1, FDIFF_1:9;
for x being Real st x in Z holds
((sec * ln) `| Z) . x = (sin . (ln . x)) / (x * ((cos . (ln . x)) ^2))

proof

let x be Real; :: thesis: ( x in Z implies ((sec * ln) `| Z) . x = (sin . (ln . x)) / (x * ((cos . (ln . x)) ^2)) )
assume A10: x in Z ; :: thesis: ((sec * ln) `| Z) . x = (sin . (ln . x)) / (x * ((cos . (ln . x)) ^2))
then A11: ln is_differentiable_in x by A3, TAYLOR_1:18;
A12: cos . (ln . x) <> 0 by A5, A10;
then sec is_differentiable_in ln . x by Th1;
then diff ((sec * ln),x) = (diff (sec,(ln . x))) * (diff (ln,x)) by A11, FDIFF_2:13
.= ((sin . (ln . x)) / ((cos . (ln . x)) ^2)) * (diff (ln,x)) by A12, Th1
.= (1 / x) * ((sin . (ln . x)) / ((cos . (ln . x)) ^2)) by A4, A10
.= (1 * (sin . (ln . x))) / (x * ((cos . (ln . x)) ^2)) by XCMPLX_1:76 ;
hence ((sec * ln) `| Z) . x = (sin . (ln . x)) / (x * ((cos . (ln . x)) ^2)) by A9, A10, FDIFF_1:def 7; :: thesis: verum

end;

hence ( sec * ln is_differentiable_on Z & ( for x being Real st x in Z holds
((sec * ln) `| Z) . x = (sin . (ln . x)) / (x * ((cos . (ln . x)) ^2)) ) ) by A1, A6, FDIFF_1:9; :: thesis: verum