let Z be open Subset of REAL; :: thesis: ( Z c= dom (tan - (id Z)) implies ( tan - (id Z) is_differentiable_on Z & ( for x being Real st x in Z holds
((tan - (id Z)) `| Z) . x = ((sin . x) ^2) / ((cos . x) ^2) ) ) )
A1: for x being Real st x in Z holds
(id Z) . x = (1 * x) + 0 by FUNCT_1:18;
assume A2: Z c= dom (tan - (id Z)) ; :: thesis: ( tan - (id Z) is_differentiable_on Z & ( for x being Real st x in Z holds
((tan - (id Z)) `| Z) . x = ((sin . x) ^2) / ((cos . x) ^2) ) )
then A3: Z c= (dom tan) /\ (dom (id Z)) by VALUED_1:12;
then A4: Z c= dom tan by XBOOLE_1:18;
A5: Z c= dom (id Z) by A3, XBOOLE_1:18;
then A6: id Z is_differentiable_on Z by A1, FDIFF_1:23;
for x being Real st x in Z holds
tan is_differentiable_in x

proof

let x be Real; :: thesis: ( x in Z implies tan is_differentiable_in x )
assume x in Z ; :: thesis: tan is_differentiable_in x
then cos . x <> 0 by A4, Th1;
hence tan is_differentiable_in x by FDIFF_7:46; :: thesis: verum

end;

then A7: tan is_differentiable_on Z by A4, FDIFF_1:9;
for x being Real st x in Z holds
((tan - (id Z)) `| Z) . x = ((sin . x) ^2) / ((cos . x) ^2)

proof

let x be Real; :: thesis: ( x in Z implies ((tan - (id Z)) `| Z) . x = ((sin . x) ^2) / ((cos . x) ^2) )
assume A8: x in Z ; :: thesis: ((tan - (id Z)) `| Z) . x = ((sin . x) ^2) / ((cos . x) ^2)
then A9: cos . x <> 0 by A4, Th1;
then A10: (cos . x) ^2 > 0 by SQUARE_1:12;
((tan - (id Z)) `| Z) . x = (diff (tan,x)) - (diff ((id Z),x)) by A2, A6, A7, A8, FDIFF_1:19
.= (1 / ((cos . x) ^2)) - (diff ((id Z),x)) by A9, FDIFF_7:46
.= (1 / ((cos . x) ^2)) - (((id Z) `| Z) . x) by A6, A8, FDIFF_1:def 7
.= (1 / ((cos . x) ^2)) - 1 by A5, A1, A8, FDIFF_1:23
.= (1 / ((cos . x) ^2)) - (((cos . x) ^2) / ((cos . x) ^2)) by A10, XCMPLX_1:60
.= (1 - ((cos . x) ^2)) / ((cos . x) ^2)
.= ((((sin . x) ^2) + ((cos . x) ^2)) - ((cos . x) ^2)) / ((cos . x) ^2) by SIN_COS:28
.= ((sin . x) ^2) / ((cos . x) ^2) ;
hence ((tan - (id Z)) `| Z) . x = ((sin . x) ^2) / ((cos . x) ^2) ; :: thesis: verum

end;

hence ( tan - (id Z) is_differentiable_on Z & ( for x being Real st x in Z holds
((tan - (id Z)) `| Z) . x = ((sin . x) ^2) / ((cos . x) ^2) ) ) by A2, A6, A7, FDIFF_1:19; :: thesis: verum