let Z be open Subset of REAL; :: thesis: ( Z c= dom (arccot * arctan) & Z c= ].(- 1),1.[ & ( for x being Real st x in Z holds
( arctan . x > - 1 & arctan . x < 1 ) ) implies ( arccot * arctan is_differentiable_on Z & ( for x being Real st x in Z holds
((arccot * arctan) `| Z) . x = - (1 / ((1 + (x ^2)) * (1 + ((arctan . x) ^2)))) ) ) )
assume that
A1: Z c= dom (arccot * arctan) and
A2: Z c= ].(- 1),1.[ and
A3: for x being Real st x in Z holds
( arctan . x > - 1 & arctan . x < 1 ) ; :: thesis: ( arccot * arctan is_differentiable_on Z & ( for x being Real st x in Z holds
((arccot * arctan) `| Z) . x = - (1 / ((1 + (x ^2)) * (1 + ((arctan . x) ^2)))) ) )
A4: for x being Real st x in Z holds
arccot * arctan is_differentiable_in x

proof

let x be Real; :: thesis: ( x in Z implies arccot * arctan is_differentiable_in x )
assume A5: x in Z ; :: thesis: arccot * arctan is_differentiable_in x
then A6: ( arctan . x > - 1 & arctan . x < 1 ) by A3;
arctan is_differentiable_on Z by A2, SIN_COS9:81;
then arctan is_differentiable_in x by A5, FDIFF_1:9;
hence arccot * arctan is_differentiable_in x by A6, SIN_COS9:86; :: thesis: verum

end;

then A7: arccot * arctan is_differentiable_on Z by A1, FDIFF_1:9;
for x being Real st x in Z holds
((arccot * arctan) `| Z) . x = - (1 / ((1 + (x ^2)) * (1 + ((arctan . x) ^2))))

proof

let x be Real; :: thesis: ( x in Z implies ((arccot * arctan) `| Z) . x = - (1 / ((1 + (x ^2)) * (1 + ((arctan . x) ^2)))) )
assume A8: x in Z ; :: thesis: ((arccot * arctan) `| Z) . x = - (1 / ((1 + (x ^2)) * (1 + ((arctan . x) ^2))))
then A9: ( arctan . x > - 1 & arctan . x < 1 ) by A3;
A10: arctan is_differentiable_on Z by A2, SIN_COS9:81;
then A11: arctan is_differentiable_in x by A8, FDIFF_1:9;
((arccot * arctan) `| Z) . x = diff ((arccot * arctan),x) by A7, A8, FDIFF_1:def 7
.= - ((diff (arctan,x)) / (1 + ((arctan . x) ^2))) by A11, A9, SIN_COS9:86
.= - (((arctan `| Z) . x) / (1 + ((arctan . x) ^2))) by A8, A10, FDIFF_1:def 7
.= - ((1 / (1 + (x ^2))) / (1 + ((arctan . x) ^2))) by A2, A8, SIN_COS9:81
.= - (1 / ((1 + (x ^2)) * (1 + ((arctan . x) ^2)))) by XCMPLX_1:78 ;
hence ((arccot * arctan) `| Z) . x = - (1 / ((1 + (x ^2)) * (1 + ((arctan . x) ^2)))) ; :: thesis: verum

end;

hence ( arccot * arctan is_differentiable_on Z & ( for x being Real st x in Z holds
((arccot * arctan) `| Z) . x = - (1 / ((1 + (x ^2)) * (1 + ((arctan . x) ^2)))) ) ) by A1, A4, FDIFF_1:9; :: thesis: verum