let n be Nat; :: thesis: for h, x being Real
for f being Function of REAL,REAL holds ((fdif (f,h)) . n) . x = ((bdif (f,h)) . n) . (x + (n * h))
let h, x be Real; :: thesis: for f being Function of REAL,REAL holds ((fdif (f,h)) . n) . x = ((bdif (f,h)) . n) . (x + (n * h))
let f be Function of REAL,REAL; :: thesis: ((fdif (f,h)) . n) . x = ((bdif (f,h)) . n) . (x + (n * h))
defpred S₁[ Nat] means for x being Real holds ((fdif (f,h)) . $1) . x = ((bdif (f,h)) . $1) . (x + ($1 * h));
A1: for k being Nat st S₁[k] holds
S₁[k + 1]

proof

let k be Nat; :: thesis: ( S₁[k] implies S₁[k + 1] )
assume A2: for x being Real holds ((fdif (f,h)) . k) . x = ((bdif (f,h)) . k) . (x + (k * h)) ; :: thesis: S₁[k + 1]
let x be Real; :: thesis: ((fdif (f,h)) . (k + 1)) . x = ((bdif (f,h)) . (k + 1)) . (x + ((k + 1) * h))
A3: ((fdif (f,h)) . k) . (x + h) = ((bdif (f,h)) . k) . ((x + h) + (k * h)) by A2;
A4: (fdif (f,h)) . k is Function of REAL,REAL by Th2;
A5: (bdif (f,h)) . k is Function of REAL,REAL by Th12;
((fdif (f,h)) . (k + 1)) . x = (fD (((fdif (f,h)) . k),h)) . x by Def6
.= (((fdif (f,h)) . k) . (x + h)) - (((fdif (f,h)) . k) . x) by A4, Th3
.= (((bdif (f,h)) . k) . ((x + h) + (k * h))) - (((bdif (f,h)) . k) . (x + (k * h))) by A2, A3
.= (((bdif (f,h)) . k) . (x + ((k + 1) * h))) - (((bdif (f,h)) . k) . ((x + ((k + 1) * h)) - h))
.= (bD (((bdif (f,h)) . k),h)) . (x + ((k + 1) * h)) by A5, Th4
.= ((bdif (f,h)) . (k + 1)) . (x + ((k + 1) * h)) by Def7 ;
hence ((fdif (f,h)) . (k + 1)) . x = ((bdif (f,h)) . (k + 1)) . (x + ((k + 1) * h)) ; :: thesis: verum

end;

A6: S₁[ 0 ]

proof

let x be Real; :: thesis: ((fdif (f,h)) . 0) . x = ((bdif (f,h)) . 0) . (x + (0 * h))
((fdif (f,h)) . 0) . x = f . x by Def6
.= ((bdif (f,h)) . 0) . (x + (0 * h)) by Def7 ;
hence ((fdif (f,h)) . 0) . x = ((bdif (f,h)) . 0) . (x + (0 * h)) ; :: thesis: verum

end;

for n being Nat holds S₁[n] from NAT_1:sch 2(A6, A1);
hence ((fdif (f,h)) . n) . x = ((bdif (f,h)) . n) . (x + (n * h)) ; :: thesis: verum