let Z be open Subset of REAL; :: thesis: ( Z c= dom (tan * arccot) & Z c= ].(- 1),1.[ implies ( tan * arccot is_differentiable_on Z & ( for x being Real st x in Z holds
((tan * arccot) `| Z) . x = - (1 / (((cos . (arccot . x)) ^2) * (1 + (x ^2)))) ) ) )
assume that
A1: Z c= dom (tan * arccot) and
A2: Z c= ].(- 1),1.[ ; :: thesis: ( tan * arccot is_differentiable_on Z & ( for x being Real st x in Z holds
((tan * arccot) `| Z) . x = - (1 / (((cos . (arccot . x)) ^2) * (1 + (x ^2)))) ) )
A3: for x being Real st x in Z holds
tan * arccot is_differentiable_in x

proof

let x be Real; :: thesis: ( x in Z implies tan * arccot is_differentiable_in x )
assume A4: x in Z ; :: thesis: tan * arccot is_differentiable_in x
then arccot . x in dom tan by A1, FUNCT_1:11;
then cos . (arccot . x) <> 0 by FDIFF_8:1;
then A5: tan is_differentiable_in arccot . x by FDIFF_7:46;
arccot is_differentiable_on Z by A2, SIN_COS9:82;
then arccot is_differentiable_in x by A4, FDIFF_1:9;
hence tan * arccot is_differentiable_in x by A5, FDIFF_2:13; :: thesis: verum

end;

then A6: tan * arccot is_differentiable_on Z by A1, FDIFF_1:9;
for x being Real st x in Z holds
((tan * arccot) `| Z) . x = - (1 / (((cos . (arccot . x)) ^2) * (1 + (x ^2))))

proof

let x be Real; :: thesis: ( x in Z implies ((tan * arccot) `| Z) . x = - (1 / (((cos . (arccot . x)) ^2) * (1 + (x ^2)))) )
assume A7: x in Z ; :: thesis: ((tan * arccot) `| Z) . x = - (1 / (((cos . (arccot . x)) ^2) * (1 + (x ^2))))
then arccot . x in dom tan by A1, FUNCT_1:11;
then A8: cos . (arccot . x) <> 0 by FDIFF_8:1;
then A9: tan is_differentiable_in arccot . x by FDIFF_7:46;
A10: arccot is_differentiable_on Z by A2, SIN_COS9:82;
then A11: arccot is_differentiable_in x by A7, FDIFF_1:9;
((tan * arccot) `| Z) . x = diff ((tan * arccot),x) by A6, A7, FDIFF_1:def 7
.= (diff (tan,(arccot . x))) * (diff (arccot,x)) by A11, A9, FDIFF_2:13
.= (1 / ((cos . (arccot . x)) ^2)) * (diff (arccot,x)) by A8, FDIFF_7:46
.= (1 / ((cos . (arccot . x)) ^2)) * ((arccot `| Z) . x) by A7, A10, FDIFF_1:def 7
.= (1 / ((cos . (arccot . x)) ^2)) * (- (1 / (1 + (x ^2)))) by A2, A7, SIN_COS9:82
.= - ((1 / ((cos . (arccot . x)) ^2)) * (1 / (1 + (x ^2))))
.= - (1 / (((cos . (arccot . x)) ^2) * (1 + (x ^2)))) by XCMPLX_1:102 ;
hence ((tan * arccot) `| Z) . x = - (1 / (((cos . (arccot . x)) ^2) * (1 + (x ^2)))) ; :: thesis: verum

end;

hence ( tan * arccot is_differentiable_on Z & ( for x being Real st x in Z holds
((tan * arccot) `| Z) . x = - (1 / (((cos . (arccot . x)) ^2) * (1 + (x ^2)))) ) ) by A1, A3, FDIFF_1:9; :: thesis: verum