let Z be open Subset of REAL; :: thesis: for f, f1 being PartFunc of REAL,REAL st Z c= dom ((1 / 2) (#) (ln * f)) & f = f1 + (2 (#) sin) & ( for x being Real st x in Z holds
( f1 . x = 1 & f . x > 0 ) ) holds
( (1 / 2) (#) (ln * f) is_differentiable_on Z & ( for x being Real st x in Z holds
(((1 / 2) (#) (ln * f)) `| Z) . x = (cos . x) / (1 + (2 * (sin . x))) ) )
let f, f1 be PartFunc of REAL,REAL; :: thesis: ( Z c= dom ((1 / 2) (#) (ln * f)) & f = f1 + (2 (#) sin) & ( for x being Real st x in Z holds
( f1 . x = 1 & f . x > 0 ) ) implies ( (1 / 2) (#) (ln * f) is_differentiable_on Z & ( for x being Real st x in Z holds
(((1 / 2) (#) (ln * f)) `| Z) . x = (cos . x) / (1 + (2 * (sin . x))) ) ) )
assume that
A1: Z c= dom ((1 / 2) (#) (ln * f)) and
A2: f = f1 + (2 (#) sin) and
A3: for x being Real st x in Z holds
( f1 . x = 1 & f . x > 0 ) ; :: thesis: ( (1 / 2) (#) (ln * f) is_differentiable_on Z & ( for x being Real st x in Z holds
(((1 / 2) (#) (ln * f)) `| Z) . x = (cos . x) / (1 + (2 * (sin . x))) ) )
A4: Z c= dom (ln * f) by A1, VALUED_1:def 5;
then for y being object st y in Z holds
y in dom f by FUNCT_1:11;
then A5: Z c= dom (f1 + (2 (#) sin)) by A2, TARSKI:def 3;
A6: for x being Real st x in Z holds
f1 . x = 1 by A3;
then A7: f is_differentiable_on Z by A2, A5, Lm6;
for x being Real st x in Z holds
ln * f is_differentiable_in x

proof

let x be Real; :: thesis: ( x in Z implies ln * f is_differentiable_in x )
assume x in Z ; :: thesis: ln * f is_differentiable_in x
then ( f is_differentiable_in x & f . x > 0 ) by A3, A7, FDIFF_1:9;
hence ln * f is_differentiable_in x by TAYLOR_1:20; :: thesis: verum

end;

then A8: ln * f is_differentiable_on Z by A4, FDIFF_1:9;
Z c= (dom f1) /\ (dom (2 (#) sin)) by A5, VALUED_1:def 1;
then A9: Z c= dom (2 (#) sin) by XBOOLE_1:18;
for x being Real st x in Z holds
(((1 / 2) (#) (ln * f)) `| Z) . x = (cos . x) / (1 + (2 * (sin . x)))

proof

let x be Real; :: thesis: ( x in Z implies (((1 / 2) (#) (ln * f)) `| Z) . x = (cos . x) / (1 + (2 * (sin . x))) )
assume A10: x in Z ; :: thesis: (((1 / 2) (#) (ln * f)) `| Z) . x = (cos . x) / (1 + (2 * (sin . x)))
then A11: f . x = (f1 . x) + ((2 (#) sin) . x) by A2, A5, VALUED_1:def 1
.= 1 + ((2 (#) sin) . x) by A3, A10
.= 1 + (2 * (sin . x)) by A9, A10, VALUED_1:def 5 ;
A12: ( f is_differentiable_in x & f . x > 0 ) by A3, A7, A10, FDIFF_1:9;
(((1 / 2) (#) (ln * f)) `| Z) . x = (1 / 2) * (diff ((ln * f),x)) by A1, A8, A10, FDIFF_1:20
.= (1 / 2) * ((diff (f,x)) / (f . x)) by A12, TAYLOR_1:20
.= (1 / 2) * (((f `| Z) . x) / (f . x)) by A7, A10, FDIFF_1:def 7
.= (1 / 2) * ((2 * (cos . x)) / (f . x)) by A2, A6, A5, A10, Lm6
.= ((1 / 2) * (2 * (cos . x))) / (f . x) by XCMPLX_1:74
.= (cos . x) / (1 + (2 * (sin . x))) by A11 ;
hence (((1 / 2) (#) (ln * f)) `| Z) . x = (cos . x) / (1 + (2 * (sin . x))) ; :: thesis: verum

end;

hence ( (1 / 2) (#) (ln * f) is_differentiable_on Z & ( for x being Real st x in Z holds
(((1 / 2) (#) (ln * f)) `| Z) . x = (cos . x) / (1 + (2 * (sin . x))) ) ) by A1, A8, FDIFF_1:20; :: thesis: verum