let Z be open Subset of REAL; :: thesis: ( Z c= dom (cos (#) cot) implies ( cos (#) cot is_differentiable_on Z & ( for x being Real st x in Z holds
((cos (#) cot) `| Z) . x = (- (cos . x)) - ((cos . x) / ((sin . x) ^2)) ) ) )
A1: for x being Real st x in Z holds
cos is_differentiable_in x by SIN_COS:63;
assume A2: Z c= dom (cos (#) cot) ; :: thesis: ( cos (#) cot is_differentiable_on Z & ( for x being Real st x in Z holds
((cos (#) cot) `| Z) . x = (- (cos . x)) - ((cos . x) / ((sin . x) ^2)) ) )
then A3: Z c= (dom cos) /\ (dom cot) by VALUED_1:def 4;
then A4: Z c= dom cot by XBOOLE_1:18;
for x being Real st x in Z holds
cot is_differentiable_in x

proof

let x be Real; :: thesis: ( x in Z implies cot is_differentiable_in x )
assume x in Z ; :: thesis: cot is_differentiable_in x
then sin . x <> 0 by A4, FDIFF_8:2;
hence cot is_differentiable_in x by FDIFF_7:47; :: thesis: verum

end;

then A5: cot is_differentiable_on Z by A4, FDIFF_1:9;
Z c= dom cos by A3, XBOOLE_1:18;
then A6: cos is_differentiable_on Z by A1, FDIFF_1:9;
A7: for x being Real st x in Z holds
diff (cot,x) = - (1 / ((sin . x) ^2))

proof

let x be Real; :: thesis: ( x in Z implies diff (cot,x) = - (1 / ((sin . x) ^2)) )
assume x in Z ; :: thesis: diff (cot,x) = - (1 / ((sin . x) ^2))
then sin . x <> 0 by A4, FDIFF_8:2;
hence diff (cot,x) = - (1 / ((sin . x) ^2)) by FDIFF_7:47; :: thesis: verum

end;

for x being Real st x in Z holds
((cos (#) cot) `| Z) . x = (- (cos . x)) - ((cos . x) / ((sin . x) ^2))

proof

let x be Real; :: thesis: ( x in Z implies ((cos (#) cot) `| Z) . x = (- (cos . x)) - ((cos . x) / ((sin . x) ^2)) )
assume A8: x in Z ; :: thesis: ((cos (#) cot) `| Z) . x = (- (cos . x)) - ((cos . x) / ((sin . x) ^2))
then ((cos (#) cot) `| Z) . x = ((diff (cos,x)) * (cot . x)) + ((cos . x) * (diff (cot,x))) by A2, A5, A6, FDIFF_1:21
.= ((cot . x) * (- (sin . x))) + ((cos . x) * (diff (cot,x))) by SIN_COS:63
.= ((cot . x) * (- (sin . x))) + ((cos . x) * (- (1 / ((sin . x) ^2)))) by A7, A8
.= (((cos . x) / (sin . x)) * (- ((sin . x) / 1))) - ((cos . x) / ((sin . x) ^2)) by A4, A8, RFUNCT_1:def 1
.= (- ((cos . x) * ((sin . x) / (sin . x)))) - ((cos . x) / ((sin . x) ^2))
.= (- ((cos . x) * 1)) - ((cos . x) / ((sin . x) ^2)) by A4, A8, FDIFF_8:2, XCMPLX_1:60
.= (- (cos . x)) - ((cos . x) / ((sin . x) ^2)) ;
hence ((cos (#) cot) `| Z) . x = (- (cos . x)) - ((cos . x) / ((sin . x) ^2)) ; :: thesis: verum

end;

hence ( cos (#) cot is_differentiable_on Z & ( for x being Real st x in Z holds
((cos (#) cot) `| Z) . x = (- (cos . x)) - ((cos . x) / ((sin . x) ^2)) ) ) by A2, A5, A6, FDIFF_1:21; :: thesis: verum