let Z be open Subset of REAL; :: thesis: ( Z c= dom ((#Z 2) * (cos / sin)) & ( for x being Real st x in Z holds
sin . x <> 0 ) implies ( (#Z 2) * (cos / sin) is_differentiable_on Z & ( for x being Real st x in Z holds
(((#Z 2) * (cos / sin)) `| Z) . x = - ((2 * (cos . x)) / ((sin . x) #Z 3)) ) ) )
assume that
A1: Z c= dom ((#Z 2) * (cos / sin)) and
A2: for x being Real st x in Z holds
sin . x <> 0 ; :: thesis: ( (#Z 2) * (cos / sin) is_differentiable_on Z & ( for x being Real st x in Z holds
(((#Z 2) * (cos / sin)) `| Z) . x = - ((2 * (cos . x)) / ((sin . x) #Z 3)) ) )
for y being object st y in Z holds
y in dom (cos / sin) by A1, FUNCT_1:11;
then A3: Z c= dom (cos / sin) by TARSKI:def 3;
A4: for x being Real st x in Z holds
(#Z 2) * (cos / sin) is_differentiable_in x

proof

let x be Real; :: thesis: ( x in Z implies (#Z 2) * (cos / sin) is_differentiable_in x )
assume x in Z ; :: thesis: (#Z 2) * (cos / sin) is_differentiable_in x
then sin . x <> 0 by A2;
then cos / sin is_differentiable_in x by Th47;
hence (#Z 2) * (cos / sin) is_differentiable_in x by TAYLOR_1:3; :: thesis: verum

end;

then A5: (#Z 2) * (cos / sin) is_differentiable_on Z by A1, FDIFF_1:9;
for x being Real st x in Z holds
(((#Z 2) * (cos / sin)) `| Z) . x = - ((2 * (cos . x)) / ((sin . x) #Z 3))

proof

let x be Real; :: thesis: ( x in Z implies (((#Z 2) * (cos / sin)) `| Z) . x = - ((2 * (cos . x)) / ((sin . x) #Z 3)) )
assume A6: x in Z ; :: thesis: (((#Z 2) * (cos / sin)) `| Z) . x = - ((2 * (cos . x)) / ((sin . x) #Z 3))
then A7: (cos / sin) . x = (cos . x) * ((sin . x) ") by A3, RFUNCT_1:def 1
.= (cos . x) * (1 / (sin . x)) by XCMPLX_1:215
.= (cos . x) / (sin . x) by XCMPLX_1:99 ;
A8: sin . x <> 0 by A2, A6;
then A9: cos / sin is_differentiable_in x by Th47;
(((#Z 2) * (cos / sin)) `| Z) . x = diff (((#Z 2) * (cos / sin)),x) by A5, A6, FDIFF_1:def 7
.= (2 * (((cos / sin) . x) #Z (2 - 1))) * (diff ((cos / sin),x)) by A9, TAYLOR_1:3
.= (2 * (((cos / sin) . x) #Z (2 - 1))) * (- (1 / ((sin . x) ^2))) by A8, Th47
.= - ((2 * (((cos / sin) . x) #Z (2 - 1))) * (1 / ((sin . x) ^2)))
.= - ((2 * (((cos / sin) . x) #Z 1)) / ((sin . x) ^2)) by XCMPLX_1:99
.= - ((2 * ((cos . x) / (sin . x))) / ((sin . x) ^2)) by A7, PREPOWER:35
.= - (((2 * (cos . x)) / (sin . x)) / ((sin . x) ^2)) by XCMPLX_1:74
.= - ((2 * (cos . x)) / ((sin . x) * ((sin . x) ^2))) by XCMPLX_1:78
.= - ((2 * (cos . x)) / ((sin . x) * ((sin . x) #Z 2))) by Th1
.= - ((2 * (cos . x)) / (((sin . x) #Z 1) * ((sin . x) #Z 2))) by PREPOWER:35
.= - ((2 * (cos . x)) / ((sin . x) #Z (1 + 2))) by A2, A6, PREPOWER:44
.= - ((2 * (cos . x)) / ((sin . x) #Z 3)) ;
hence (((#Z 2) * (cos / sin)) `| Z) . x = - ((2 * (cos . x)) / ((sin . x) #Z 3)) ; :: thesis: verum

end;

hence ( (#Z 2) * (cos / sin) is_differentiable_on Z & ( for x being Real st x in Z holds
(((#Z 2) * (cos / sin)) `| Z) . x = - ((2 * (cos . x)) / ((sin . x) #Z 3)) ) ) by A1, A4, FDIFF_1:9; :: thesis: verum