let V be RealLinearSpace; :: thesis: for v1, v2 being VECTOR of V
for L being Linear_Combination of V st L is circled & Carrier L = {v1,v2} & v1 <> v2 holds
( (L . v1) + (L . v2) = 1 & L . v1 >= 0 & L . v2 >= 0 & Sum L = ((L . v1) * v1) + ((L . v2) * v2) )
let v1, v2 be VECTOR of V; :: thesis: for L being Linear_Combination of V st L is circled & Carrier L = {v1,v2} & v1 <> v2 holds
( (L . v1) + (L . v2) = 1 & L . v1 >= 0 & L . v2 >= 0 & Sum L = ((L . v1) * v1) + ((L . v2) * v2) )
let L be Linear_Combination of V; :: thesis: ( L is circled & Carrier L = {v1,v2} & v1 <> v2 implies ( (L . v1) + (L . v2) = 1 & L . v1 >= 0 & L . v2 >= 0 & Sum L = ((L . v1) * v1) + ((L . v2) * v2) ) )
assume that
A1: L is circled and
A2: Carrier L = {v1,v2} and
A3: v1 <> v2 ; :: thesis: ( (L . v1) + (L . v2) = 1 & L . v1 >= 0 & L . v2 >= 0 & Sum L = ((L . v1) * v1) + ((L . v2) * v2) )
reconsider L = L as Linear_Combination of {v1,v2} by A2, RLVECT_2:def 6;
consider F being FinSequence of the carrier of V such that
A4: ( F is one-to-one & rng F = Carrier L ) and
A5: ex f being FinSequence of REAL st
( len f = len F & Sum f = 1 & ( for n being Nat st n in dom f holds
( f . n = L . (F . n) & f . n >= 0 ) ) ) by A1;
consider f being FinSequence of REAL such that
A6: len f = len F and
A7: Sum f = 1 and
A8: for n being Nat st n in dom f holds
( f . n = L . (F . n) & f . n >= 0 ) by A5;
len F = card {v1,v2} by A2, A4, FINSEQ_4:62;
then A9: len f = 2 by A3, A6, CARD_2:57;
then A10: dom f = {1,2} by FINSEQ_1:2, FINSEQ_1:def 3;
then A11: 1 in dom f by TARSKI:def 2;
then A12: f . 1 = L . (F . 1) by A8;
then f /. 1 = L . (F . 1) by A11, PARTFUN1:def 6;
then reconsider r1 = L . (F . 1) as Element of REAL ;
A13: 2 in dom f by A10, TARSKI:def 2;
then A14: f . 2 = L . (F . 2) by A8;
then f /. 2 = L . (F . 2) by A13, PARTFUN1:def 6;
then reconsider r2 = L . (F . 2) as Element of REAL ;
A15: f = <*r1,r2*> by A9, A12, A14, FINSEQ_1:44;

now :: thesis: ( (L . v1) + (L . v2) = 1 & L . v1 >= 0 & L . v2 >= 0 )

per cases ( F = <*v1,v2*> or F = <*v2,v1*> ) by A2, A3, A4, FINSEQ_3:99;

suppose F = <*v1,v2*> ; :: thesis: ( (L . v1) + (L . v2) = 1 & L . v1 >= 0 & L . v2 >= 0 )

then ( F . 1 = v1 & F . 2 = v2 ) ;
hence ( (L . v1) + (L . v2) = 1 & L . v1 >= 0 & L . v2 >= 0 ) by A7, A8, A11, A13, A12, A14, A15, RVSUM_1:77; :: thesis: verum

end;

suppose F = <*v2,v1*> ; :: thesis: ( (L . v1) + (L . v2) = 1 & L . v1 >= 0 & L . v2 >= 0 )

then ( F . 1 = v2 & F . 2 = v1 ) ;
hence ( (L . v1) + (L . v2) = 1 & L . v1 >= 0 & L . v2 >= 0 ) by A7, A8, A11, A13, A12, A14, A15, RVSUM_1:77; :: thesis: verum

end;

end;

end;

hence ( (L . v1) + (L . v2) = 1 & L . v1 >= 0 & L . v2 >= 0 & Sum L = ((L . v1) * v1) + ((L . v2) * v2) ) by A3, RLVECT_2:33; :: thesis: verum