let X be ComplexUnitarySpace; :: thesis: for seq1, seq2 being sequence of X st seq1 is convergent & ex k being Nat st
for n being Nat st n >= k holds
seq2 . n = seq1 . n holds
lim seq1 = lim seq2
let seq1, seq2 be sequence of X; :: thesis: ( seq1 is convergent & ex k being Nat st
for n being Nat st n >= k holds
seq2 . n = seq1 . n implies lim seq1 = lim seq2 )
assume that
A1: seq1 is convergent and
A2: ex k being Nat st
for n being Nat st n >= k holds
seq2 . n = seq1 . n ; :: thesis: lim seq1 = lim seq2
consider k being Nat such that
A3: for n being Nat st n >= k holds
seq2 . n = seq1 . n by A2;

A4: now :: thesis: for r being Real st r > 0 holds
ex m being Nat st
for n being Nat st n >= m holds
dist ((seq2 . n),(lim seq1)) < r

let r be Real; :: thesis: ( r > 0 implies ex m being Nat st
for n being Nat st n >= m holds
dist ((seq2 . n),(lim seq1)) < r )
assume r > 0 ; :: thesis: ex m being Nat st
for n being Nat st n >= m holds
dist ((seq2 . n),(lim seq1)) < r
then consider m1 being Nat such that
A5: for n being Nat st n >= m1 holds
dist ((seq1 . n),(lim seq1)) < r by A1, Def2;

A6: now :: thesis: ( m1 <= k implies ex m being Nat st
for n being Nat st n >= m holds
dist ((seq2 . n),(lim seq1)) < r )

assume A7: m1 <= k ; :: thesis: ex m being Nat st
for n being Nat st n >= m holds
dist ((seq2 . n),(lim seq1)) < r
take m = k; :: thesis: for n being Nat st n >= m holds
dist ((seq2 . n),(lim seq1)) < r
let n be Nat; :: thesis: ( n >= m implies dist ((seq2 . n),(lim seq1)) < r )
assume A8: n >= m ; :: thesis: dist ((seq2 . n),(lim seq1)) < r
then n >= m1 by A7, XXREAL_0:2;
then dist ((seq1 . n),(lim seq1)) < r by A5;
hence dist ((seq2 . n),(lim seq1)) < r by A3, A8; :: thesis: verum

end;

now :: thesis: ( k <= m1 implies ex m being Nat st
for n being Nat st n >= m holds
dist ((seq2 . n),(lim seq1)) < r )

assume A9: k <= m1 ; :: thesis: ex m being Nat st
for n being Nat st n >= m holds
dist ((seq2 . n),(lim seq1)) < r
take m = m1; :: thesis: for n being Nat st n >= m holds
dist ((seq2 . n),(lim seq1)) < r
let n be Nat; :: thesis: ( n >= m implies dist ((seq2 . n),(lim seq1)) < r )
assume A10: n >= m ; :: thesis: dist ((seq2 . n),(lim seq1)) < r
then seq2 . n = seq1 . n by A3, A9, XXREAL_0:2;
hence dist ((seq2 . n),(lim seq1)) < r by A5, A10; :: thesis: verum

end;

hence ex m being Nat st
for n being Nat st n >= m holds
dist ((seq2 . n),(lim seq1)) < r by A6; :: thesis: verum

end;

seq2 is convergent by A1, A2, Th2;
hence lim seq1 = lim seq2 by A4, Def2; :: thesis: verum