let Z be open Subset of REAL; :: thesis: ( Z c= dom (exp_R * (arctan - arccot)) & Z c= ].(- 1),1.[ implies ( exp_R * (arctan - arccot) is_differentiable_on Z & ( for x being Real st x in Z holds
((exp_R * (arctan - arccot)) `| Z) . x = (2 * (exp_R . ((arctan . x) - (arccot . x)))) / (1 + (x ^2)) ) ) )
assume that
A1: Z c= dom (exp_R * (arctan - arccot)) and
A2: Z c= ].(- 1),1.[ ; :: thesis: ( exp_R * (arctan - arccot) is_differentiable_on Z & ( for x being Real st x in Z holds
((exp_R * (arctan - arccot)) `| Z) . x = (2 * (exp_R . ((arctan . x) - (arccot . x)))) / (1 + (x ^2)) ) )
A3: ].(- 1),1.[ c= [.(- 1),1.] by XXREAL_1:25;
then ].(- 1),1.[ c= dom arccot by SIN_COS9:24, XBOOLE_1:1;
then A4: Z c= dom arccot by A2, XBOOLE_1:1;
].(- 1),1.[ c= dom arctan by A3, SIN_COS9:23, XBOOLE_1:1;
then Z c= dom arctan by A2, XBOOLE_1:1;
then Z c= (dom arctan) /\ (dom arccot) by A4, XBOOLE_1:19;
then A5: Z c= dom (arctan - arccot) by VALUED_1:12;
A6: arctan - arccot is_differentiable_on Z by A2, Th38;
A7: for x being Real st x in Z holds
exp_R * (arctan - arccot) is_differentiable_in x

proof

let x be Real; :: thesis: ( x in Z implies exp_R * (arctan - arccot) is_differentiable_in x )
assume x in Z ; :: thesis: exp_R * (arctan - arccot) is_differentiable_in x
then A8: arctan - arccot is_differentiable_in x by A6, FDIFF_1:9;
exp_R is_differentiable_in (arctan - arccot) . x by SIN_COS:65;
hence exp_R * (arctan - arccot) is_differentiable_in x by A8, FDIFF_2:13; :: thesis: verum

end;

then A9: exp_R * (arctan - arccot) is_differentiable_on Z by A1, FDIFF_1:9;
for x being Real st x in Z holds
((exp_R * (arctan - arccot)) `| Z) . x = (2 * (exp_R . ((arctan . x) - (arccot . x)))) / (1 + (x ^2))

proof

let x be Real; :: thesis: ( x in Z implies ((exp_R * (arctan - arccot)) `| Z) . x = (2 * (exp_R . ((arctan . x) - (arccot . x)))) / (1 + (x ^2)) )
A10: exp_R is_differentiable_in (arctan - arccot) . x by SIN_COS:65;
assume A11: x in Z ; :: thesis: ((exp_R * (arctan - arccot)) `| Z) . x = (2 * (exp_R . ((arctan . x) - (arccot . x)))) / (1 + (x ^2))
then A12: arctan - arccot is_differentiable_in x by A6, FDIFF_1:9;
((exp_R * (arctan - arccot)) `| Z) . x = diff ((exp_R * (arctan - arccot)),x) by A9, A11, FDIFF_1:def 7
.= (diff (exp_R,((arctan - arccot) . x))) * (diff ((arctan - arccot),x)) by A12, A10, FDIFF_2:13
.= (exp_R . ((arctan - arccot) . x)) * (diff ((arctan - arccot),x)) by SIN_COS:65
.= (exp_R . ((arctan - arccot) . x)) * (((arctan - arccot) `| Z) . x) by A6, A11, FDIFF_1:def 7
.= (exp_R . ((arctan - arccot) . x)) * (2 / (1 + (x ^2))) by A2, A11, Th38
.= (exp_R . ((arctan . x) - (arccot . x))) * (2 / (1 + (x ^2))) by A5, A11, VALUED_1:13
.= (2 * (exp_R . ((arctan . x) - (arccot . x)))) / (1 + (x ^2)) ;
hence ((exp_R * (arctan - arccot)) `| Z) . x = (2 * (exp_R . ((arctan . x) - (arccot . x)))) / (1 + (x ^2)) ; :: thesis: verum

end;

hence ( exp_R * (arctan - arccot) is_differentiable_on Z & ( for x being Real st x in Z holds
((exp_R * (arctan - arccot)) `| Z) . x = (2 * (exp_R . ((arctan . x) - (arccot . x)))) / (1 + (x ^2)) ) ) by A1, A7, FDIFF_1:9; :: thesis: verum