let V be ComplexLinearSpace; :: thesis: for u, v being VECTOR of V
for W being Subspace of V holds
( u in W iff v + W = (v + u) + W )
let u, v be VECTOR of V; :: thesis: for W being Subspace of V holds
( u in W iff v + W = (v + u) + W )
let W be Subspace of V; :: thesis: ( u in W iff v + W = (v + u) + W )
thus ( u in W implies v + W = (v + u) + W ) :: thesis: ( v + W = (v + u) + W implies u in W )

proof

assume A1: u in W ; :: thesis: v + W = (v + u) + W
thus v + W c= (v + u) + W :: according to XBOOLE_0:def 10 :: thesis: (v + u) + W c= v + W

proof

let x be object ; :: according to TARSKI:def 3 :: thesis: ( not x in v + W or x in (v + u) + W )
assume x in v + W ; :: thesis: x in (v + u) + W
then consider v1 being VECTOR of V such that
A2: x = v + v1 and
A3: v1 in W ;
A4: (v + u) + (v1 - u) = v + (u + (v1 - u)) by RLVECT_1:def 3
.= v + ((v1 + u) - u) by RLVECT_1:def 3
.= v + (v1 + (u - u)) by RLVECT_1:def 3
.= v + (v1 + (0. V)) by RLVECT_1:15
.= x by A2, RLVECT_1:4 ;
v1 - u in W by A1, A3, Th42;
hence x in (v + u) + W by A4; :: thesis: verum

end;

let x be object ; :: according to TARSKI:def 3 :: thesis: ( not x in (v + u) + W or x in v + W )
assume x in (v + u) + W ; :: thesis: x in v + W
then consider v2 being VECTOR of V such that
A5: x = (v + u) + v2 and
A6: v2 in W ;
A7: x = v + (u + v2) by A5, RLVECT_1:def 3;
u + v2 in W by A1, A6, Th39;
hence x in v + W by A7; :: thesis: verum

end;

assume A8: v + W = (v + u) + W ; :: thesis: u in W
( 0. V in W & v + (0. V) = v ) by Th36, RLVECT_1:4;
then v in (v + u) + W by A8;
then consider u1 being VECTOR of V such that
A9: v = (v + u) + u1 and
A10: u1 in W ;
( v = v + (0. V) & v = v + (u + u1) ) by A9, RLVECT_1:4, RLVECT_1:def 3;
then u + u1 = 0. V by RLVECT_1:8;
then u = - u1 by RLVECT_1:def 10;
hence u in W by A10, Th41; :: thesis: verum