let X be ComplexUnitarySpace; :: thesis: for z being Complex
for seq being sequence of X st seq is convergent holds
z * seq is convergent
let z be Complex; :: thesis: for seq being sequence of X st seq is convergent holds
z * seq is convergent
let seq be sequence of X; :: thesis: ( seq is convergent implies z * seq is convergent )
assume seq is convergent ; :: thesis: z * seq is convergent
then consider g being Point of X such that
A1: for r being Real st r > 0 holds
ex m being Nat st
for n being Nat st n >= m holds
dist ((seq . n),g) < r ;
take h = z * g; :: according to CLVECT_2:def 1 :: thesis: for r being Real st r > 0 holds
ex m being Nat st
for n being Nat st n >= m holds
dist (((z * seq) . n),h) < r

A2: now :: thesis: ( z <> 0 implies for r being Real st r > 0 holds
ex k being Nat st
for n being Nat st n >= k holds
dist (((z * seq) . n),h) < r )

A3: 0 / |.z.| = 0 ;
assume A4: z <> 0 ; :: thesis: for r being Real st r > 0 holds
ex k being Nat st
for n being Nat st n >= k holds
dist (((z * seq) . n),h) < r
then A5: |.z.| > 0 by COMPLEX1:47;
let r be Real; :: thesis: ( r > 0 implies ex k being Nat st
for n being Nat st n >= k holds
dist (((z * seq) . n),h) < r )
assume r > 0 ; :: thesis: ex k being Nat st
for n being Nat st n >= k holds
dist (((z * seq) . n),h) < r
then consider m1 being Nat such that
A6: for n being Nat st n >= m1 holds
dist ((seq . n),g) < r / |.z.| by A1, A5, A3, XREAL_1:74;
take k = m1; :: thesis: for n being Nat st n >= k holds
dist (((z * seq) . n),h) < r
let n be Nat; :: thesis: ( n >= k implies dist (((z * seq) . n),h) < r )
assume n >= k ; :: thesis: dist (((z * seq) . n),h) < r
then A7: dist ((seq . n),g) < r / |.z.| by A6;
A8: |.z.| <> 0 by A4, COMPLEX1:47;
A9: |.z.| * (r / |.z.|) = |.z.| * ((|.z.| ") * r) by XCMPLX_0:def 9
.= (|.z.| * (|.z.| ")) * r
.= 1 * r by A8, XCMPLX_0:def 7
.= r ;
dist ((z * (seq . n)),(z * g)) = ||.((z * (seq . n)) - (z * g)).|| by CSSPACE:def 16
.= ||.(z * ((seq . n) - g)).|| by CLVECT_1:9
.= |.z.| * ||.((seq . n) - g).|| by CSSPACE:43
.= |.z.| * (dist ((seq . n),g)) by CSSPACE:def 16 ;
then dist ((z * (seq . n)),h) < r by A5, A7, A9, XREAL_1:68;
hence dist (((z * seq) . n),h) < r by CLVECT_1:def 14; :: thesis: verum

end;

now :: thesis: ( z = 0 implies for r being Real st r > 0 holds
ex k being Nat st
for n being Nat st n >= k holds
dist (((z * seq) . n),h) < r )

assume A10: z = 0 ; :: thesis: for r being Real st r > 0 holds
ex k being Nat st
for n being Nat st n >= k holds
dist (((z * seq) . n),h) < r
let r be Real; :: thesis: ( r > 0 implies ex k being Nat st
for n being Nat st n >= k holds
dist (((z * seq) . n),h) < r )
assume r > 0 ; :: thesis: ex k being Nat st
for n being Nat st n >= k holds
dist (((z * seq) . n),h) < r
then consider m1 being Nat such that
A11: for n being Nat st n >= m1 holds
dist ((seq . n),g) < r by A1;
take k = m1; :: thesis: for n being Nat st n >= k holds
dist (((z * seq) . n),h) < r
let n be Nat; :: thesis: ( n >= k implies dist (((z * seq) . n),h) < r )
assume n >= k ; :: thesis: dist (((z * seq) . n),h) < r
then A12: dist ((seq . n),g) < r by A11;
dist ((z * (seq . n)),(z * g)) = dist ((0c * (seq . n)),H₁(X)) by A10, CLVECT_1:1
.= dist (H₁(X),H₁(X)) by CLVECT_1:1
.= 0 by CSSPACE:50 ;
then dist ((z * (seq . n)),h) < r by A12, CSSPACE:53;
hence dist (((z * seq) . n),h) < r by CLVECT_1:def 14; :: thesis: verum

end;

hence for r being Real st r > 0 holds
ex m being Nat st
for n being Nat st n >= m holds
dist (((z * seq) . n),h) < r by A2; :: thesis: verum