let Z be open Subset of REAL; :: thesis: ( Z c= dom (tan * cot) implies ( tan * cot is_differentiable_on Z & ( for x being Real st x in Z holds
((tan * cot) `| Z) . x = (1 / ((cos . (cot . x)) ^2)) * (- (1 / ((sin . x) ^2))) ) ) )
assume A1: Z c= dom (tan * cot) ; :: thesis: ( tan * cot is_differentiable_on Z & ( for x being Real st x in Z holds
((tan * cot) `| Z) . x = (1 / ((cos . (cot . x)) ^2)) * (- (1 / ((sin . x) ^2))) ) )
A2: for x being Real st x in Z holds
cos . (cot . x) <> 0

proof

let x be Real; :: thesis: ( x in Z implies cos . (cot . x) <> 0 )
assume x in Z ; :: thesis: cos . (cot . x) <> 0
then cot . x in dom tan by A1, FUNCT_1:11;
hence cos . (cot . x) <> 0 by FDIFF_8:1; :: thesis: verum

end;

A3: for x being Real st x in Z holds
sin . x <> 0

proof

let x be Real; :: thesis: ( x in Z implies sin . x <> 0 )
assume x in Z ; :: thesis: sin . x <> 0
then x in dom (cos / sin) by A1, FUNCT_1:11;
hence sin . x <> 0 by FDIFF_8:2; :: thesis: verum

end;

A4: for x being Real st x in Z holds
tan * cot is_differentiable_in x

proof

let x be Real; :: thesis: ( x in Z implies tan * cot is_differentiable_in x )
assume A5: x in Z ; :: thesis: tan * cot is_differentiable_in x
then cos . (cot . x) <> 0 by A2;
then A6: tan is_differentiable_in cot . x by FDIFF_7:46;
sin . x <> 0 by A3, A5;
then cot is_differentiable_in x by FDIFF_7:47;
hence tan * cot is_differentiable_in x by A6, FDIFF_2:13; :: thesis: verum

end;

then A7: tan * cot is_differentiable_on Z by A1, FDIFF_1:9;
for x being Real st x in Z holds
((tan * cot) `| Z) . x = (1 / ((cos . (cot . x)) ^2)) * (- (1 / ((sin . x) ^2)))

proof

let x be Real; :: thesis: ( x in Z implies ((tan * cot) `| Z) . x = (1 / ((cos . (cot . x)) ^2)) * (- (1 / ((sin . x) ^2))) )
assume A8: x in Z ; :: thesis: ((tan * cot) `| Z) . x = (1 / ((cos . (cot . x)) ^2)) * (- (1 / ((sin . x) ^2)))
then A9: cos . (cot . x) <> 0 by A2;
then A10: tan is_differentiable_in cot . x by FDIFF_7:46;
A11: sin . x <> 0 by A3, A8;
then cot is_differentiable_in x by FDIFF_7:47;
then diff ((tan * cot),x) = (diff (tan,(cot . x))) * (diff (cot,x)) by A10, FDIFF_2:13
.= (1 / ((cos . (cot . x)) ^2)) * (diff (cot,x)) by A9, FDIFF_7:46
.= (1 / ((cos . (cot . x)) ^2)) * (- (1 / ((sin . x) ^2))) by A11, FDIFF_7:47 ;
hence ((tan * cot) `| Z) . x = (1 / ((cos . (cot . x)) ^2)) * (- (1 / ((sin . x) ^2))) by A7, A8, FDIFF_1:def 7; :: thesis: verum

end;

hence ( tan * cot is_differentiable_on Z & ( for x being Real st x in Z holds
((tan * cot) `| Z) . x = (1 / ((cos . (cot . x)) ^2)) * (- (1 / ((sin . x) ^2))) ) ) by A1, A4, FDIFF_1:9; :: thesis: verum