let X be RealNormSpace; :: thesis: for f being PartFunc of (DualSp X),REAL
for x0 being Point of (DualSp X)
for x being sequence of (DualSp X) st f is_weakly*_continuous_in x0 & rng x c= dom f & x is weakly*-convergent & w*-lim x = x0 holds
( f /* x is convergent & lim (f /* x) = f . x0 )

let f be PartFunc of (DualSp X),REAL; :: thesis: for x0 being Point of (DualSp X)
for x being sequence of (DualSp X) st f is_weakly*_continuous_in x0 & rng x c= dom f & x is weakly*-convergent & w*-lim x = x0 holds
( f /* x is convergent & lim (f /* x) = f . x0 )

let x0 be Point of (DualSp X); :: thesis: for x being sequence of (DualSp X) st f is_weakly*_continuous_in x0 & rng x c= dom f & x is weakly*-convergent & w*-lim x = x0 holds
( f /* x is convergent & lim (f /* x) = f . x0 )

let x be sequence of (DualSp X); :: thesis: ( f is_weakly*_continuous_in x0 & rng x c= dom f & x is weakly*-convergent & w*-lim x = x0 implies ( f /* x is convergent & lim (f /* x) = f . x0 ) )
assume that
A1: f is_weakly*_continuous_in x0 and
A2: ( rng x c= dom f & x is weakly*-convergent ) and
A3: w*-lim x = x0 ; :: thesis: ( f /* x is convergent & lim (f /* x) = f . x0 )
A6: for e being Real st 0 < e holds
ex n being Nat st
for m being Nat st n <= m holds
|.(((f /* x) . m) - (f . x0)).| < e
proof
let e be Real; :: thesis: ( 0 < e implies ex n being Nat st
for m being Nat st n <= m holds
|.(((f /* x) . m) - (f . x0)).| < e )

assume 0 < e ; :: thesis: ex n being Nat st
for m being Nat st n <= m holds
|.(((f /* x) . m) - (f . x0)).| < e

then consider d being Real, Y being Subset of X such that
A7: ( 0 < d & Y is finite & Y <> {} & ( for z being Point of (DualSp X) st z in dom f & ( for y being Point of X st y in Y holds
|.((z - x0) . y).| < d ) holds
|.((f . z) - (f . x0)).| < e ) ) by A1;
A8: now :: thesis: for y being Point of X st y in Y holds
ex ny being Nat st
for m being Nat st ny <= m holds
|.(((x . m) - x0) . y).| < d
let y be Point of X; :: thesis: ( y in Y implies ex ny being Nat st
for m being Nat st ny <= m holds
|.(((x . m) - x0) . y).| < d )

assume y in Y ; :: thesis: ex ny being Nat st
for m being Nat st ny <= m holds
|.(((x . m) - x0) . y).| < d

( x # y is convergent & lim (x # y) = x0 . y ) by DUALSP03:def 5, A2, A3;
then consider ny being Nat such that
A9: for m being Nat st ny <= m holds
|.(((x # y) . m) - (x0 . y)).| < d by A7, SEQ_2:def 7;
take ny = ny; :: thesis: for m being Nat st ny <= m holds
|.(((x . m) - x0) . y).| < d

let m be Nat; :: thesis: ( ny <= m implies |.(((x . m) - x0) . y).| < d )
assume A10P: ny <= m ; :: thesis: |.(((x . m) - x0) . y).| < d
((x # y) . m) - (x0 . y) = ((x . m) . y) - (x0 . y) by DUALSP03:def 1
.= ((x . m) - x0) . y by DUALSP01:33 ;
hence |.(((x . m) - x0) . y).| < d by A10P, A9; :: thesis: verum
end;
defpred S1[ object , object ] means ex y being Point of X ex n being Nat st
( $1 = y & $2 = n & ( for m being Nat st n <= m holds
|.(((x . m) - x0) . y).| < d ) );
A12: for z being object st z in Y holds
ex w being object st
( w in NAT & S1[z,w] )
proof
let z be object ; :: thesis: ( z in Y implies ex w being object st
( w in NAT & S1[z,w] ) )

assume A13: z in Y ; :: thesis: ex w being object st
( w in NAT & S1[z,w] )

then reconsider y = z as Point of X ;
consider ny being Nat such that
A14: for m being Nat st ny <= m holds
|.(((x . m) - x0) . y).| < d by A13, A8;
take ny ; :: thesis: ( ny in NAT & S1[z,ny] )
thus ny in NAT by ORDINAL1:def 12; :: thesis: S1[z,ny]
thus S1[z,ny] by A14; :: thesis: verum
end;
consider N being Function of Y,NAT such that
A15: for z being object st z in Y holds
S1[z,N . z] from FUNCT_2:sch 1(A12);
consider z being object such that
A16: z in Y by A7, XBOOLE_0:def 1;
reconsider M = rng N as non empty finite Subset of NAT by A16, FUNCT_2:4, A7;
set n0 = max M;
max M in NAT by ORDINAL1:def 12;
then reconsider n0 = max M as Nat ;
A17: for m being Nat st n0 <= m holds
for y being Point of X st y in Y holds
|.(((x . m) - x0) . y).| < d
proof
let m be Nat; :: thesis: ( n0 <= m implies for y being Point of X st y in Y holds
|.(((x . m) - x0) . y).| < d )

assume A18: n0 <= m ; :: thesis: for y being Point of X st y in Y holds
|.(((x . m) - x0) . y).| < d

let y be Point of X; :: thesis: ( y in Y implies |.(((x . m) - x0) . y).| < d )
assume A19: y in Y ; :: thesis: |.(((x . m) - x0) . y).| < d
then A20P: ex y0 being Point of X ex n being Nat st
( y = y0 & N . y = n & ( for m being Nat st n <= m holds
|.(((x . m) - x0) . y0).| < d ) ) by A15;
n0 is UpperBound of M by XXREAL_2:def 3;
then N . y <= n0 by XXREAL_2:def 1, A19, FUNCT_2:4;
then N . y <= m by A18, XXREAL_0:2;
hence |.(((x . m) - x0) . y).| < d by A20P; :: thesis: verum
end;
take n0 ; :: thesis: for m being Nat st n0 <= m holds
|.(((f /* x) . m) - (f . x0)).| < e

let m be Nat; :: thesis: ( n0 <= m implies |.(((f /* x) . m) - (f . x0)).| < e )
assume n0 <= m ; :: thesis: |.(((f /* x) . m) - (f . x0)).| < e
then A22: for y being Point of X st y in Y holds
|.(((x . m) - x0) . y).| < d by A17;
A23: m in NAT by ORDINAL1:def 12;
x . m in rng x by FUNCT_2:4, ORDINAL1:def 12;
then |.((f . (x . m)) - (f . x0)).| < e by A7, A22, A2;
hence |.(((f /* x) . m) - (f . x0)).| < e by A2, A23, FUNCT_2:108; :: thesis: verum
end;
hence f /* x is convergent by SEQ_2:def 6; :: thesis: lim (f /* x) = f . x0
hence lim (f /* x) = f . x0 by A6, SEQ_2:def 7; :: thesis: verum