let Z be open Subset of REAL; :: thesis: for f being PartFunc of REAL,REAL st Z c= dom (ln * ((exp_R - f) / exp_R)) & ( for x being Real st x in Z holds
( f . x = 1 & (exp_R - f) . x > 0 ) ) holds
( ln * ((exp_R - f) / exp_R) is_differentiable_on Z & ( for x being Real st x in Z holds
((ln * ((exp_R - f) / exp_R)) `| Z) . x = 1 / ((exp_R . x) - 1) ) )
let f be PartFunc of REAL,REAL; :: thesis: ( Z c= dom (ln * ((exp_R - f) / exp_R)) & ( for x being Real st x in Z holds
( f . x = 1 & (exp_R - f) . x > 0 ) ) implies ( ln * ((exp_R - f) / exp_R) is_differentiable_on Z & ( for x being Real st x in Z holds
((ln * ((exp_R - f) / exp_R)) `| Z) . x = 1 / ((exp_R . x) - 1) ) ) )
assume that
A1: Z c= dom (ln * ((exp_R - f) / exp_R)) and
A2: for x being Real st x in Z holds
( f . x = 1 & (exp_R - f) . x > 0 ) ; :: thesis: ( ln * ((exp_R - f) / exp_R) is_differentiable_on Z & ( for x being Real st x in Z holds
((ln * ((exp_R - f) / exp_R)) `| Z) . x = 1 / ((exp_R . x) - 1) ) )
A3: for x being Real st x in Z holds
f . x = (0 * x) + 1 by A2;
for y being object st y in Z holds
y in dom ((exp_R - f) / exp_R) by A1, FUNCT_1:11;
then Z c= dom ((exp_R - f) / exp_R) by TARSKI:def 3;
then Z c= (dom (exp_R - f)) /\ ((dom exp_R) \ (exp_R " {0})) by RFUNCT_1:def 1;
then A4: Z c= dom (exp_R - f) by XBOOLE_1:18;
then Z c= (dom exp_R) /\ (dom f) by VALUED_1:12;
then A5: Z c= dom f by XBOOLE_1:18;
then A6: f is_differentiable_on Z by A3, FDIFF_1:23;
A7: exp_R is_differentiable_on Z by FDIFF_1:26, TAYLOR_1:16;
then A8: exp_R - f is_differentiable_on Z by A4, A6, FDIFF_1:19;
for x being Real st x in Z holds
exp_R . x <> 0 by SIN_COS:54;
then A9: (exp_R - f) / exp_R is_differentiable_on Z by A7, A8, FDIFF_2:21;
A10: for x being Real st x in Z holds
((exp_R - f) `| Z) . x = exp_R . x

proof

let x be Real; :: thesis: ( x in Z implies ((exp_R - f) `| Z) . x = exp_R . x )
assume A11: x in Z ; :: thesis: ((exp_R - f) `| Z) . x = exp_R . x
hence ((exp_R - f) `| Z) . x = (diff (exp_R,x)) - (diff (f,x)) by A4, A6, A7, FDIFF_1:19
.= (exp_R . x) - (diff (f,x)) by SIN_COS:65
.= (exp_R . x) - ((f `| Z) . x) by A6, A11, FDIFF_1:def 7
.= (exp_R . x) - 0 by A5, A3, A11, FDIFF_1:23
.= exp_R . x ;
:: thesis: verum

end;

A12: for x being Real st x in Z holds
(((exp_R - f) / exp_R) `| Z) . x = 1 / (exp_R . x)

proof

let x be Real; :: thesis: ( x in Z implies (((exp_R - f) / exp_R) `| Z) . x = 1 / (exp_R . x) )
A13: exp_R . x <> 0 by SIN_COS:54;
assume A14: x in Z ; :: thesis: (((exp_R - f) / exp_R) `| Z) . x = 1 / (exp_R . x)
then A15: (exp_R - f) . x = (exp_R . x) - (f . x) by A4, VALUED_1:13
.= (exp_R . x) - 1 by A2, A14 ;
( exp_R is_differentiable_in x & exp_R - f is_differentiable_in x ) by A8, A14, FDIFF_1:9, SIN_COS:65;
then diff (((exp_R - f) / exp_R),x) = (((diff ((exp_R - f),x)) * (exp_R . x)) - ((diff (exp_R,x)) * ((exp_R - f) . x))) / ((exp_R . x) ^2) by A13, FDIFF_2:14
.= (((((exp_R - f) `| Z) . x) * (exp_R . x)) - ((diff (exp_R,x)) * ((exp_R - f) . x))) / ((exp_R . x) ^2) by A8, A14, FDIFF_1:def 7
.= (((exp_R . x) * (exp_R . x)) - ((diff (exp_R,x)) * ((exp_R - f) . x))) / ((exp_R . x) ^2) by A10, A14
.= (((exp_R . x) * (exp_R . x)) - ((exp_R . x) * ((exp_R . x) - 1))) / ((exp_R . x) ^2) by A15, SIN_COS:65
.= ((exp_R . x) / (exp_R . x)) / (exp_R . x) by XCMPLX_1:78
.= 1 / (exp_R . x) by A13, XCMPLX_1:60 ;
hence (((exp_R - f) / exp_R) `| Z) . x = 1 / (exp_R . x) by A9, A14, FDIFF_1:def 7; :: thesis: verum

end;

A16: for x being Real st x in Z holds
((exp_R - f) / exp_R) . x > 0

proof

let x be Real; :: thesis: ( x in Z implies ((exp_R - f) / exp_R) . x > 0 )
A17: exp_R . x > 0 by SIN_COS:54;
assume A18: x in Z ; :: thesis: ((exp_R - f) / exp_R) . x > 0
then x in dom ((exp_R - f) / exp_R) by A1, FUNCT_1:11;
then A19: ((exp_R - f) / exp_R) . x = ((exp_R - f) . x) * ((exp_R . x) ") by RFUNCT_1:def 1
.= ((exp_R - f) . x) * (1 / (exp_R . x)) by XCMPLX_1:215
.= ((exp_R - f) . x) / (exp_R . x) by XCMPLX_1:99 ;
(exp_R - f) . x > 0 by A2, A18;
hence ((exp_R - f) / exp_R) . x > 0 by A19, A17, XREAL_1:139; :: thesis: verum

end;

A20: for x being Real st x in Z holds
ln * ((exp_R - f) / exp_R) is_differentiable_in x

proof

let x be Real; :: thesis: ( x in Z implies ln * ((exp_R - f) / exp_R) is_differentiable_in x )
assume x in Z ; :: thesis: ln * ((exp_R - f) / exp_R) is_differentiable_in x
then ( (exp_R - f) / exp_R is_differentiable_in x & ((exp_R - f) / exp_R) . x > 0 ) by A9, A16, FDIFF_1:9;
hence ln * ((exp_R - f) / exp_R) is_differentiable_in x by TAYLOR_1:20; :: thesis: verum

end;

then A21: ln * ((exp_R - f) / exp_R) is_differentiable_on Z by A1, FDIFF_1:9;
for x being Real st x in Z holds
((ln * ((exp_R - f) / exp_R)) `| Z) . x = 1 / ((exp_R . x) - 1)

proof

let x be Real; :: thesis: ( x in Z implies ((ln * ((exp_R - f) / exp_R)) `| Z) . x = 1 / ((exp_R . x) - 1) )
A22: exp_R . x > 0 by SIN_COS:54;
assume A23: x in Z ; :: thesis: ((ln * ((exp_R - f) / exp_R)) `| Z) . x = 1 / ((exp_R . x) - 1)
then x in dom ((exp_R - f) / exp_R) by A1, FUNCT_1:11;
then A24: ((exp_R - f) / exp_R) . x = ((exp_R - f) . x) * ((exp_R . x) ") by RFUNCT_1:def 1
.= ((exp_R - f) . x) * (1 / (exp_R . x)) by XCMPLX_1:215
.= ((exp_R - f) . x) / (exp_R . x) by XCMPLX_1:99
.= ((exp_R . x) - (f . x)) / (exp_R . x) by A4, A23, VALUED_1:13
.= ((exp_R . x) - 1) / (exp_R . x) by A2, A23 ;
( (exp_R - f) / exp_R is_differentiable_in x & ((exp_R - f) / exp_R) . x > 0 ) by A9, A16, A23, FDIFF_1:9;
then diff ((ln * ((exp_R - f) / exp_R)),x) = (diff (((exp_R - f) / exp_R),x)) / (((exp_R - f) / exp_R) . x) by TAYLOR_1:20
.= ((((exp_R - f) / exp_R) `| Z) . x) / (((exp_R - f) / exp_R) . x) by A9, A23, FDIFF_1:def 7
.= (1 / (exp_R . x)) / (((exp_R . x) - 1) / (exp_R . x)) by A12, A23, A24
.= 1 / ((exp_R . x) - 1) by A22, XCMPLX_1:55 ;
hence ((ln * ((exp_R - f) / exp_R)) `| Z) . x = 1 / ((exp_R . x) - 1) by A21, A23, FDIFF_1:def 7; :: thesis: verum

end;

hence ( ln * ((exp_R - f) / exp_R) is_differentiable_on Z & ( for x being Real st x in Z holds
((ln * ((exp_R - f) / exp_R)) `| Z) . x = 1 / ((exp_R . x) - 1) ) ) by A1, A20, FDIFF_1:9; :: thesis: verum