let n be Element of NAT ; :: thesis: for Z being open Subset of REAL st Z c= dom (ln * (#Z n)) & ( for x being Real st x in Z holds
x > 0 ) holds
( ln * (#Z n) is_differentiable_on Z & ( for x being Real st x in Z holds
((ln * (#Z n)) `| Z) . x = n / x ) )
let Z be open Subset of REAL; :: thesis: ( Z c= dom (ln * (#Z n)) & ( for x being Real st x in Z holds
x > 0 ) implies ( ln * (#Z n) is_differentiable_on Z & ( for x being Real st x in Z holds
((ln * (#Z n)) `| Z) . x = n / x ) ) )
assume that
A1: Z c= dom (ln * (#Z n)) and
A2: for x being Real st x in Z holds
x > 0 ; :: thesis: ( ln * (#Z n) is_differentiable_on Z & ( for x being Real st x in Z holds
((ln * (#Z n)) `| Z) . x = n / x ) )
A3: for x being Real st x in Z holds
ln * (#Z n) is_differentiable_in x

proof

let x be Real; :: thesis: ( x in Z implies ln * (#Z n) is_differentiable_in x )
A4: (#Z n) . x = x #Z n by TAYLOR_1:def 1;
assume x in Z ; :: thesis: ln * (#Z n) is_differentiable_in x
then ( #Z n is_differentiable_in x & (#Z n) . x > 0 ) by A2, A4, PREPOWER:39, TAYLOR_1:2;
hence ln * (#Z n) is_differentiable_in x by TAYLOR_1:20; :: thesis: verum

end;

then A5: ln * (#Z n) is_differentiable_on Z by A1, FDIFF_1:9;
for x being Real st x in Z holds
((ln * (#Z n)) `| Z) . x = n / x

proof

let x be Real; :: thesis: ( x in Z implies ((ln * (#Z n)) `| Z) . x = n / x )
A6: ( #Z n is_differentiable_in x & diff ((#Z n),x) = n * (x #Z (n - 1)) ) by TAYLOR_1:2;
assume A7: x in Z ; :: thesis: ((ln * (#Z n)) `| Z) . x = n / x
then A8: x > 0 by A2;
A9: x |^ n > 0 by A2, A7, NEWTON:83;
A10: (#Z n) . x = x #Z n by TAYLOR_1:def 1;
then (#Z n) . x > 0 by A2, A7, PREPOWER:39;
then diff ((ln * (#Z n)),x) = (n * (x #Z (n - 1))) / (x #Z n) by A6, A10, TAYLOR_1:20
.= (n * (x #Z (n - 1))) / (x |^ n) by PREPOWER:36
.= (n * ((x |^ n) / (x |^ 1))) / (x |^ n) by A8, PREPOWER:43
.= n * (((x |^ n) / (x |^ 1)) / (x |^ n)) by XCMPLX_1:74
.= n * (((x |^ n) / (x |^ n)) / (x |^ 1)) by XCMPLX_1:48
.= n * (1 / (x |^ 1)) by A9, XCMPLX_1:60
.= n * (1 / x)
.= (n * 1) / x by XCMPLX_1:74
.= n / x ;
hence ((ln * (#Z n)) `| Z) . x = n / x by A5, A7, FDIFF_1:def 7; :: thesis: verum

end;

hence ( ln * (#Z n) is_differentiable_on Z & ( for x being Real st x in Z holds
((ln * (#Z n)) `| Z) . x = n / x ) ) by A1, A3, FDIFF_1:9; :: thesis: verum