let X be non empty set ; :: thesis: for Y being ComplexNormSpace
for f, g being Point of (C_NormSpace_of_BoundedFunctions (X,Y))
for c being Complex holds
( ( ||.f.|| = 0 implies f = 0. (C_NormSpace_of_BoundedFunctions (X,Y)) ) & ( f = 0. (C_NormSpace_of_BoundedFunctions (X,Y)) implies ||.f.|| = 0 ) & ||.(c * f).|| = |.c.| * ||.f.|| & ||.(f + g).|| <= ||.f.|| + ||.g.|| )
let Y be ComplexNormSpace; :: thesis: for f, g being Point of (C_NormSpace_of_BoundedFunctions (X,Y))
for c being Complex holds
( ( ||.f.|| = 0 implies f = 0. (C_NormSpace_of_BoundedFunctions (X,Y)) ) & ( f = 0. (C_NormSpace_of_BoundedFunctions (X,Y)) implies ||.f.|| = 0 ) & ||.(c * f).|| = |.c.| * ||.f.|| & ||.(f + g).|| <= ||.f.|| + ||.g.|| )
let f, g be Point of (C_NormSpace_of_BoundedFunctions (X,Y)); :: thesis: for c being Complex holds
( ( ||.f.|| = 0 implies f = 0. (C_NormSpace_of_BoundedFunctions (X,Y)) ) & ( f = 0. (C_NormSpace_of_BoundedFunctions (X,Y)) implies ||.f.|| = 0 ) & ||.(c * f).|| = |.c.| * ||.f.|| & ||.(f + g).|| <= ||.f.|| + ||.g.|| )
let c be Complex; :: thesis: ( ( ||.f.|| = 0 implies f = 0. (C_NormSpace_of_BoundedFunctions (X,Y)) ) & ( f = 0. (C_NormSpace_of_BoundedFunctions (X,Y)) implies ||.f.|| = 0 ) & ||.(c * f).|| = |.c.| * ||.f.|| & ||.(f + g).|| <= ||.f.|| + ||.g.|| )
A1: now :: thesis: ( f = 0. (C_NormSpace_of_BoundedFunctions (X,Y)) implies ||.f.|| = 0 )
assume A2: f = 0. (C_NormSpace_of_BoundedFunctions (X,Y)) ; :: thesis: ||.f.|| = 0
thus ||.f.|| = 0 :: thesis: verum
proof
reconsider g = f as bounded Function of X, the carrier of Y by Def5;
set z = X --> (0. Y);
reconsider z = X --> (0. Y) as Function of X, the carrier of Y ;
consider r0 being object such that
A3: r0 in PreNorms g by XBOOLE_0:def 1;
reconsider r0 = r0 as Real by A3;
A4: ( ( for s being Real st s in PreNorms g holds
s <= 0 ) implies upper_bound (PreNorms g) <= 0 ) by SEQ_4:45;
A5: ( not PreNorms g is empty & PreNorms g is bounded_above ) by Th12;
A6: z = g by A2, Th16;
A7: now :: thesis: for r being Real st r in PreNorms g holds
( 0 <= r & r <= 0 )
let r be Real; :: thesis: ( r in PreNorms g implies ( 0 <= r & r <= 0 ) )
assume r in PreNorms g ; :: thesis: ( 0 <= r & r <= 0 )
then consider t being Element of X such that
A8: r = ||.(g . t).|| ;
||.(g . t).|| = ||.(0. Y).|| by A6, FUNCOP_1:7
.= 0 ;
hence ( 0 <= r & r <= 0 ) by A8; :: thesis: verum
end;
then 0 <= r0 by A3;
then upper_bound (PreNorms g) = 0 by A7, A5, A3, A4, SEQ_4:def 1;
then (ComplexBoundedFunctionsNorm (X,Y)) . f = 0 by Th15;
hence ||.f.|| = 0 ; :: thesis: verum
end;
end;
A9: ||.(f + g).|| <= ||.f.|| + ||.g.||
proof
reconsider f1 = f, g1 = g, h1 = f + g as bounded Function of X, the carrier of Y by Def5;
A10: ( ( for s being Real st s in PreNorms h1 holds
s <= ||.f.|| + ||.g.|| ) implies upper_bound (PreNorms h1) <= ||.f.|| + ||.g.|| ) by SEQ_4:45;
A11: now :: thesis: for t being Element of X holds ||.(h1 . t).|| <= ||.f.|| + ||.g.||
let t be Element of X; :: thesis: ||.(h1 . t).|| <= ||.f.|| + ||.g.||
( ||.(f1 . t).|| <= ||.f.|| & ||.(g1 . t).|| <= ||.g.|| ) by Th17;
then A12: ||.(f1 . t).|| + ||.(g1 . t).|| <= ||.f.|| + ||.g.|| by XREAL_1:7;
( ||.(h1 . t).|| = ||.((f1 . t) + (g1 . t)).|| & ||.((f1 . t) + (g1 . t)).|| <= ||.(f1 . t).|| + ||.(g1 . t).|| ) by Th20, CLVECT_1:def 13;
hence ||.(h1 . t).|| <= ||.f.|| + ||.g.|| by A12, XXREAL_0:2; :: thesis: verum
end;
A13: now :: thesis: for r being Real st r in PreNorms h1 holds
r <= ||.f.|| + ||.g.||
let r be Real; :: thesis: ( r in PreNorms h1 implies r <= ||.f.|| + ||.g.|| )
assume r in PreNorms h1 ; :: thesis: r <= ||.f.|| + ||.g.||
then ex t being Element of X st r = ||.(h1 . t).|| ;
hence r <= ||.f.|| + ||.g.|| by A11; :: thesis: verum
end;
(ComplexBoundedFunctionsNorm (X,Y)) . (f + g) = upper_bound (PreNorms h1) by Th15;
hence ||.(f + g).|| <= ||.f.|| + ||.g.|| by A13, A10; :: thesis: verum
end;
A14: ||.(c * f).|| = |.c.| * ||.f.||
proof
reconsider f1 = f, h1 = c * f as bounded Function of X, the carrier of Y by Def5;
A15: ( ( for s being Real st s in PreNorms h1 holds
s <= |.c.| * ||.f.|| ) implies upper_bound (PreNorms h1) <= |.c.| * ||.f.|| ) by SEQ_4:45;
A16: now :: thesis: for t being Element of X holds ||.(h1 . t).|| <= |.c.| * ||.f.||
let t be Element of X; :: thesis: ||.(h1 . t).|| <= |.c.| * ||.f.||
A17: 0 <= |.c.| by COMPLEX1:46;
( ||.(h1 . t).|| = ||.(c * (f1 . t)).|| & ||.(c * (f1 . t)).|| = |.c.| * ||.(f1 . t).|| ) by Th21, CLVECT_1:def 13;
hence ||.(h1 . t).|| <= |.c.| * ||.f.|| by A17, Th17, XREAL_1:64; :: thesis: verum
end;
A18: now :: thesis: for r being Real st r in PreNorms h1 holds
r <= |.c.| * ||.f.||
let r be Real; :: thesis: ( r in PreNorms h1 implies r <= |.c.| * ||.f.|| )
assume r in PreNorms h1 ; :: thesis: r <= |.c.| * ||.f.||
then ex t being Element of X st r = ||.(h1 . t).|| ;
hence r <= |.c.| * ||.f.|| by A16; :: thesis: verum
end;
A19: now :: thesis: ( ( c <> 0c & |.c.| * ||.f.|| <= ||.(c * f).|| ) or ( c = 0c & ||.(c * f).|| = |.c.| * ||.f.|| ) )
per cases ( c <> 0c or c = 0c ) ;
case A20: c <> 0c ; :: thesis: |.c.| * ||.f.|| <= ||.(c * f).||
A21: now :: thesis: for t being Element of X holds ||.(f1 . t).|| <= (|.c.| ") * ||.(c * f).||
let t be Element of X; :: thesis: ||.(f1 . t).|| <= (|.c.| ") * ||.(c * f).||
A22: |.(c ").| = |.(1r / c).| by COMPLEX1:def 4, XCMPLX_1:215
.= 1 / |.c.| by COMPLEX1:48, COMPLEX1:67
.= 1 * (|.c.| ") by XCMPLX_0:def 9
.= |.c.| " ;
h1 . t = c * (f1 . t) by Th21;
then A23: (c ") * (h1 . t) = ((c ") * c) * (f1 . t) by CLVECT_1:def 4
.= 1r * (f1 . t) by A20, COMPLEX1:def 4, XCMPLX_0:def 7
.= f1 . t by CLVECT_1:def 5 ;
( ||.((c ") * (h1 . t)).|| = |.(c ").| * ||.(h1 . t).|| & 0 <= |.(c ").| ) by CLVECT_1:def 13, COMPLEX1:46;
hence ||.(f1 . t).|| <= (|.c.| ") * ||.(c * f).|| by A23, A22, Th17, XREAL_1:64; :: thesis: verum
end;
A24: now :: thesis: for r being Real st r in PreNorms f1 holds
r <= (|.c.| ") * ||.(c * f).||
let r be Real; :: thesis: ( r in PreNorms f1 implies r <= (|.c.| ") * ||.(c * f).|| )
assume r in PreNorms f1 ; :: thesis: r <= (|.c.| ") * ||.(c * f).||
then ex t being Element of X st r = ||.(f1 . t).|| ;
hence r <= (|.c.| ") * ||.(c * f).|| by A21; :: thesis: verum
end;
A25: ( ( for s being Real st s in PreNorms f1 holds
s <= (|.c.| ") * ||.(c * f).|| ) implies upper_bound (PreNorms f1) <= (|.c.| ") * ||.(c * f).|| ) by SEQ_4:45;
A26: 0 <= |.c.| by COMPLEX1:46;
(ComplexBoundedFunctionsNorm (X,Y)) . f = upper_bound (PreNorms f1) by Th15;
then ||.f.|| <= (|.c.| ") * ||.(c * f).|| by A24, A25;
then |.c.| * ||.f.|| <= |.c.| * ((|.c.| ") * ||.(c * f).||) by A26, XREAL_1:64;
then A27: |.c.| * ||.f.|| <= (|.c.| * (|.c.| ")) * ||.(c * f).|| ;
|.c.| <> 0 by A20, COMPLEX1:47;
then |.c.| * ||.f.|| <= 1 * ||.(c * f).|| by A27, XCMPLX_0:def 7;
hence |.c.| * ||.f.|| <= ||.(c * f).|| ; :: thesis: verum
end;
end;
end;
(ComplexBoundedFunctionsNorm (X,Y)) . (c * f) = upper_bound (PreNorms h1) by Th15;
then ||.(c * f).|| <= |.c.| * ||.f.|| by A18, A15;
hence ||.(c * f).|| = |.c.| * ||.f.|| by A19, XXREAL_0:1; :: thesis: verum
end;
now :: thesis: ( ||.f.|| = 0 implies f = 0. (C_NormSpace_of_BoundedFunctions (X,Y)) )
reconsider g = f as bounded Function of X, the carrier of Y by Def5;
set z = X --> (0. Y);
reconsider z = X --> (0. Y) as Function of X, the carrier of Y ;
assume A29: ||.f.|| = 0 ; :: thesis: f = 0. (C_NormSpace_of_BoundedFunctions (X,Y))
now :: thesis: for t being Element of X holds g . t = z . t
let t be Element of X; :: thesis: g . t = z . t
||.(g . t).|| <= ||.f.|| by Th17;
then ||.(g . t).|| = 0 by A29, CLVECT_1:105;
hence g . t = 0. Y by NORMSP_0:def 5
.= z . t by FUNCOP_1:7 ;
:: thesis: verum
end;
then g = z by FUNCT_2:63;
hence f = 0. (C_NormSpace_of_BoundedFunctions (X,Y)) by Th16; :: thesis: verum
end;
hence ( ( ||.f.|| = 0 implies f = 0. (C_NormSpace_of_BoundedFunctions (X,Y)) ) & ( f = 0. (C_NormSpace_of_BoundedFunctions (X,Y)) implies ||.f.|| = 0 ) & ||.(c * f).|| = |.c.| * ||.f.|| & ||.(f + g).|| <= ||.f.|| + ||.g.|| ) by A1, A14, A9; :: thesis: verum