let f be PartFunc of REAL,REAL; :: thesis: for x0 being Real st f is_differentiable_in x0 holds
f is_continuous_in x0
let x0 be Real; :: thesis: ( f is_differentiable_in x0 implies f is_continuous_in x0 )
assume A1: f is_differentiable_in x0 ; :: thesis: f is_continuous_in x0
then consider N being Neighbourhood of x0 such that
A2: N c= dom f and
ex L being LinearFunc ex R being RestFunc st
for x being Real st x in N holds
(f . x) - (f . x0) = (L . (x - x0)) + (R . (x - x0)) ;

now :: thesis: for s1 being Real_Sequence st rng s1 c= dom f & s1 is convergent & lim s1 = x0 & ( for n being Nat holds s1 . n <> x0 ) holds
( f /* s1 is convergent & f . x0 = lim (f /* s1) )

consider g being Real such that
A3: 0 < g and
A4: N = ].(x0 - g),(x0 + g).[ by RCOMP_1:def 6;
set s2 = seq_const x0;
let s1 be Real_Sequence; :: thesis: ( rng s1 c= dom f & s1 is convergent & lim s1 = x0 & ( for n being Nat holds s1 . n <> x0 ) implies ( f /* s1 is convergent & f . x0 = lim (f /* s1) ) )
assume that
A5: rng s1 c= dom f and
A6: s1 is convergent and
A7: lim s1 = x0 and
A8: for n being Nat holds s1 . n <> x0 ; :: thesis: ( f /* s1 is convergent & f . x0 = lim (f /* s1) )
consider l being Nat such that
A9: for m being Nat st l <= m holds
|.((s1 . m) - x0).| < g by A6, A7, A3, SEQ_2:def 7;
reconsider c = (seq_const x0) ^\ l as constant Real_Sequence ;
deffunc H₁( Nat) -> set = (s1 . $1) - ((seq_const x0) . $1);
consider s3 being Real_Sequence such that
A10: for n being Nat holds s3 . n = H₁(n) from SEQ_1:sch 1();
A11: s3 = s1 - (seq_const x0) by A10, RFUNCT_2:1;
then A12: s3 is convergent by A6;
A13: rng c = {x0}

proof

thus rng c c= {x0} :: according to XBOOLE_0:def 10 :: thesis: {x0} c= rng c

proof

let y be object ; :: according to TARSKI:def 3 :: thesis: ( not y in rng c or y in {x0} )
assume y in rng c ; :: thesis: y in {x0}
then consider n being Element of NAT such that
A14: y = ((seq_const x0) ^\ l) . n by FUNCT_2:113;
A15: (seq_const x0) . (n + l) = x0 by SEQ_1:57;
y = (seq_const x0) . (n + l) by A14, NAT_1:def 3;
then y = x0 by A15;
hence y in {x0} by TARSKI:def 1; :: thesis: verum

end;

let y be object ; :: according to TARSKI:def 3 :: thesis: ( not y in {x0} or y in rng c )
assume y in {x0} ; :: thesis: y in rng c
then A16: y = x0 by TARSKI:def 1;
c . 0 = (seq_const x0) . (0 + l) by NAT_1:def 3
.= y by A16, SEQ_1:57 ;
hence y in rng c by VALUED_0:28; :: thesis: verum

end;

A17: now :: thesis: for p being Real st 0 < p holds
ex n being Nat st
for m being Nat st n <= m holds
|.(((f /* c) . m) - (f . x0)).| < p

let p be Real; :: thesis: ( 0 < p implies ex n being Nat st
for m being Nat st n <= m holds
|.(((f /* c) . m) - (f . x0)).| < p )
assume A18: 0 < p ; :: thesis: ex n being Nat st
for m being Nat st n <= m holds
|.(((f /* c) . m) - (f . x0)).| < p
reconsider n = 0 as Nat ;
take n = n; :: thesis: for m being Nat st n <= m holds
|.(((f /* c) . m) - (f . x0)).| < p
let m be Nat; :: thesis: ( n <= m implies |.(((f /* c) . m) - (f . x0)).| < p )
assume n <= m ; :: thesis: |.(((f /* c) . m) - (f . x0)).| < p
A19: m in NAT by ORDINAL1:def 12;
x0 in N by RCOMP_1:16;
then rng c c= dom f by A2, A13, ZFMISC_1:31;
then |.(((f /* c) . m) - (f . x0)).| = |.((f . (c . m)) - (f . x0)).| by FUNCT_2:108, A19
.= |.((f . ((seq_const x0) . (m + l))) - (f . x0)).| by NAT_1:def 3
.= |.((f . x0) - (f . x0)).| by SEQ_1:57
.= 0 by ABSVALUE:2 ;
hence |.(((f /* c) . m) - (f . x0)).| < p by A18; :: thesis: verum

end;

then A20: f /* c is convergent by SEQ_2:def 6;
lim (seq_const x0) = (seq_const x0) . 0 by SEQ_4:26
.= x0 by SEQ_1:57 ;
then lim s3 = x0 - x0 by A6, A7, A11, SEQ_2:12
.= 0 ;
then A21: lim (s3 ^\ l) = 0 by A12, SEQ_4:20;

A22: now :: thesis: for n being Nat holds not s3 . n = 0

given n being Nat such that A23: s3 . n = 0 ; :: thesis: contradiction
(s1 . n) - ((seq_const x0) . n) = 0 by A10, A23;
hence contradiction by A8, SEQ_1:57; :: thesis: verum

end;

A24: now :: thesis: for n being Nat holds not (s3 ^\ l) . n = 0

given n being Nat such that A25: (s3 ^\ l) . n = 0 ; :: thesis: contradiction
s3 . (n + l) = 0 by A25, NAT_1:def 3;
hence contradiction by A22; :: thesis: verum

end;

s3 ^\ l is 0 -convergent by A12, A21;
then reconsider h = s3 ^\ l as non-zero 0 -convergent Real_Sequence by A24, SEQ_1:5;

now :: thesis: for n being Element of NAT holds (((f /* (h + c)) - (f /* c)) + (f /* c)) . n = (f /* (h + c)) . n

let n be Element of NAT ; :: thesis: (((f /* (h + c)) - (f /* c)) + (f /* c)) . n = (f /* (h + c)) . n
thus (((f /* (h + c)) - (f /* c)) + (f /* c)) . n = (((f /* (h + c)) - (f /* c)) . n) + ((f /* c) . n) by SEQ_1:7
.= (((f /* (h + c)) . n) - ((f /* c) . n)) + ((f /* c) . n) by RFUNCT_2:1
.= (f /* (h + c)) . n ; :: thesis: verum

end;

then A26: ((f /* (h + c)) - (f /* c)) + (f /* c) = f /* (h + c) by FUNCT_2:63;

now :: thesis: for n being Element of NAT holds (h + c) . n = (s1 ^\ l) . n

let n be Element of NAT ; :: thesis: (h + c) . n = (s1 ^\ l) . n
thus (h + c) . n = (((s1 - (seq_const x0)) + (seq_const x0)) ^\ l) . n by A11, SEQM_3:15
.= ((s1 - (seq_const x0)) + (seq_const x0)) . (n + l) by NAT_1:def 3
.= ((s1 - (seq_const x0)) . (n + l)) + ((seq_const x0) . (n + l)) by SEQ_1:7
.= ((s1 . (n + l)) - ((seq_const x0) . (n + l))) + ((seq_const x0) . (n + l)) by RFUNCT_2:1
.= (s1 ^\ l) . n by NAT_1:def 3 ; :: thesis: verum

end;

then A27: ((f /* (h + c)) - (f /* c)) + (f /* c) = f /* (s1 ^\ l) by A26, FUNCT_2:63
.= (f /* s1) ^\ l by A5, VALUED_0:27 ;
rng (h + c) c= N

proof

let y be object ; :: according to TARSKI:def 3 :: thesis: ( not y in rng (h + c) or y in N )
assume y in rng (h + c) ; :: thesis: y in N
then consider n being Element of NAT such that
A28: y = (h + c) . n by FUNCT_2:113;
(h + c) . n = (((s1 - (seq_const x0)) + (seq_const x0)) ^\ l) . n by A11, SEQM_3:15
.= ((s1 - (seq_const x0)) + (seq_const x0)) . (n + l) by NAT_1:def 3
.= ((s1 - (seq_const x0)) . (n + l)) + ((seq_const x0) . (n + l)) by SEQ_1:7
.= ((s1 . (n + l)) - ((seq_const x0) . (n + l))) + ((seq_const x0) . (n + l)) by RFUNCT_2:1
.= s1 . (l + n) ;
then |.(((h + c) . n) - x0).| < g by A9, NAT_1:12;
hence y in N by A4, A28, RCOMP_1:1; :: thesis: verum

end;

then A29: (h ") (#) ((f /* (h + c)) - (f /* c)) is convergent by A1, A2, A13, Th12;
then A30: lim (h (#) ((h ") (#) ((f /* (h + c)) - (f /* c)))) = 0 * (lim ((h ") (#) ((f /* (h + c)) - (f /* c)))) by A21, SEQ_2:15
.= 0 ;

now :: thesis: for n being Element of NAT holds (h (#) ((h ") (#) ((f /* (h + c)) - (f /* c)))) . n = ((f /* (h + c)) - (f /* c)) . n

let n be Element of NAT ; :: thesis: (h (#) ((h ") (#) ((f /* (h + c)) - (f /* c)))) . n = ((f /* (h + c)) - (f /* c)) . n
A31: h . n <> 0 by A24;
thus (h (#) ((h ") (#) ((f /* (h + c)) - (f /* c)))) . n = (h . n) * (((h ") (#) ((f /* (h + c)) - (f /* c))) . n) by SEQ_1:8
.= (h . n) * (((h ") . n) * (((f /* (h + c)) - (f /* c)) . n)) by SEQ_1:8
.= (h . n) * (((h . n) ") * (((f /* (h + c)) - (f /* c)) . n)) by VALUED_1:10
.= ((h . n) * ((h . n) ")) * (((f /* (h + c)) - (f /* c)) . n)
.= 1 * (((f /* (h + c)) - (f /* c)) . n) by A31, XCMPLX_0:def 7
.= ((f /* (h + c)) - (f /* c)) . n ; :: thesis: verum

end;

then A32: h (#) ((h ") (#) ((f /* (h + c)) - (f /* c))) = (f /* (h + c)) - (f /* c) by FUNCT_2:63;
then A33: (f /* (h + c)) - (f /* c) is convergent by A29;
then A34: ((f /* (h + c)) - (f /* c)) + (f /* c) is convergent by A20;
hence f /* s1 is convergent by A27, SEQ_4:21; :: thesis: f . x0 = lim (f /* s1)
lim (f /* c) = f . x0 by A17, A20, SEQ_2:def 7;
then lim (((f /* (h + c)) - (f /* c)) + (f /* c)) = 0 + (f . x0) by A30, A32, A33, A20, SEQ_2:6
.= f . x0 ;
hence f . x0 = lim (f /* s1) by A34, A27, SEQ_4:22; :: thesis: verum

end;

hence f is_continuous_in x0 by FCONT_1:2; :: thesis: verum