let Z be open Subset of REAL; :: thesis: for g being PartFunc of REAL,REAL st not 0 in Z & Z c= dom (g (#) (arccot * ((id Z) ^))) & g = #Z 2 & ( for x being Real st x in Z holds
( ((id Z) ^) . x > - 1 & ((id Z) ^) . x < 1 ) ) holds
( g (#) (arccot * ((id Z) ^)) is_differentiable_on Z & ( for x being Real st x in Z holds
((g (#) (arccot * ((id Z) ^))) `| Z) . x = ((2 * x) * (arccot . (1 / x))) + ((x ^2) / (1 + (x ^2))) ) )
let g be PartFunc of REAL,REAL; :: thesis: ( not 0 in Z & Z c= dom (g (#) (arccot * ((id Z) ^))) & g = #Z 2 & ( for x being Real st x in Z holds
( ((id Z) ^) . x > - 1 & ((id Z) ^) . x < 1 ) ) implies ( g (#) (arccot * ((id Z) ^)) is_differentiable_on Z & ( for x being Real st x in Z holds
((g (#) (arccot * ((id Z) ^))) `| Z) . x = ((2 * x) * (arccot . (1 / x))) + ((x ^2) / (1 + (x ^2))) ) ) )
set f = id Z;
assume that
A1: not 0 in Z and
A2: Z c= dom (g (#) (arccot * ((id Z) ^))) and
A3: g = #Z 2 and
A4: for x being Real st x in Z holds
( ((id Z) ^) . x > - 1 & ((id Z) ^) . x < 1 ) ; :: thesis: ( g (#) (arccot * ((id Z) ^)) is_differentiable_on Z & ( for x being Real st x in Z holds
((g (#) (arccot * ((id Z) ^))) `| Z) . x = ((2 * x) * (arccot . (1 / x))) + ((x ^2) / (1 + (x ^2))) ) )
A5: for x being Real st x in Z holds
g is_differentiable_in x by A3, TAYLOR_1:2;
A6: Z c= (dom g) /\ (dom (arccot * ((id Z) ^))) by A2, VALUED_1:def 4;
then A7: Z c= dom (arccot * ((id Z) ^)) by XBOOLE_1:18;
then A8: arccot * ((id Z) ^) is_differentiable_on Z by A1, A4, SIN_COS9:112;
Z c= dom g by A6, XBOOLE_1:18;
then A9: g is_differentiable_on Z by A5, FDIFF_1:9;
A10: for x being Real st x in Z holds
(g `| Z) . x = 2 * x

proof

let x be Real; :: thesis: ( x in Z implies (g `| Z) . x = 2 * x )
assume x in Z ; :: thesis: (g `| Z) . x = 2 * x
then (g `| Z) . x = diff (g,x) by A9, FDIFF_1:def 7
.= 2 * (x #Z (2 - 1)) by A3, TAYLOR_1:2
.= 2 * x by PREPOWER:35 ;
hence (g `| Z) . x = 2 * x ; :: thesis: verum

end;

for y being object st y in Z holds
y in dom ((id Z) ^) by A7, FUNCT_1:11;
then A11: Z c= dom ((id Z) ^) by TARSKI:def 3;
for x being Real st x in Z holds
((g (#) (arccot * ((id Z) ^))) `| Z) . x = ((2 * x) * (arccot . (1 / x))) + ((x ^2) / (1 + (x ^2)))

proof

let x be Real; :: thesis: ( x in Z implies ((g (#) (arccot * ((id Z) ^))) `| Z) . x = ((2 * x) * (arccot . (1 / x))) + ((x ^2) / (1 + (x ^2))) )
assume A12: x in Z ; :: thesis: ((g (#) (arccot * ((id Z) ^))) `| Z) . x = ((2 * x) * (arccot . (1 / x))) + ((x ^2) / (1 + (x ^2)))
then ((g (#) (arccot * ((id Z) ^))) `| Z) . x = (((arccot * ((id Z) ^)) . x) * (diff (g,x))) + ((g . x) * (diff ((arccot * ((id Z) ^)),x))) by A2, A8, A9, FDIFF_1:21
.= (((arccot * ((id Z) ^)) . x) * ((g `| Z) . x)) + ((g . x) * (diff ((arccot * ((id Z) ^)),x))) by A9, A12, FDIFF_1:def 7
.= (((arccot * ((id Z) ^)) . x) * (2 * x)) + ((g . x) * (diff ((arccot * ((id Z) ^)),x))) by A10, A12
.= (((arccot * ((id Z) ^)) . x) * (2 * x)) + ((x #Z 2) * (diff ((arccot * ((id Z) ^)),x))) by A3, TAYLOR_1:def 1
.= (((arccot * ((id Z) ^)) . x) * (2 * x)) + ((x #Z 2) * (((arccot * ((id Z) ^)) `| Z) . x)) by A8, A12, FDIFF_1:def 7
.= (((arccot * ((id Z) ^)) . x) * (2 * x)) + ((x #Z (1 + 1)) * (1 / (1 + (x ^2)))) by A1, A4, A7, A12, SIN_COS9:112
.= (((arccot * ((id Z) ^)) . x) * (2 * x)) + (((x #Z 1) * (x #Z 1)) * (1 / (1 + (x ^2)))) by TAYLOR_1:1
.= (((arccot * ((id Z) ^)) . x) * (2 * x)) + ((x * (x #Z 1)) * (1 / (1 + (x ^2)))) by PREPOWER:35
.= (((arccot * ((id Z) ^)) . x) * (2 * x)) + ((x ^2) / (1 + (x ^2))) by PREPOWER:35
.= ((arccot . (((id Z) ^) . x)) * (2 * x)) + ((x ^2) / (1 + (x ^2))) by A7, A12, FUNCT_1:12
.= ((arccot . (((id Z) . x) ")) * (2 * x)) + ((x ^2) / (1 + (x ^2))) by A11, A12, RFUNCT_1:def 2
.= ((2 * x) * (arccot . (1 / x))) + ((x ^2) / (1 + (x ^2))) by A12, FUNCT_1:18 ;
hence ((g (#) (arccot * ((id Z) ^))) `| Z) . x = ((2 * x) * (arccot . (1 / x))) + ((x ^2) / (1 + (x ^2))) ; :: thesis: verum

end;

hence ( g (#) (arccot * ((id Z) ^)) is_differentiable_on Z & ( for x being Real st x in Z holds
((g (#) (arccot * ((id Z) ^))) `| Z) . x = ((2 * x) * (arccot . (1 / x))) + ((x ^2) / (1 + (x ^2))) ) ) by A2, A8, A9, FDIFF_1:21; :: thesis: verum