let Z be open Subset of REAL; :: thesis: ( Z c= dom (arccot * sin) & ( for x being Real st x in Z holds
( sin . x > - 1 & sin . x < 1 ) ) implies ( arccot * sin is_differentiable_on Z & ( for x being Real st x in Z holds
((arccot * sin) `| Z) . x = - ((cos . x) / (1 + ((sin . x) ^2))) ) ) )
assume that
A1: Z c= dom (arccot * sin) and
A2: for x being Real st x in Z holds
( sin . x > - 1 & sin . x < 1 ) ; :: thesis: ( arccot * sin is_differentiable_on Z & ( for x being Real st x in Z holds
((arccot * sin) `| Z) . x = - ((cos . x) / (1 + ((sin . x) ^2))) ) )
A3: for x being Real st x in Z holds
arccot * sin is_differentiable_in x

proof

let x be Real; :: thesis: ( x in Z implies arccot * sin is_differentiable_in x )
assume x in Z ; :: thesis: arccot * sin is_differentiable_in x
then A4: ( sin . x > - 1 & sin . x < 1 ) by A2;
sin is_differentiable_in x by SIN_COS:64;
hence arccot * sin is_differentiable_in x by A4, SIN_COS9:86; :: thesis: verum

end;

then A5: arccot * sin is_differentiable_on Z by A1, FDIFF_1:9;
for x being Real st x in Z holds
((arccot * sin) `| Z) . x = - ((cos . x) / (1 + ((sin . x) ^2)))

proof

let x be Real; :: thesis: ( x in Z implies ((arccot * sin) `| Z) . x = - ((cos . x) / (1 + ((sin . x) ^2))) )
A6: sin is_differentiable_in x by SIN_COS:64;
assume A7: x in Z ; :: thesis: ((arccot * sin) `| Z) . x = - ((cos . x) / (1 + ((sin . x) ^2)))
then A8: ( sin . x > - 1 & sin . x < 1 ) by A2;
((arccot * sin) `| Z) . x = diff ((arccot * sin),x) by A5, A7, FDIFF_1:def 7
.= - ((diff (sin,x)) / (1 + ((sin . x) ^2))) by A6, A8, SIN_COS9:86
.= - ((cos . x) / (1 + ((sin . x) ^2))) by SIN_COS:64 ;
hence ((arccot * sin) `| Z) . x = - ((cos . x) / (1 + ((sin . x) ^2))) ; :: thesis: verum

end;

hence ( arccot * sin is_differentiable_on Z & ( for x being Real st x in Z holds
((arccot * sin) `| Z) . x = - ((cos . x) / (1 + ((sin . x) ^2))) ) ) by A1, A3, FDIFF_1:9; :: thesis: verum