let n be Nat; :: thesis: for h, r, x being Real
for f being Function of REAL,REAL holds ((cdif ((r (#) f),h)) . (n + 1)) . x = r * (((cdif (f,h)) . (n + 1)) . x)
let h, r, x be Real; :: thesis: for f being Function of REAL,REAL holds ((cdif ((r (#) f),h)) . (n + 1)) . x = r * (((cdif (f,h)) . (n + 1)) . x)
let f be Function of REAL,REAL; :: thesis: ((cdif ((r (#) f),h)) . (n + 1)) . x = r * (((cdif (f,h)) . (n + 1)) . x)
defpred S₁[ Nat] means for x being Real holds ((cdif ((r (#) f),h)) . ($1 + 1)) . x = r * (((cdif (f,h)) . ($1 + 1)) . x);
A1: for k being Nat st S₁[k] holds
S₁[k + 1]

proof

let k be Nat; :: thesis: ( S₁[k] implies S₁[k + 1] )
assume A2: for x being Real holds ((cdif ((r (#) f),h)) . (k + 1)) . x = r * (((cdif (f,h)) . (k + 1)) . x) ; :: thesis: S₁[k + 1]
let x be Real; :: thesis: ((cdif ((r (#) f),h)) . ((k + 1) + 1)) . x = r * (((cdif (f,h)) . ((k + 1) + 1)) . x)
A3: ( ((cdif ((r (#) f),h)) . (k + 1)) . (x - (h / 2)) = r * (((cdif (f,h)) . (k + 1)) . (x - (h / 2))) & ((cdif ((r (#) f),h)) . (k + 1)) . (x + (h / 2)) = r * (((cdif (f,h)) . (k + 1)) . (x + (h / 2))) ) by A2;
A4: (cdif ((r (#) f),h)) . (k + 1) is Function of REAL,REAL by Th19;
A5: (cdif (f,h)) . (k + 1) is Function of REAL,REAL by Th19;
((cdif ((r (#) f),h)) . ((k + 1) + 1)) . x = (cD (((cdif ((r (#) f),h)) . (k + 1)),h)) . x by Def8
.= (((cdif ((r (#) f),h)) . (k + 1)) . (x + (h / 2))) - (((cdif ((r (#) f),h)) . (k + 1)) . (x - (h / 2))) by A4, Th5
.= r * ((((cdif (f,h)) . (k + 1)) . (x + (h / 2))) - (((cdif (f,h)) . (k + 1)) . (x - (h / 2)))) by A3
.= r * ((cD (((cdif (f,h)) . (k + 1)),h)) . x) by A5, Th5
.= r * (((cdif (f,h)) . ((k + 1) + 1)) . x) by Def8 ;
hence ((cdif ((r (#) f),h)) . ((k + 1) + 1)) . x = r * (((cdif (f,h)) . ((k + 1) + 1)) . x) ; :: thesis: verum

end;

A6: S₁[ 0 ]

proof

let x be Real; :: thesis: ((cdif ((r (#) f),h)) . (0 + 1)) . x = r * (((cdif (f,h)) . (0 + 1)) . x)
x + (h / 2) in REAL by XREAL_0:def 1;
then A7: x + (h / 2) in dom (r (#) f) by FUNCT_2:def 1;
x - (h / 2) in REAL by XREAL_0:def 1;
then A8: x - (h / 2) in dom (r (#) f) by FUNCT_2:def 1;
((cdif ((r (#) f),h)) . (0 + 1)) . x = (cD (((cdif ((r (#) f),h)) . 0),h)) . x by Def8
.= (cD ((r (#) f),h)) . x by Def8
.= ((r (#) f) . (x + (h / 2))) - ((r (#) f) . (x - (h / 2))) by Th5
.= (r * (f . (x + (h / 2)))) - ((r (#) f) . (x - (h / 2))) by A7, VALUED_1:def 5
.= (r * (f . (x + (h / 2)))) - (r * (f . (x - (h / 2)))) by A8, VALUED_1:def 5
.= r * ((f . (x + (h / 2))) - (f . (x - (h / 2))))
.= r * ((cD (f,h)) . x) by Th5
.= r * ((cD (((cdif (f,h)) . 0),h)) . x) by Def8
.= r * (((cdif (f,h)) . (0 + 1)) . x) by Def8 ;
hence ((cdif ((r (#) f),h)) . (0 + 1)) . x = r * (((cdif (f,h)) . (0 + 1)) . x) ; :: thesis: verum

end;

for n being Nat holds S₁[n] from NAT_1:sch 2(A6, A1);
hence ((cdif ((r (#) f),h)) . (n + 1)) . x = r * (((cdif (f,h)) . (n + 1)) . x) ; :: thesis: verum