let Z be open Subset of REAL; :: thesis: ( Z c= dom (sec * arctan) & Z c= ].(- 1),1.[ implies ( sec * arctan is_differentiable_on Z & ( for x being Real st x in Z holds
((sec * arctan) `| Z) . x = (sin . (arctan . x)) / (((cos . (arctan . x)) ^2) * (1 + (x ^2))) ) ) )
assume that
A1: Z c= dom (sec * arctan) and
A2: Z c= ].(- 1),1.[ ; :: thesis: ( sec * arctan is_differentiable_on Z & ( for x being Real st x in Z holds
((sec * arctan) `| Z) . x = (sin . (arctan . x)) / (((cos . (arctan . x)) ^2) * (1 + (x ^2))) ) )
A3: for x being Real st x in Z holds
cos . (arctan . x) <> 0

proof

let x be Real; :: thesis: ( x in Z implies cos . (arctan . x) <> 0 )
assume x in Z ; :: thesis: cos . (arctan . x) <> 0
then arctan . x in dom sec by A1, FUNCT_1:11;
hence cos . (arctan . x) <> 0 by RFUNCT_1:3; :: thesis: verum

end;

A4: for x being Real st x in Z holds
sec * arctan is_differentiable_in x

proof

let x be Real; :: thesis: ( x in Z implies sec * arctan is_differentiable_in x )
assume A5: x in Z ; :: thesis: sec * arctan is_differentiable_in x
then cos . (arctan . x) <> 0 by A3;
then A6: sec is_differentiable_in arctan . x by FDIFF_9:1;
arctan is_differentiable_on Z by A2, SIN_COS9:81;
then arctan is_differentiable_in x by A5, FDIFF_1:9;
hence sec * arctan is_differentiable_in x by A6, FDIFF_2:13; :: thesis: verum

end;

then A7: sec * arctan is_differentiable_on Z by A1, FDIFF_1:9;
for x being Real st x in Z holds
((sec * arctan) `| Z) . x = (sin . (arctan . x)) / (((cos . (arctan . x)) ^2) * (1 + (x ^2)))

proof

let x be Real; :: thesis: ( x in Z implies ((sec * arctan) `| Z) . x = (sin . (arctan . x)) / (((cos . (arctan . x)) ^2) * (1 + (x ^2))) )
assume A8: x in Z ; :: thesis: ((sec * arctan) `| Z) . x = (sin . (arctan . x)) / (((cos . (arctan . x)) ^2) * (1 + (x ^2)))
then A9: cos . (arctan . x) <> 0 by A3;
cos . (arctan . x) <> 0 by A3, A8;
then A10: sec is_differentiable_in arctan . x by FDIFF_9:1;
A11: arctan is_differentiable_on Z by A2, SIN_COS9:81;
then A12: arctan is_differentiable_in x by A8, FDIFF_1:9;
((sec * arctan) `| Z) . x = diff ((sec * arctan),x) by A7, A8, FDIFF_1:def 7
.= (diff (sec,(arctan . x))) * (diff (arctan,x)) by A12, A10, FDIFF_2:13
.= ((sin . (arctan . x)) / ((cos . (arctan . x)) ^2)) * (diff (arctan,x)) by A9, FDIFF_9:1
.= ((sin . (arctan . x)) / ((cos . (arctan . x)) ^2)) * ((arctan `| Z) . x) by A8, A11, FDIFF_1:def 7
.= ((sin . (arctan . x)) / ((cos . (arctan . x)) ^2)) * (1 / (1 + (x ^2))) by A2, A8, SIN_COS9:81
.= ((sin . (arctan . x)) * 1) / (((cos . (arctan . x)) ^2) * (1 + (x ^2))) by XCMPLX_1:76
.= (sin . (arctan . x)) / (((cos . (arctan . x)) ^2) * (1 + (x ^2))) ;
hence ((sec * arctan) `| Z) . x = (sin . (arctan . x)) / (((cos . (arctan . x)) ^2) * (1 + (x ^2))) ; :: thesis: verum

end;

hence ( sec * arctan is_differentiable_on Z & ( for x being Real st x in Z holds
((sec * arctan) `| Z) . x = (sin . (arctan . x)) / (((cos . (arctan . x)) ^2) * (1 + (x ^2))) ) ) by A1, A4, FDIFF_1:9; :: thesis: verum