let X, Y be ComplexNormSpace; :: thesis: for f, g being Point of (C_NormSpace_of_BoundedLinearOperators (X,Y))
for c being Complex holds
( ( ||.f.|| = 0 implies f = 0. (C_NormSpace_of_BoundedLinearOperators (X,Y)) ) & ( f = 0. (C_NormSpace_of_BoundedLinearOperators (X,Y)) implies ||.f.|| = 0 ) & ||.(c * f).|| = |.c.| * ||.f.|| & ||.(f + g).|| <= ||.f.|| + ||.g.|| )
let f, g be Point of (C_NormSpace_of_BoundedLinearOperators (X,Y)); :: thesis: for c being Complex holds
( ( ||.f.|| = 0 implies f = 0. (C_NormSpace_of_BoundedLinearOperators (X,Y)) ) & ( f = 0. (C_NormSpace_of_BoundedLinearOperators (X,Y)) implies ||.f.|| = 0 ) & ||.(c * f).|| = |.c.| * ||.f.|| & ||.(f + g).|| <= ||.f.|| + ||.g.|| )
let c be Complex; :: thesis: ( ( ||.f.|| = 0 implies f = 0. (C_NormSpace_of_BoundedLinearOperators (X,Y)) ) & ( f = 0. (C_NormSpace_of_BoundedLinearOperators (X,Y)) implies ||.f.|| = 0 ) & ||.(c * f).|| = |.c.| * ||.f.|| & ||.(f + g).|| <= ||.f.|| + ||.g.|| )
A1: now :: thesis: ( f = 0. (C_NormSpace_of_BoundedLinearOperators (X,Y)) implies ||.f.|| = 0 )
assume A2: f = 0. (C_NormSpace_of_BoundedLinearOperators (X,Y)) ; :: thesis: ||.f.|| = 0
thus ||.f.|| = 0 :: thesis: verum
proof
reconsider g = f as Lipschitzian LinearOperator of X,Y by Def7;
set z = the carrier of X --> (0. Y);
reconsider z = the carrier of X --> (0. Y) as Function of the carrier of X, the carrier of Y ;
consider r0 being object such that
A3: r0 in PreNorms g by XBOOLE_0:def 1;
reconsider r0 = r0 as Real by A3;
A4: ( ( for s being Real st s in PreNorms g holds
s <= 0 ) implies upper_bound (PreNorms g) <= 0 ) by SEQ_4:45;
A5: ( not PreNorms g is empty & PreNorms g is bounded_above ) by Th26;
A6: z = g by A2, Th30;
A7: now :: thesis: for r being Real st r in PreNorms g holds
( 0 <= r & r <= 0 )
let r be Real; :: thesis: ( r in PreNorms g implies ( 0 <= r & r <= 0 ) )
assume r in PreNorms g ; :: thesis: ( 0 <= r & r <= 0 )
then consider t being VECTOR of X such that
A8: r = ||.(g . t).|| and
||.t.|| <= 1 ;
||.(g . t).|| = ||.(0. Y).|| by A6, FUNCOP_1:7
.= 0 by NORMSP_0:def 6 ;
hence ( 0 <= r & r <= 0 ) by A8; :: thesis: verum
end;
then 0 <= r0 by A3;
then upper_bound (PreNorms g) = 0 by A7, A5, A3, A4, SEQ_4:def 1;
then (BoundedLinearOperatorsNorm (X,Y)) . f = 0 by Th29;
hence ||.f.|| = 0 ; :: thesis: verum
end;
end;
A9: ||.(f + g).|| <= ||.f.|| + ||.g.||
proof
reconsider f1 = f, g1 = g, h1 = f + g as Lipschitzian LinearOperator of X,Y by Def7;
A10: ( ( for s being Real st s in PreNorms h1 holds
s <= ||.f.|| + ||.g.|| ) implies upper_bound (PreNorms h1) <= ||.f.|| + ||.g.|| ) by SEQ_4:45;
A11: now :: thesis: for t being VECTOR of X st ||.t.|| <= 1 holds
||.(h1 . t).|| <= ||.f.|| + ||.g.||
let t be VECTOR of X; :: thesis: ( ||.t.|| <= 1 implies ||.(h1 . t).|| <= ||.f.|| + ||.g.|| )
assume A12: ||.t.|| <= 1 ; :: thesis: ||.(h1 . t).|| <= ||.f.|| + ||.g.||
0 <= ||.g.|| by Th32;
then A13: ||.g.|| * ||.t.|| <= ||.g.|| * 1 by A12, XREAL_1:64;
0 <= ||.f.|| by Th32;
then ||.f.|| * ||.t.|| <= ||.f.|| * 1 by A12, XREAL_1:64;
then A14: (||.f.|| * ||.t.||) + (||.g.|| * ||.t.||) <= (||.f.|| * 1) + (||.g.|| * 1) by A13, XREAL_1:7;
A15: ||.((f1 . t) + (g1 . t)).|| <= ||.(f1 . t).|| + ||.(g1 . t).|| by CLVECT_1:def 13;
A16: ||.(g1 . t).|| <= ||.g.|| * ||.t.|| by Th31;
||.(f1 . t).|| <= ||.f.|| * ||.t.|| by Th31;
then ||.(f1 . t).|| + ||.(g1 . t).|| <= (||.f.|| * ||.t.||) + (||.g.|| * ||.t.||) by A16, XREAL_1:7;
then A17: ||.(f1 . t).|| + ||.(g1 . t).|| <= ||.f.|| + ||.g.|| by A14, XXREAL_0:2;
||.(h1 . t).|| = ||.((f1 . t) + (g1 . t)).|| by Th34;
hence ||.(h1 . t).|| <= ||.f.|| + ||.g.|| by A15, A17, XXREAL_0:2; :: thesis: verum
end;
A18: now :: thesis: for r being Real st r in PreNorms h1 holds
r <= ||.f.|| + ||.g.||
let r be Real; :: thesis: ( r in PreNorms h1 implies r <= ||.f.|| + ||.g.|| )
assume r in PreNorms h1 ; :: thesis: r <= ||.f.|| + ||.g.||
then ex t being VECTOR of X st
( r = ||.(h1 . t).|| & ||.t.|| <= 1 ) ;
hence r <= ||.f.|| + ||.g.|| by A11; :: thesis: verum
end;
(BoundedLinearOperatorsNorm (X,Y)) . (f + g) = upper_bound (PreNorms h1) by Th29;
hence ||.(f + g).|| <= ||.f.|| + ||.g.|| by A18, A10; :: thesis: verum
end;
A19: ||.(c * f).|| = |.c.| * ||.f.||
proof
reconsider f1 = f, h1 = c * f as Lipschitzian LinearOperator of X,Y by Def7;
A20: ( ( for s being Real st s in PreNorms h1 holds
s <= |.c.| * ||.f.|| ) implies upper_bound (PreNorms h1) <= |.c.| * ||.f.|| ) by SEQ_4:45;
A21: now :: thesis: for t being VECTOR of X st ||.t.|| <= 1 holds
||.(h1 . t).|| <= |.c.| * ||.f.||
A22: 0 <= ||.f.|| by Th32;
let t be VECTOR of X; :: thesis: ( ||.t.|| <= 1 implies ||.(h1 . t).|| <= |.c.| * ||.f.|| )
assume ||.t.|| <= 1 ; :: thesis: ||.(h1 . t).|| <= |.c.| * ||.f.||
then A23: ||.f.|| * ||.t.|| <= ||.f.|| * 1 by A22, XREAL_1:64;
||.(f1 . t).|| <= ||.f.|| * ||.t.|| by Th31;
then A24: ||.(f1 . t).|| <= ||.f.|| by A23, XXREAL_0:2;
A25: ||.(c * (f1 . t)).|| = |.c.| * ||.(f1 . t).|| by CLVECT_1:def 13;
A26: 0 <= |.c.| by COMPLEX1:46;
||.(h1 . t).|| = ||.(c * (f1 . t)).|| by Th35;
hence ||.(h1 . t).|| <= |.c.| * ||.f.|| by A25, A24, A26, XREAL_1:64; :: thesis: verum
end;
A27: now :: thesis: for r being Real st r in PreNorms h1 holds
r <= |.c.| * ||.f.||
let r be Real; :: thesis: ( r in PreNorms h1 implies r <= |.c.| * ||.f.|| )
assume r in PreNorms h1 ; :: thesis: r <= |.c.| * ||.f.||
then ex t being VECTOR of X st
( r = ||.(h1 . t).|| & ||.t.|| <= 1 ) ;
hence r <= |.c.| * ||.f.|| by A21; :: thesis: verum
end;
A28: now :: thesis: ( ( c <> 0c & |.c.| * ||.f.|| <= ||.(c * f).|| ) or ( c = 0c & ||.(c * f).|| = |.c.| * ||.f.|| ) )
per cases ( c <> 0c or c = 0c ) ;
case A29: c <> 0c ; :: thesis: |.c.| * ||.f.|| <= ||.(c * f).||
A30: now :: thesis: for t being VECTOR of X st ||.t.|| <= 1 holds
||.(f1 . t).|| <= (|.c.| ") * ||.(c * f).||
A31: 0 <= ||.(c * f).|| by Th32;
let t be VECTOR of X; :: thesis: ( ||.t.|| <= 1 implies ||.(f1 . t).|| <= (|.c.| ") * ||.(c * f).|| )
assume ||.t.|| <= 1 ; :: thesis: ||.(f1 . t).|| <= (|.c.| ") * ||.(c * f).||
then A32: ||.(c * f).|| * ||.t.|| <= ||.(c * f).|| * 1 by A31, XREAL_1:64;
||.(h1 . t).|| <= ||.(c * f).|| * ||.t.|| by Th31;
then A33: ||.(h1 . t).|| <= ||.(c * f).|| by A32, XXREAL_0:2;
h1 . t = c * (f1 . t) by Th35;
then A34: (c ") * (h1 . t) = ((c ") * c) * (f1 . t) by CLVECT_1:def 4
.= 1r * (f1 . t) by A29, COMPLEX1:def 4, XCMPLX_0:def 7
.= f1 . t by CLVECT_1:def 5 ;
A35: |.(c ").| = |.c.| " by COMPLEX1:66;
A36: 0 <= |.(c ").| by COMPLEX1:46;
||.((c ") * (h1 . t)).|| = |.(c ").| * ||.(h1 . t).|| by CLVECT_1:def 13;
hence ||.(f1 . t).|| <= (|.c.| ") * ||.(c * f).|| by A34, A33, A36, A35, XREAL_1:64; :: thesis: verum
end;
A37: now :: thesis: for r being Real st r in PreNorms f1 holds
r <= (|.c.| ") * ||.(c * f).||
let r be Real; :: thesis: ( r in PreNorms f1 implies r <= (|.c.| ") * ||.(c * f).|| )
assume r in PreNorms f1 ; :: thesis: r <= (|.c.| ") * ||.(c * f).||
then ex t being VECTOR of X st
( r = ||.(f1 . t).|| & ||.t.|| <= 1 ) ;
hence r <= (|.c.| ") * ||.(c * f).|| by A30; :: thesis: verum
end;
A38: ( ( for s being Real st s in PreNorms f1 holds
s <= (|.c.| ") * ||.(c * f).|| ) implies upper_bound (PreNorms f1) <= (|.c.| ") * ||.(c * f).|| ) by SEQ_4:45;
A39: 0 <= |.c.| by COMPLEX1:46;
(BoundedLinearOperatorsNorm (X,Y)) . f = upper_bound (PreNorms f1) by Th29;
then ||.f.|| <= (|.c.| ") * ||.(c * f).|| by A37, A38;
then |.c.| * ||.f.|| <= |.c.| * ((|.c.| ") * ||.(c * f).||) by A39, XREAL_1:64;
then A40: |.c.| * ||.f.|| <= (|.c.| * (|.c.| ")) * ||.(c * f).|| ;
|.c.| <> 0 by A29, COMPLEX1:47;
then |.c.| * ||.f.|| <= 1 * ||.(c * f).|| by A40, XCMPLX_0:def 7;
hence |.c.| * ||.f.|| <= ||.(c * f).|| ; :: thesis: verum
end;
end;
end;
(BoundedLinearOperatorsNorm (X,Y)) . (c * f) = upper_bound (PreNorms h1) by Th29;
then ||.(c * f).|| <= |.c.| * ||.f.|| by A27, A20;
hence ||.(c * f).|| = |.c.| * ||.f.|| by A28, XXREAL_0:1; :: thesis: verum
end;
now :: thesis: ( ||.f.|| = 0 implies f = 0. (C_NormSpace_of_BoundedLinearOperators (X,Y)) )
reconsider g = f as Lipschitzian LinearOperator of X,Y by Def7;
set z = the carrier of X --> (0. Y);
reconsider z = the carrier of X --> (0. Y) as Function of the carrier of X, the carrier of Y ;
assume A42: ||.f.|| = 0 ; :: thesis: f = 0. (C_NormSpace_of_BoundedLinearOperators (X,Y))
now :: thesis: for t being VECTOR of X holds g . t = z . t
let t be VECTOR of X; :: thesis: g . t = z . t
||.(g . t).|| <= ||.f.|| * ||.t.|| by Th31;
then ||.(g . t).|| = 0 by A42, CLVECT_1:105;
hence g . t = 0. Y by NORMSP_0:def 5
.= z . t by FUNCOP_1:7 ;
:: thesis: verum
end;
then g = z by FUNCT_2:63;
hence f = 0. (C_NormSpace_of_BoundedLinearOperators (X,Y)) by Th30; :: thesis: verum
end;
hence ( ( ||.f.|| = 0 implies f = 0. (C_NormSpace_of_BoundedLinearOperators (X,Y)) ) & ( f = 0. (C_NormSpace_of_BoundedLinearOperators (X,Y)) implies ||.f.|| = 0 ) & ||.(c * f).|| = |.c.| * ||.f.|| & ||.(f + g).|| <= ||.f.|| + ||.g.|| ) by A1, A19, A9; :: thesis: verum