let n be Element of NAT ; :: thesis: for Z being open Subset of REAL st Z c= dom ((1 / n) (#) ((#Z n) * (arctan ^))) & Z c= ].(- 1),1.[ & n > 0 & ( for x being Real st x in Z holds
arctan . x <> 0 ) holds
( (1 / n) (#) ((#Z n) * (arctan ^)) is_differentiable_on Z & ( for x being Real st x in Z holds
(((1 / n) (#) ((#Z n) * (arctan ^))) `| Z) . x = - (1 / (((arctan . x) #Z (n + 1)) * (1 + (x ^2)))) ) )
let Z be open Subset of REAL; :: thesis: ( Z c= dom ((1 / n) (#) ((#Z n) * (arctan ^))) & Z c= ].(- 1),1.[ & n > 0 & ( for x being Real st x in Z holds
arctan . x <> 0 ) implies ( (1 / n) (#) ((#Z n) * (arctan ^)) is_differentiable_on Z & ( for x being Real st x in Z holds
(((1 / n) (#) ((#Z n) * (arctan ^))) `| Z) . x = - (1 / (((arctan . x) #Z (n + 1)) * (1 + (x ^2)))) ) ) )
assume that
A1: Z c= dom ((1 / n) (#) ((#Z n) * (arctan ^))) and
A2: Z c= ].(- 1),1.[ and
A3: n > 0 and
A4: for x being Real st x in Z holds
arctan . x <> 0 ; :: thesis: ( (1 / n) (#) ((#Z n) * (arctan ^)) is_differentiable_on Z & ( for x being Real st x in Z holds
(((1 / n) (#) ((#Z n) * (arctan ^))) `| Z) . x = - (1 / (((arctan . x) #Z (n + 1)) * (1 + (x ^2)))) ) )
A5: Z c= dom ((#Z n) * (arctan ^)) by A1, VALUED_1:def 5;
A6: arctan ^ is_differentiable_on Z by A2, A4, Th67;
for x being Real st x in Z holds
(#Z n) * (arctan ^) is_differentiable_in x

proof

let x be Real; :: thesis: ( x in Z implies (#Z n) * (arctan ^) is_differentiable_in x )
assume x in Z ; :: thesis: (#Z n) * (arctan ^) is_differentiable_in x
then arctan ^ is_differentiable_in x by A6, FDIFF_1:9;
hence (#Z n) * (arctan ^) is_differentiable_in x by TAYLOR_1:3; :: thesis: verum

end;

then A7: (#Z n) * (arctan ^) is_differentiable_on Z by A5, FDIFF_1:9;
for y being object st y in Z holds
y in dom (arctan ^) by A5, FUNCT_1:11;
then A8: Z c= dom (arctan ^) by TARSKI:def 3;
for x being Real st x in Z holds
(((1 / n) (#) ((#Z n) * (arctan ^))) `| Z) . x = - (1 / (((arctan . x) #Z (n + 1)) * (1 + (x ^2))))

proof

let x be Real; :: thesis: ( x in Z implies (((1 / n) (#) ((#Z n) * (arctan ^))) `| Z) . x = - (1 / (((arctan . x) #Z (n + 1)) * (1 + (x ^2)))) )
assume A9: x in Z ; :: thesis: (((1 / n) (#) ((#Z n) * (arctan ^))) `| Z) . x = - (1 / (((arctan . x) #Z (n + 1)) * (1 + (x ^2))))
then A10: arctan ^ is_differentiable_in x by A6, FDIFF_1:9;
A11: (arctan ^) . x = 1 / (arctan . x) by A8, A9, RFUNCT_1:def 2;
(((1 / n) (#) ((#Z n) * (arctan ^))) `| Z) . x = (1 / n) * (diff (((#Z n) * (arctan ^)),x)) by A1, A7, A9, FDIFF_1:20
.= (1 / n) * ((n * (((arctan ^) . x) #Z (n - 1))) * (diff ((arctan ^),x))) by A10, TAYLOR_1:3
.= (1 / n) * ((n * (((arctan ^) . x) #Z (n - 1))) * (((arctan ^) `| Z) . x)) by A6, A9, FDIFF_1:def 7
.= (1 / n) * ((n * (((arctan ^) . x) #Z (n - 1))) * (- (1 / (((arctan . x) ^2) * (1 + (x ^2)))))) by A2, A4, A9, Th67
.= - ((((1 / n) * n) * (((arctan ^) . x) #Z (n - 1))) * (1 / (((arctan . x) ^2) * (1 + (x ^2)))))
.= - ((1 * (((arctan ^) . x) #Z (n - 1))) * (1 / (((arctan . x) ^2) * (1 + (x ^2))))) by A3, XCMPLX_1:106
.= - (((1 / (arctan . x)) #Z (n - 1)) * (1 / (((arctan . x) #Z 2) * (1 + (x ^2))))) by A11, FDIFF_7:1
.= - ((1 / ((arctan . x) #Z (n - 1))) / (((arctan . x) #Z 2) * (1 + (x ^2)))) by PREPOWER:42
.= - (1 / (((arctan . x) #Z (n - 1)) * (((arctan . x) #Z 2) * (1 + (x ^2))))) by XCMPLX_1:78
.= - (1 / ((((arctan . x) #Z (n - 1)) * ((arctan . x) #Z 2)) * (1 + (x ^2))))
.= - (1 / (((arctan . x) #Z ((n - 1) + 2)) * (1 + (x ^2)))) by A4, A9, PREPOWER:44
.= - (1 / (((arctan . x) #Z (n + 1)) * (1 + (x ^2)))) ;
hence (((1 / n) (#) ((#Z n) * (arctan ^))) `| Z) . x = - (1 / (((arctan . x) #Z (n + 1)) * (1 + (x ^2)))) ; :: thesis: verum

end;

hence ( (1 / n) (#) ((#Z n) * (arctan ^)) is_differentiable_on Z & ( for x being Real st x in Z holds
(((1 / n) (#) ((#Z n) * (arctan ^))) `| Z) . x = - (1 / (((arctan . x) #Z (n + 1)) * (1 + (x ^2)))) ) ) by A1, A7, FDIFF_1:20; :: thesis: verum