let Z be open Subset of REAL; :: thesis: for f being PartFunc of REAL,REAL st Z c= dom ((sin / cos) * f) & ( for x being Real st x in Z holds
( f . x = x / 2 & cos . (f . x) <> 0 ) ) holds
( (sin / cos) * f is_differentiable_on Z & ( for x being Real st x in Z holds
(((sin / cos) * f) `| Z) . x = 1 / (1 + (cos . x)) ) )
let f be PartFunc of REAL,REAL; :: thesis: ( Z c= dom ((sin / cos) * f) & ( for x being Real st x in Z holds
( f . x = x / 2 & cos . (f . x) <> 0 ) ) implies ( (sin / cos) * f is_differentiable_on Z & ( for x being Real st x in Z holds
(((sin / cos) * f) `| Z) . x = 1 / (1 + (cos . x)) ) ) )
assume that
A1: Z c= dom ((sin / cos) * f) and
A2: for x being Real st x in Z holds
( f . x = x / 2 & cos . (f . x) <> 0 ) ; :: thesis: ( (sin / cos) * f is_differentiable_on Z & ( for x being Real st x in Z holds
(((sin / cos) * f) `| Z) . x = 1 / (1 + (cos . x)) ) )
A3: for x being Real st x in Z holds
f . x = ((1 / 2) * x) + 0

proof

let x be Real; :: thesis: ( x in Z implies f . x = ((1 / 2) * x) + 0 )
assume x in Z ; :: thesis: f . x = ((1 / 2) * x) + 0
then f . x = x / 2 by A2;
hence f . x = ((1 / 2) * x) + 0 ; :: thesis: verum

end;

for y being object st y in Z holds
y in dom f by A1, FUNCT_1:11;
then A4: Z c= dom f by TARSKI:def 3;
then A5: f is_differentiable_on Z by A3, FDIFF_1:23;
A6: for x being Real st x in Z holds
(sin / cos) * f is_differentiable_in x

proof

let x be Real; :: thesis: ( x in Z implies (sin / cos) * f is_differentiable_in x )
assume A7: x in Z ; :: thesis: (sin / cos) * f is_differentiable_in x
then cos . (f . x) <> 0 by A2;
then A8: sin / cos is_differentiable_in f . x by Th46;
f is_differentiable_in x by A5, A7, FDIFF_1:9;
hence (sin / cos) * f is_differentiable_in x by A8, FDIFF_2:13; :: thesis: verum

end;

then A9: (sin / cos) * f is_differentiable_on Z by A1, FDIFF_1:9;
for x being Real st x in Z holds
(((sin / cos) * f) `| Z) . x = 1 / (1 + (cos . x))

proof

let x be Real; :: thesis: ( x in Z implies (((sin / cos) * f) `| Z) . x = 1 / (1 + (cos . x)) )
assume A10: x in Z ; :: thesis: (((sin / cos) * f) `| Z) . x = 1 / (1 + (cos . x))
then A11: f is_differentiable_in x by A5, FDIFF_1:9;
A12: cos . (f . x) <> 0 by A2, A10;
then sin / cos is_differentiable_in f . x by Th46;
then diff (((sin / cos) * f),x) = (diff ((sin / cos),(f . x))) * (diff (f,x)) by A11, FDIFF_2:13
.= (1 / ((cos . (f . x)) ^2)) * (diff (f,x)) by A12, Th46
.= (diff (f,x)) / ((cos . (f . x)) ^2) by XCMPLX_1:99
.= (diff (f,x)) / ((cos . (x / 2)) ^2) by A2, A10
.= ((f `| Z) . x) / ((cos . (x / 2)) ^2) by A5, A10, FDIFF_1:def 7
.= (1 / 2) / ((cos . (x / 2)) ^2) by A3, A4, A10, FDIFF_1:23
.= 1 / (2 * ((cos . (x / 2)) ^2)) by XCMPLX_1:78
.= 1 / (1 + (cos . x)) by Lm1 ;
hence (((sin / cos) * f) `| Z) . x = 1 / (1 + (cos . x)) by A9, A10, FDIFF_1:def 7; :: thesis: verum

end;

hence ( (sin / cos) * f is_differentiable_on Z & ( for x being Real st x in Z holds
(((sin / cos) * f) `| Z) . x = 1 / (1 + (cos . x)) ) ) by A1, A6, FDIFF_1:9; :: thesis: verum