let CNS be ComplexNormSpace; :: thesis: for S1, S2 being sequence of CNS st S1 is convergent & S2 is convergent holds
S1 + S2 is convergent
let S1, S2 be sequence of CNS; :: thesis: ( S1 is convergent & S2 is convergent implies S1 + S2 is convergent )
assume that
A1: S1 is convergent and
A2: S2 is convergent ; :: thesis: S1 + S2 is convergent
consider g1 being Point of CNS such that
A3: for r being Real st 0 < r holds
ex m being Nat st
for n being Nat st m <= n holds
||.((S1 . n) - g1).|| < r by A1;
consider g2 being Point of CNS such that
A4: for r being Real st 0 < r holds
ex m being Nat st
for n being Nat st m <= n holds
||.((S2 . n) - g2).|| < r by A2;
take g = g1 + g2; :: according to CLVECT_1:def 15 :: thesis: for r being Real st 0 < r holds
ex m being Nat st
for n being Nat st m <= n holds
||.(((S1 + S2) . n) - g).|| < r
let r be Real; :: thesis: ( 0 < r implies ex m being Nat st
for n being Nat st m <= n holds
||.(((S1 + S2) . n) - g).|| < r )
assume A5: 0 < r ; :: thesis: ex m being Nat st
for n being Nat st m <= n holds
||.(((S1 + S2) . n) - g).|| < r
then consider m1 being Nat such that
A6: for n being Nat st m1 <= n holds
||.((S1 . n) - g1).|| < r / 2 by A3;
consider m2 being Nat such that
A7: for n being Nat st m2 <= n holds
||.((S2 . n) - g2).|| < r / 2 by A4, A5;
reconsider k = m1 + m2 as Nat ;
take k ; :: thesis: for n being Nat st k <= n holds
||.(((S1 + S2) . n) - g).|| < r
let n be Nat; :: thesis: ( k <= n implies ||.(((S1 + S2) . n) - g).|| < r )
assume A8: k <= n ; :: thesis: ||.(((S1 + S2) . n) - g).|| < r
m2 <= k by NAT_1:12;
then m2 <= n by A8, XXREAL_0:2;
then A9: ||.((S2 . n) - g2).|| < r / 2 by A7;
A10: ||.(((S1 + S2) . n) - g).|| = ||.((- (g1 + g2)) + ((S1 . n) + (S2 . n))).|| by NORMSP_1:def 2
.= ||.(((- g1) + (- g2)) + ((S1 . n) + (S2 . n))).|| by RLVECT_1:31
.= ||.(((S1 . n) + ((- g1) + (- g2))) + (S2 . n)).|| by RLVECT_1:def 3
.= ||.((((S1 . n) - g1) + (- g2)) + (S2 . n)).|| by RLVECT_1:def 3
.= ||.(((S1 . n) - g1) + ((S2 . n) - g2)).|| by RLVECT_1:def 3 ;
A11: ||.(((S1 . n) - g1) + ((S2 . n) - g2)).|| <= ||.((S1 . n) - g1).|| + ||.((S2 . n) - g2).|| by Def13;
m1 <= m1 + m2 by NAT_1:12;
then m1 <= n by A8, XXREAL_0:2;
then ||.((S1 . n) - g1).|| < r / 2 by A6;
then ||.((S1 . n) - g1).|| + ||.((S2 . n) - g2).|| < (r / 2) + (r / 2) by A9, XREAL_1:8;
hence ||.(((S1 + S2) . n) - g).|| < r by A10, A11, XXREAL_0:2; :: thesis: verum