let Z be open Subset of REAL; :: thesis: ( Z c= dom (tan * ln) implies ( tan * ln is_differentiable_on Z & ( for x being Real st x in Z holds
((tan * ln) `| Z) . x = 1 / (x * ((cos . (ln . x)) ^2)) ) ) )
assume A1: Z c= dom (tan * ln) ; :: thesis: ( tan * ln is_differentiable_on Z & ( for x being Real st x in Z holds
((tan * ln) `| Z) . x = 1 / (x * ((cos . (ln . x)) ^2)) ) )
dom (tan * ln) c= dom ln by RELAT_1:25;
then A2: Z c= dom ln by A1, XBOOLE_1:1;
A3: for x being Real st x in Z holds
x > 0

proof

let x be Real; :: thesis: ( x in Z implies x > 0 )
assume x in Z ; :: thesis: x > 0
then x in right_open_halfline 0 by A2, TAYLOR_1:18;
then ex g being Real st
( x = g & 0 < g ) by Lm1;
hence x > 0 ; :: thesis: verum

end;

A4: for x being Real st x in Z holds
diff (ln,x) = 1 / x

proof

let x be Real; :: thesis: ( x in Z implies diff (ln,x) = 1 / x )
assume x in Z ; :: thesis: diff (ln,x) = 1 / x
then x > 0 by A3;
then x in right_open_halfline 0 by Lm1;
hence diff (ln,x) = 1 / x by TAYLOR_1:18; :: thesis: verum

end;

A5: for x being Real st x in Z holds
cos . (ln . x) <> 0

proof

let x be Real; :: thesis: ( x in Z implies cos . (ln . x) <> 0 )
assume x in Z ; :: thesis: cos . (ln . x) <> 0
then ln . x in dom (sin / cos) by A1, FUNCT_1:11;
hence cos . (ln . x) <> 0 by Th1; :: thesis: verum

end;

A6: for x being Real st x in Z holds
tan * ln is_differentiable_in x

proof

let x be Real; :: thesis: ( x in Z implies tan * ln is_differentiable_in x )
assume A7: x in Z ; :: thesis: tan * ln is_differentiable_in x
then cos . (ln . x) <> 0 by A5;
then A8: tan is_differentiable_in ln . x by FDIFF_7:46;
ln is_differentiable_in x by A3, A7, TAYLOR_1:18;
hence tan * ln is_differentiable_in x by A8, FDIFF_2:13; :: thesis: verum

end;

then A9: tan * ln is_differentiable_on Z by A1, FDIFF_1:9;
for x being Real st x in Z holds
((tan * ln) `| Z) . x = 1 / (x * ((cos . (ln . x)) ^2))

proof

let x be Real; :: thesis: ( x in Z implies ((tan * ln) `| Z) . x = 1 / (x * ((cos . (ln . x)) ^2)) )
assume A10: x in Z ; :: thesis: ((tan * ln) `| Z) . x = 1 / (x * ((cos . (ln . x)) ^2))
then A11: ln is_differentiable_in x by A3, TAYLOR_1:18;
A12: cos . (ln . x) <> 0 by A5, A10;
then tan is_differentiable_in ln . x by FDIFF_7:46;
then diff ((tan * ln),x) = (diff (tan,(ln . x))) * (diff (ln,x)) by A11, FDIFF_2:13
.= (1 / ((cos . (ln . x)) ^2)) * (diff (ln,x)) by A12, FDIFF_7:46
.= (1 / x) / ((cos . (ln . x)) ^2) by A4, A10
.= 1 / (x * ((cos . (ln . x)) ^2)) by XCMPLX_1:78 ;
hence ((tan * ln) `| Z) . x = 1 / (x * ((cos . (ln . x)) ^2)) by A9, A10, FDIFF_1:def 7; :: thesis: verum

end;

hence ( tan * ln is_differentiable_on Z & ( for x being Real st x in Z holds
((tan * ln) `| Z) . x = 1 / (x * ((cos . (ln . x)) ^2)) ) ) by A1, A6, FDIFF_1:9; :: thesis: verum