now :: thesis: for r1, r2 being Real st r1 in [.PI,(2 * PI).] /\ (dom cos) & r2 in [.PI,(2 * PI).] /\ (dom cos) & r1 < r2 holds
cos . r2 > cos . r1

let r1, r2 be Real; :: thesis: ( r1 in [.PI,(2 * PI).] /\ (dom cos) & r2 in [.PI,(2 * PI).] /\ (dom cos) & r1 < r2 implies cos . r2 > cos . r1 )
assume that
A1: r1 in [.PI,(2 * PI).] /\ (dom cos) and
A2: r2 in [.PI,(2 * PI).] /\ (dom cos) and
A3: r1 < r2 ; :: thesis: cos . r2 > cos . r1
A4: r1 in dom cos by A1, XBOOLE_0:def 4;
set r3 = (r1 + r2) / 2;
r1 in [.PI,(2 * PI).] by A1, XBOOLE_0:def 4;
then A5: PI <= r1 by XXREAL_1:1;
|.(cos ((r1 + r2) / 2)).| <= 1 by SIN_COS:27;
then A6: |.(cos . ((r1 + r2) / 2)).| <= 1 by SIN_COS:def 19;
then A7: cos . ((r1 + r2) / 2) <= 1 by ABSVALUE:5;
r2 in [.PI,(2 * PI).] by A2, XBOOLE_0:def 4;
then A8: r2 <= 2 * PI by XXREAL_1:1;
A9: r1 < (r1 + r2) / 2 by A3, XREAL_1:226;
then A10: PI < (r1 + r2) / 2 by A5, XXREAL_0:2;
A11: (r1 + r2) / 2 < r2 by A3, XREAL_1:226;
then (r1 + r2) / 2 < 2 * PI by A8, XXREAL_0:2;
then (r1 + r2) / 2 in ].PI,(2 * PI).[ by A10, XXREAL_1:4;
then A12: (r1 + r2) / 2 in ].PI,(2 * PI).[ /\ (dom cos) by SIN_COS:24, XBOOLE_0:def 4;
|.(cos r2).| <= 1 by SIN_COS:27;
then |.(cos . r2).| <= 1 by SIN_COS:def 19;
then A13: cos . r2 >= - 1 by ABSVALUE:5;
A14: r2 in dom cos by A2, XBOOLE_0:def 4;
A15: cos . ((r1 + r2) / 2) >= - 1 by A6, ABSVALUE:5;

now :: thesis: cos . r2 > cos . r1

per cases ( PI < r1 or PI = r1 ) by A5, XXREAL_0:1;

suppose A16: PI < r1 ; :: thesis: cos . r2 > cos . r1

then A17: PI < r2 by A3, XXREAL_0:2;

now :: thesis: cos . r2 > cos . r1

per cases ( r2 < 2 * PI or r2 = 2 * PI ) by A8, XXREAL_0:1;

suppose A18: r2 < 2 * PI ; :: thesis: cos . r2 > cos . r1

then r1 < 2 * PI by A3, XXREAL_0:2;
then r1 in ].PI,(2 * PI).[ by A16, XXREAL_1:4;
then A19: r1 in ].PI,(2 * PI).[ /\ (dom cos) by A4, XBOOLE_0:def 4;
r2 in ].PI,(2 * PI).[ by A17, A18, XXREAL_1:4;
then r2 in ].PI,(2 * PI).[ /\ (dom cos) by A14, XBOOLE_0:def 4;
hence cos . r2 > cos . r1 by A3, A19, Th22, RFUNCT_2:20; :: thesis: verum

end;

suppose A20: r2 = 2 * PI ; :: thesis: not cos . r2 <= cos . r1

then r1 in ].PI,(2 * PI).[ by A3, A16, XXREAL_1:4;
then r1 in ].PI,(2 * PI).[ /\ (dom cos) by A4, XBOOLE_0:def 4;
then A21: cos . ((r1 + r2) / 2) > cos . r1 by A9, A12, Th22, RFUNCT_2:20;
assume cos . r2 <= cos . r1 ; :: thesis: contradiction
hence contradiction by A7, A20, A21, SIN_COS:76, XXREAL_0:2; :: thesis: verum

end;

end;

end;

hence cos . r2 > cos . r1 ; :: thesis: verum

end;

suppose A22: PI = r1 ; :: thesis: cos . r2 > cos . r1

now :: thesis: not cos . r2 <= cos . r1

per cases ( r2 < 2 * PI or r2 = 2 * PI ) by A8, XXREAL_0:1;

suppose r2 < 2 * PI ; :: thesis: not cos . r2 <= cos . r1

then r2 in ].PI,(2 * PI).[ by A3, A22, XXREAL_1:4;
then r2 in ].PI,(2 * PI).[ /\ (dom cos) by A14, XBOOLE_0:def 4;
then A23: cos . r2 > cos . ((r1 + r2) / 2) by A11, A12, Th22, RFUNCT_2:20;
assume cos . r2 <= cos . r1 ; :: thesis: contradiction
hence contradiction by A15, A13, A22, A23, SIN_COS:76, XXREAL_0:1; :: thesis: verum

end;

suppose r2 = 2 * PI ; :: thesis: cos . r2 > cos . r1

hence cos . r2 > cos . r1 by A22, SIN_COS:76; :: thesis: verum

end;

end;

end;

hence cos . r2 > cos . r1 ; :: thesis: verum

end;

end;

end;

hence cos . r2 > cos . r1 ; :: thesis: verum

end;

hence cos | [.PI,(2 * PI).] is increasing by RFUNCT_2:20; :: thesis: verum