let a, b, c be Real; :: thesis: for Z being open Subset of REAL
for f1, f2 being PartFunc of REAL,REAL st Z c= dom (f1 + (c (#) f2)) & ( for x being Real st x in Z holds
f1 . x = a + (b * x) ) & f2 = #Z 2 holds
( f1 + (c (#) f2) is_differentiable_on Z & ( for x being Real st x in Z holds
((f1 + (c (#) f2)) `| Z) . x = b + ((2 * c) * x) ) )
let Z be open Subset of REAL; :: thesis: for f1, f2 being PartFunc of REAL,REAL st Z c= dom (f1 + (c (#) f2)) & ( for x being Real st x in Z holds
f1 . x = a + (b * x) ) & f2 = #Z 2 holds
( f1 + (c (#) f2) is_differentiable_on Z & ( for x being Real st x in Z holds
((f1 + (c (#) f2)) `| Z) . x = b + ((2 * c) * x) ) )
let f1, f2 be PartFunc of REAL,REAL; :: thesis: ( Z c= dom (f1 + (c (#) f2)) & ( for x being Real st x in Z holds
f1 . x = a + (b * x) ) & f2 = #Z 2 implies ( f1 + (c (#) f2) is_differentiable_on Z & ( for x being Real st x in Z holds
((f1 + (c (#) f2)) `| Z) . x = b + ((2 * c) * x) ) ) )
assume that
A1: Z c= dom (f1 + (c (#) f2)) and
A2: for x being Real st x in Z holds
f1 . x = a + (b * x) and
A3: f2 = #Z 2 ; :: thesis: ( f1 + (c (#) f2) is_differentiable_on Z & ( for x being Real st x in Z holds
((f1 + (c (#) f2)) `| Z) . x = b + ((2 * c) * x) ) )
A4: for x being Real st x in Z holds
f2 is_differentiable_in x by A3, TAYLOR_1:2;
A5: Z c= (dom f1) /\ (dom (c (#) f2)) by A1, VALUED_1:def 1;
then A6: Z c= dom f1 by XBOOLE_1:18;
A7: for x being Real st x in Z holds
f1 . x = (b * x) + a by A2;
then A8: f1 is_differentiable_on Z by A6, FDIFF_1:23;
A9: Z c= dom (c (#) f2) by A5, XBOOLE_1:18;
then Z c= dom f2 by VALUED_1:def 5;
then A10: f2 is_differentiable_on Z by A4, FDIFF_1:9;
then A11: c (#) f2 is_differentiable_on Z by A9, FDIFF_1:20;
A12: for x being Real st x in Z holds
(f2 `| Z) . x = 2 * x

proof

let x be Real; :: thesis: ( x in Z implies (f2 `| Z) . x = 2 * x )
2 * (x #Z (2 - 1)) = 2 * x by PREPOWER:35;
then A13: diff (f2,x) = 2 * x by A3, TAYLOR_1:2;
assume x in Z ; :: thesis: (f2 `| Z) . x = 2 * x
hence (f2 `| Z) . x = 2 * x by A10, A13, FDIFF_1:def 7; :: thesis: verum

end;

A14: for x being Real st x in Z holds
((c (#) f2) `| Z) . x = (2 * c) * x

proof

let x be Real; :: thesis: ( x in Z implies ((c (#) f2) `| Z) . x = (2 * c) * x )
assume A15: x in Z ; :: thesis: ((c (#) f2) `| Z) . x = (2 * c) * x
hence ((c (#) f2) `| Z) . x = c * (diff (f2,x)) by A9, A10, FDIFF_1:20
.= c * ((f2 `| Z) . x) by A10, A15, FDIFF_1:def 7
.= c * (2 * x) by A12, A15
.= (2 * c) * x ;
:: thesis: verum

end;

for x being Real st x in Z holds
((f1 + (c (#) f2)) `| Z) . x = b + ((2 * c) * x)

proof

let x be Real; :: thesis: ( x in Z implies ((f1 + (c (#) f2)) `| Z) . x = b + ((2 * c) * x) )
assume A16: x in Z ; :: thesis: ((f1 + (c (#) f2)) `| Z) . x = b + ((2 * c) * x)
then ((f1 + (c (#) f2)) `| Z) . x = (diff (f1,x)) + (diff ((c (#) f2),x)) by A1, A8, A11, FDIFF_1:18
.= ((f1 `| Z) . x) + (diff ((c (#) f2),x)) by A8, A16, FDIFF_1:def 7
.= ((f1 `| Z) . x) + (((c (#) f2) `| Z) . x) by A11, A16, FDIFF_1:def 7
.= b + (((c (#) f2) `| Z) . x) by A6, A7, A16, FDIFF_1:23
.= b + ((2 * c) * x) by A14, A16 ;
hence ((f1 + (c (#) f2)) `| Z) . x = b + ((2 * c) * x) ; :: thesis: verum

end;

hence ( f1 + (c (#) f2) is_differentiable_on Z & ( for x being Real st x in Z holds
((f1 + (c (#) f2)) `| Z) . x = b + ((2 * c) * x) ) ) by A1, A8, A11, FDIFF_1:18; :: thesis: verum