let f be PartFunc of REAL,REAL; :: thesis: ( f is Lipschitzian implies f is continuous )
set X = dom f;
assume f is Lipschitzian ; :: thesis: f is continuous
then consider r being Real such that
A1: 0 < r and
A2: for x1, x2 being Real st x1 in dom f & x2 in dom f holds
|.((f . x1) - (f . x2)).| <= r * |.(x1 - x2).| ;

now :: thesis: for x0 being Real st x0 in dom f holds
f is_continuous_in x0

let x0 be Real; :: thesis: ( x0 in dom f implies f is_continuous_in x0 )
assume A3: x0 in dom f ; :: thesis: f is_continuous_in x0
for r being Real st 0 < r holds
ex s being Real st
( 0 < s & ( for x1 being Real st x1 in dom f & |.(x1 - x0).| < s holds
|.((f . x1) - (f . x0)).| < r ) )

proof

let g be Real; :: thesis: ( 0 < g implies ex s being Real st
( 0 < s & ( for x1 being Real st x1 in dom f & |.(x1 - x0).| < s holds
|.((f . x1) - (f . x0)).| < g ) ) )
assume A4: 0 < g ; :: thesis: ex s being Real st
( 0 < s & ( for x1 being Real st x1 in dom f & |.(x1 - x0).| < s holds
|.((f . x1) - (f . x0)).| < g ) )
set s = g / r;
take s9 = g / r; :: thesis: ( 0 < s9 & ( for x1 being Real st x1 in dom f & |.(x1 - x0).| < s9 holds
|.((f . x1) - (f . x0)).| < g ) )

A5: now :: thesis: for x1 being Real st x1 in dom f & |.(x1 - x0).| < g / r holds
|.((f . x1) - (f . x0)).| < g

let x1 be Real; :: thesis: ( x1 in dom f & |.(x1 - x0).| < g / r implies |.((f . x1) - (f . x0)).| < g )
assume that
A6: x1 in dom f and
A7: |.(x1 - x0).| < g / r ; :: thesis: |.((f . x1) - (f . x0)).| < g
r * |.(x1 - x0).| < (g / r) * r by A1, A7, XREAL_1:68;
then A8: r * |.(x1 - x0).| < g by A1, XCMPLX_1:87;
|.((f . x1) - (f . x0)).| <= r * |.(x1 - x0).| by A2, A3, A6;
hence |.((f . x1) - (f . x0)).| < g by A8, XXREAL_0:2; :: thesis: verum

end;

s9 = g * (r ") by XCMPLX_0:def 9;
hence ( 0 < s9 & ( for x1 being Real st x1 in dom f & |.(x1 - x0).| < s9 holds
|.((f . x1) - (f . x0)).| < g ) ) by A1, A4, A5, XREAL_1:129; :: thesis: verum

end;

hence f is_continuous_in x0 by Th3; :: thesis: verum

end;

hence f is continuous ; :: thesis: verum