let Z be open Subset of REAL; :: thesis: ( Z c= dom (tan + (cos ^)) & ( for x being Real st x in Z holds
( 1 + (sin . x) <> 0 & 1 - (sin . x) <> 0 ) ) implies ( tan + (cos ^) is_differentiable_on Z & ( for x being Real st x in Z holds
((tan + (cos ^)) `| Z) . x = 1 / (1 - (sin . x)) ) ) )
assume that
A1: Z c= dom (tan + (cos ^)) and
A2: for x being Real st x in Z holds
( 1 + (sin . x) <> 0 & 1 - (sin . x) <> 0 ) ; :: thesis: ( tan + (cos ^) is_differentiable_on Z & ( for x being Real st x in Z holds
((tan + (cos ^)) `| Z) . x = 1 / (1 - (sin . x)) ) )
Z c= (dom tan) /\ (dom (cos ^)) by A1, VALUED_1:def 1;
then A3: Z c= dom tan by XBOOLE_1:18;
then A4: for x being Real st x in Z holds
cos . x <> 0 by Th1;
then A5: cos ^ is_differentiable_on Z by FDIFF_4:39;
for x being Real st x in Z holds
tan is_differentiable_in x

proof

let x be Real; :: thesis: ( x in Z implies tan is_differentiable_in x )
assume x in Z ; :: thesis: tan is_differentiable_in x
then cos . x <> 0 by A3, Th1;
hence tan is_differentiable_in x by FDIFF_7:46; :: thesis: verum

end;

then A6: tan is_differentiable_on Z by A3, FDIFF_1:9;
for x being Real st x in Z holds
((tan + (cos ^)) `| Z) . x = 1 / (1 - (sin . x))

proof

let x be Real; :: thesis: ( x in Z implies ((tan + (cos ^)) `| Z) . x = 1 / (1 - (sin . x)) )
assume A7: x in Z ; :: thesis: ((tan + (cos ^)) `| Z) . x = 1 / (1 - (sin . x))
then A8: 1 + (sin . x) <> 0 by A2;
A9: cos . x <> 0 by A3, A7, Th1;
((tan + (cos ^)) `| Z) . x = (diff (tan,x)) + (diff ((cos ^),x)) by A1, A5, A6, A7, FDIFF_1:18
.= (1 / ((cos . x) ^2)) + (diff ((cos ^),x)) by A9, FDIFF_7:46
.= (1 / ((cos . x) ^2)) + (((cos ^) `| Z) . x) by A5, A7, FDIFF_1:def 7
.= (1 / ((cos . x) ^2)) + ((sin . x) / ((cos . x) ^2)) by A4, A7, FDIFF_4:39
.= (1 + (sin . x)) / ((((cos . x) ^2) + ((sin . x) ^2)) - ((sin . x) ^2))
.= (1 + (sin . x)) / (1 - ((sin . x) ^2)) by SIN_COS:28
.= (1 + (sin . x)) / ((1 + (sin . x)) * (1 - (sin . x)))
.= ((1 + (sin . x)) / (1 + (sin . x))) / (1 - (sin . x)) by XCMPLX_1:78
.= 1 / (1 - (sin . x)) by A8, XCMPLX_1:60 ;
hence ((tan + (cos ^)) `| Z) . x = 1 / (1 - (sin . x)) ; :: thesis: verum

end;

hence ( tan + (cos ^) is_differentiable_on Z & ( for x being Real st x in Z holds
((tan + (cos ^)) `| Z) . x = 1 / (1 - (sin . x)) ) ) by A1, A5, A6, FDIFF_1:18; :: thesis: verum