let f be PartFunc of REAL,REAL; :: thesis: for x0 being Real st f is_left_differentiable_in x0 & ex r0 being Real st
( r0 > 0 & ( for g being Real st g in dom f & g in [.(x0 - r0),x0.] holds
f . g <> 0 ) ) holds
( f ^ is_left_differentiable_in x0 & Ldiff ((f ^),x0) = - ((Ldiff (f,x0)) / ((f . x0) ^2)) )
let x0 be Real; :: thesis: ( f is_left_differentiable_in x0 & ex r0 being Real st
( r0 > 0 & ( for g being Real st g in dom f & g in [.(x0 - r0),x0.] holds
f . g <> 0 ) ) implies ( f ^ is_left_differentiable_in x0 & Ldiff ((f ^),x0) = - ((Ldiff (f,x0)) / ((f . x0) ^2)) ) )
assume A1: f is_left_differentiable_in x0 ; :: thesis: ( for r0 being Real holds
( not r0 > 0 or ex g being Real st
( g in dom f & g in [.(x0 - r0),x0.] & not f . g <> 0 ) ) or ( f ^ is_left_differentiable_in x0 & Ldiff ((f ^),x0) = - ((Ldiff (f,x0)) / ((f . x0) ^2)) ) )
then consider r2 being Real such that
A2: 0 < r2 and
A3: [.(x0 - r2),x0.] c= dom f ;
given r0 being Real such that A4: r0 > 0 and
A5: for g being Real st g in dom f & g in [.(x0 - r0),x0.] holds
f . g <> 0 ; :: thesis: ( f ^ is_left_differentiable_in x0 & Ldiff ((f ^),x0) = - ((Ldiff (f,x0)) / ((f . x0) ^2)) )
set r3 = min (r0,r2);
A6: 0 < min (r0,r2) by A4, A2, XXREAL_0:15;
then A7: x0 - (min (r0,r2)) <= x0 by XREAL_1:43;
min (r0,r2) <= r2 by XXREAL_0:17;
then A8: x0 - r2 <= x0 - (min (r0,r2)) by XREAL_1:13;
then x0 - r2 <= x0 by A7, XXREAL_0:2;
then A9: x0 in [.(x0 - r2),x0.] by XXREAL_1:1;
x0 - (min (r0,r2)) in { g where g is Real : ( x0 - r2 <= g & g <= x0 ) } by A7, A8;
then x0 - (min (r0,r2)) in [.(x0 - r2),x0.] by RCOMP_1:def 1;
then [.(x0 - (min (r0,r2))),x0.] c= [.(x0 - r2),x0.] by A9, XXREAL_2:def 12;
then A10: [.(x0 - (min (r0,r2))),x0.] c= dom f by A3;
min (r0,r2) <= r0 by XXREAL_0:17;
then A11: x0 - r0 <= x0 - (min (r0,r2)) by XREAL_1:13;
then x0 - r0 <= x0 by A7, XXREAL_0:2;
then A12: x0 in [.(x0 - r0),x0.] by XXREAL_1:1;
x0 - (min (r0,r2)) in { g where g is Real : ( x0 - r0 <= g & g <= x0 ) } by A7, A11;
then x0 - (min (r0,r2)) in [.(x0 - r0),x0.] by RCOMP_1:def 1;
then A13: [.(x0 - (min (r0,r2))),x0.] c= [.(x0 - r0),x0.] by A12, XXREAL_2:def 12;
A14: [.(x0 - (min (r0,r2))),x0.] c= dom (f ^)

proof

assume not [.(x0 - (min (r0,r2))),x0.] c= dom (f ^) ; :: thesis: contradiction
then consider x being object such that
A15: x in [.(x0 - (min (r0,r2))),x0.] and
A16: not x in dom (f ^) ;
reconsider x = x as Real by A15;
A17: not x in (dom f) \ (f " {0}) by A16, RFUNCT_1:def 2;

now :: thesis: contradiction

per cases ( not x in dom f or x in f " {0} ) by A17, XBOOLE_0:def 5;

suppose not x in dom f ; :: thesis: contradiction

hence contradiction by A10, A15; :: thesis: verum

end;

suppose A18: x in f " {0} ; :: thesis: contradiction

then f . x in {0} by FUNCT_1:def 7;
then A19: f . x = 0 by TARSKI:def 1;
x in dom f by A18, FUNCT_1:def 7;
hence contradiction by A5, A13, A15, A19; :: thesis: verum

end;

end;

end;

hence contradiction ; :: thesis: verum

end;

A20: x0 in [.(x0 - (min (r0,r2))),x0.] by A7, XXREAL_1:1;
for h being non-zero 0 -convergent Real_Sequence
for c being constant Real_Sequence st rng c = {x0} & rng (h + c) c= dom (f ^) & ( for n being Nat holds h . n < 0 ) holds
( (h ") (#) (((f ^) /* (h + c)) - ((f ^) /* c)) is convergent & lim ((h ") (#) (((f ^) /* (h + c)) - ((f ^) /* c))) = - ((Ldiff (f,x0)) / ((f . x0) ^2)) )

proof

let h be non-zero 0 -convergent Real_Sequence; :: thesis: for c being constant Real_Sequence st rng c = {x0} & rng (h + c) c= dom (f ^) & ( for n being Nat holds h . n < 0 ) holds
( (h ") (#) (((f ^) /* (h + c)) - ((f ^) /* c)) is convergent & lim ((h ") (#) (((f ^) /* (h + c)) - ((f ^) /* c))) = - ((Ldiff (f,x0)) / ((f . x0) ^2)) )
let c be constant Real_Sequence; :: thesis: ( rng c = {x0} & rng (h + c) c= dom (f ^) & ( for n being Nat holds h . n < 0 ) implies ( (h ") (#) (((f ^) /* (h + c)) - ((f ^) /* c)) is convergent & lim ((h ") (#) (((f ^) /* (h + c)) - ((f ^) /* c))) = - ((Ldiff (f,x0)) / ((f . x0) ^2)) ) )
assume that
A21: rng c = {x0} and
A22: rng (h + c) c= dom (f ^) and
A23: for n being Nat holds h . n < 0 ; :: thesis: ( (h ") (#) (((f ^) /* (h + c)) - ((f ^) /* c)) is convergent & lim ((h ") (#) (((f ^) /* (h + c)) - ((f ^) /* c))) = - ((Ldiff (f,x0)) / ((f . x0) ^2)) )
A24: for m being Element of NAT holds c . m = x0

proof

let m be Element of NAT ; :: thesis: c . m = x0
c . m in rng c by VALUED_0:28;
hence c . m = x0 by A21, TARSKI:def 1; :: thesis: verum

end;

A25: (dom f) \ (f " {0}) c= dom f by XBOOLE_1:36;
rng (h + c) c= (dom f) \ (f " {0}) by A22, RFUNCT_1:def 2;
then A26: rng (h + c) c= dom f by A25;
then A27: lim ((h ") (#) ((f /* (h + c)) - (f /* c))) = Ldiff (f,x0) by A1, A21, A23, Th9;
A28: (h ") (#) ((f /* (h + c)) - (f /* c)) is convergent by A1, A21, A23, A26;
then A29: - ((h ") (#) ((f /* (h + c)) - (f /* c))) is convergent ;
x0 in dom (f ^) by A20, A14;
then A30: x0 in (dom f) \ (f " {0}) by RFUNCT_1:def 2;
rng c c= (dom f) \ (f " {0}) by A21, A30, TARSKI:def 1;
then A31: rng c c= dom (f ^) by RFUNCT_1:def 2;
then A32: f /* c is non-zero by RFUNCT_2:11;

now :: thesis: for n being Element of NAT holds (h (#) ((h ") (#) ((f /* (h + c)) - (f /* c)))) . n = ((f /* (h + c)) - (f /* c)) . n

let n be Element of NAT ; :: thesis: (h (#) ((h ") (#) ((f /* (h + c)) - (f /* c)))) . n = ((f /* (h + c)) - (f /* c)) . n
A33: h . n <> 0 by A23;
thus (h (#) ((h ") (#) ((f /* (h + c)) - (f /* c)))) . n = ((h (#) (h ")) (#) ((f /* (h + c)) - (f /* c))) . n by SEQ_1:14
.= ((h (#) (h ")) . n) * (((f /* (h + c)) - (f /* c)) . n) by SEQ_1:8
.= ((h . n) * ((h ") . n)) * (((f /* (h + c)) - (f /* c)) . n) by SEQ_1:8
.= ((h . n) * ((h . n) ")) * (((f /* (h + c)) - (f /* c)) . n) by VALUED_1:10
.= 1 * (((f /* (h + c)) - (f /* c)) . n) by A33, XCMPLX_0:def 7
.= ((f /* (h + c)) - (f /* c)) . n ; :: thesis: verum

end;

then A34: h (#) ((h ") (#) ((f /* (h + c)) - (f /* c))) = (f /* (h + c)) - (f /* c) by FUNCT_2:63;
A35: f /* (h + c) is non-zero by A22, RFUNCT_2:11;
then A36: (f /* (h + c)) (#) (f /* c) is non-zero by A32, SEQ_1:35;

now :: thesis: for n being Element of NAT holds ((f /* c) + ((f /* (h + c)) - (f /* c))) . n = (f /* (h + c)) . n

let n be Element of NAT ; :: thesis: ((f /* c) + ((f /* (h + c)) - (f /* c))) . n = (f /* (h + c)) . n
thus ((f /* c) + ((f /* (h + c)) - (f /* c))) . n = ((f /* c) . n) + (((f /* (h + c)) - (f /* c)) . n) by SEQ_1:7
.= ((f /* c) . n) + (((f /* (h + c)) . n) - ((f /* c) . n)) by RFUNCT_2:1
.= (f /* (h + c)) . n ; :: thesis: verum

end;

then A37: (f /* c) + ((f /* (h + c)) - (f /* c)) = f /* (h + c) by FUNCT_2:63;
dom (f ^) = (dom f) \ (f " {0}) by RFUNCT_1:def 2;
then A38: dom (f ^) c= dom f by XBOOLE_1:36;
A39: for g being Real st 0 < g holds
ex n being Nat st
for m being Nat st n <= m holds
|.(((f /* c) . m) - (f . x0)).| < g

proof

let g be Real; :: thesis: ( 0 < g implies ex n being Nat st
for m being Nat st n <= m holds
|.(((f /* c) . m) - (f . x0)).| < g )
assume A40: 0 < g ; :: thesis: ex n being Nat st
for m being Nat st n <= m holds
|.(((f /* c) . m) - (f . x0)).| < g
take n = 0 ; :: thesis: for m being Nat st n <= m holds
|.(((f /* c) . m) - (f . x0)).| < g
let m be Nat; :: thesis: ( n <= m implies |.(((f /* c) . m) - (f . x0)).| < g )
assume n <= m ; :: thesis: |.(((f /* c) . m) - (f . x0)).| < g
A41: m in NAT by ORDINAL1:def 12;
|.(((f /* c) . m) - (f . x0)).| = |.((f . (c . m)) - (f . x0)).| by A31, A38, FUNCT_2:108, XBOOLE_1:1, A41
.= |.((f . x0) - (f . x0)).| by A24, A41
.= 0 by ABSVALUE:def 1 ;
hence |.(((f /* c) . m) - (f . x0)).| < g by A40; :: thesis: verum

end;

then A42: f /* c is convergent by SEQ_2:def 6;
then A43: lim (f /* c) = f . x0 by A39, SEQ_2:def 7;
h (#) ((h ") (#) ((f /* (h + c)) - (f /* c))) is convergent by A28;
then A44: f /* (h + c) is convergent by A42, A34, A37;
lim (h (#) ((h ") (#) ((f /* (h + c)) - (f /* c)))) = (lim h) * (lim ((h ") (#) ((f /* (h + c)) - (f /* c)))) by A28, SEQ_2:15
.= 0 ;
then 0 = (lim (f /* (h + c))) - (f . x0) by A42, A43, A34, A44, SEQ_2:12;
then A45: lim ((f /* (h + c)) (#) (f /* c)) = (f . x0) ^2 by A42, A43, A44, SEQ_2:15;
A46: lim ((f /* (h + c)) (#) (f /* c)) <> 0

proof

assume not lim ((f /* (h + c)) (#) (f /* c)) <> 0 ; :: thesis: contradiction
then f . x0 = 0 by A45, XCMPLX_1:6;
hence contradiction by A5, A3, A12, A9; :: thesis: verum

end;

now :: thesis: for n being Element of NAT holds ((h ") (#) (((f ^) /* (h + c)) - ((f ^) /* c))) . n = ((- ((h ") (#) ((f /* (h + c)) - (f /* c)))) /" ((f /* (h + c)) (#) (f /* c))) . n

let n be Element of NAT ; :: thesis: ((h ") (#) (((f ^) /* (h + c)) - ((f ^) /* c))) . n = ((- ((h ") (#) ((f /* (h + c)) - (f /* c)))) /" ((f /* (h + c)) (#) (f /* c))) . n
A47: ( (f /* (h + c)) . n <> 0 & (f /* c) . n <> 0 ) by A35, A32, SEQ_1:5;
thus ((h ") (#) (((f ^) /* (h + c)) - ((f ^) /* c))) . n = ((h ") . n) * ((((f ^) /* (h + c)) - ((f ^) /* c)) . n) by SEQ_1:8
.= ((h ") . n) * ((((f ^) /* (h + c)) . n) - (((f ^) /* c) . n)) by RFUNCT_2:1
.= ((h ") . n) * ((((f /* (h + c)) ") . n) - (((f ^) /* c) . n)) by A22, RFUNCT_2:12
.= ((h ") . n) * ((((f /* (h + c)) ") . n) - (((f /* c) ") . n)) by A31, RFUNCT_2:12
.= ((h ") . n) * ((((f /* (h + c)) . n) ") - (((f /* c) ") . n)) by VALUED_1:10
.= ((h ") . n) * ((((f /* (h + c)) . n) ") - (((f /* c) . n) ")) by VALUED_1:10
.= ((h ") . n) * ((1 / ((f /* (h + c)) . n)) - (((f /* c) . n) ")) by XCMPLX_1:215
.= ((h ") . n) * ((1 / ((f /* (h + c)) . n)) - (1 / ((f /* c) . n))) by XCMPLX_1:215
.= ((h ") . n) * (((1 * ((f /* c) . n)) - (1 * ((f /* (h + c)) . n))) / (((f /* (h + c)) . n) * ((f /* c) . n))) by A47, XCMPLX_1:130
.= ((h ") . n) * ((- (((f /* (h + c)) . n) - ((f /* c) . n))) / (((f /* (h + c)) (#) (f /* c)) . n)) by SEQ_1:8
.= ((h ") . n) * ((- (((f /* (h + c)) - (f /* c)) . n)) / (((f /* (h + c)) (#) (f /* c)) . n)) by RFUNCT_2:1
.= ((h ") . n) * (- ((((f /* (h + c)) - (f /* c)) . n) / (((f /* (h + c)) (#) (f /* c)) . n))) by XCMPLX_1:187
.= - (((h ") . n) * ((((f /* (h + c)) - (f /* c)) . n) / (((f /* (h + c)) (#) (f /* c)) . n)))
.= - ((((h ") . n) * (((f /* (h + c)) - (f /* c)) . n)) / (((f /* (h + c)) (#) (f /* c)) . n)) by XCMPLX_1:74
.= - ((((h ") (#) ((f /* (h + c)) - (f /* c))) . n) / (((f /* (h + c)) (#) (f /* c)) . n)) by SEQ_1:8
.= - ((((h ") (#) ((f /* (h + c)) - (f /* c))) . n) * ((((f /* (h + c)) (#) (f /* c)) . n) ")) by XCMPLX_0:def 9
.= - ((((h ") (#) ((f /* (h + c)) - (f /* c))) . n) * ((((f /* (h + c)) (#) (f /* c)) ") . n)) by VALUED_1:10
.= - ((((h ") (#) ((f /* (h + c)) - (f /* c))) /" ((f /* (h + c)) (#) (f /* c))) . n) by SEQ_1:8
.= (- (((h ") (#) ((f /* (h + c)) - (f /* c))) /" ((f /* (h + c)) (#) (f /* c)))) . n by SEQ_1:10
.= ((- ((h ") (#) ((f /* (h + c)) - (f /* c)))) /" ((f /* (h + c)) (#) (f /* c))) . n by SEQ_1:48 ; :: thesis: verum

end;

then A48: (h ") (#) (((f ^) /* (h + c)) - ((f ^) /* c)) = (- ((h ") (#) ((f /* (h + c)) - (f /* c)))) /" ((f /* (h + c)) (#) (f /* c)) by FUNCT_2:63;
A49: (f /* (h + c)) (#) (f /* c) is convergent by A42, A44;
then lim ((h ") (#) (((f ^) /* (h + c)) - ((f ^) /* c))) = (lim (- ((h ") (#) ((f /* (h + c)) - (f /* c))))) / ((f . x0) ^2) by A36, A45, A46, A29, A48, SEQ_2:24
.= (- (Ldiff (f,x0))) / ((f . x0) ^2) by A28, A27, SEQ_2:10
.= - ((Ldiff (f,x0)) / ((f . x0) ^2)) by XCMPLX_1:187 ;
hence ( (h ") (#) (((f ^) /* (h + c)) - ((f ^) /* c)) is convergent & lim ((h ") (#) (((f ^) /* (h + c)) - ((f ^) /* c))) = - ((Ldiff (f,x0)) / ((f . x0) ^2)) ) by A36, A49, A46, A29, A48, SEQ_2:23; :: thesis: verum

end;

hence ( f ^ is_left_differentiable_in x0 & Ldiff ((f ^),x0) = - ((Ldiff (f,x0)) / ((f . x0) ^2)) ) by A6, A14, Th9; :: thesis: verum