let Fr1, Fr2 be XFinSequence of REAL ; :: thesis: ( dom Fr1 = dom Fr2 & ( for n being Nat st n in len Fr1 holds
Fr1 . n = Fr2 . ((len Fr1) -' (1 + n)) ) implies Sum Fr1 = Sum Fr2 )
assume that
A1: dom Fr1 = dom Fr2 and
A2: for n being Nat st n in len Fr1 holds
Fr1 . n = Fr2 . ((len Fr1) -' (1 + n)) ; :: thesis: Sum Fr1 = Sum Fr2
defpred S₁[ object , object ] means for i being Nat st i = $1 holds
$2 = (len Fr1) -' (1 + i);
A3: card (len Fr1) = card (len Fr1) ;
A4: for x being object st x in len Fr1 holds
ex y being object st
( y in len Fr1 & S₁[x,y] )

proof

let x be object ; :: thesis: ( x in len Fr1 implies ex y being object st
( y in len Fr1 & S₁[x,y] ) )
assume A5: x in len Fr1 ; :: thesis: ex y being object st
( y in len Fr1 & S₁[x,y] )
reconsider k = x as Nat by A5;
k < len Fr1 by A5, AFINSQ_1:86;
then k + 1 <= len Fr1 by NAT_1:13;
then A6: (len Fr1) -' (1 + k) = (len Fr1) - (1 + k) by XREAL_1:233;
take (len Fr1) -' (1 + k) ; :: thesis: ( (len Fr1) -' (1 + k) in len Fr1 & S₁[x,(len Fr1) -' (1 + k)] )
(len Fr1) + 0 < (len Fr1) + (1 + k) by XREAL_1:8;
then (len Fr1) - (1 + k) < ((len Fr1) + (1 + k)) - (1 + k) by XREAL_1:9;
hence ( (len Fr1) -' (1 + k) in len Fr1 & S₁[x,(len Fr1) -' (1 + k)] ) by A6, AFINSQ_1:86; :: thesis: verum

end;

consider P being Function of (len Fr1),(len Fr1) such that
A7: for x being object st x in len Fr1 holds
S₁[x,P . x] from FUNCT_2:sch 1(A4);
for x1, x2 being object st x1 in len Fr1 & x2 in len Fr1 & P . x1 = P . x2 holds
x1 = x2

proof

let x1, x2 be object ; :: thesis: ( x1 in len Fr1 & x2 in len Fr1 & P . x1 = P . x2 implies x1 = x2 )
assume that
A8: x1 in len Fr1 and
A9: x2 in len Fr1 and
A10: P . x1 = P . x2 ; :: thesis: x1 = x2
reconsider i = x1, j = x2 as Nat by A8, A9;
j < len Fr1 by A9, AFINSQ_1:86;
then j + 1 <= len Fr1 by NAT_1:13;
then (len Fr1) -' (1 + j) = (len Fr1) - (1 + j) by XREAL_1:233;
then A11: P . x2 = (len Fr1) - (1 + j) by A7, A9;
i < len Fr1 by A8, AFINSQ_1:86;
then i + 1 <= len Fr1 by NAT_1:13;
then (len Fr1) -' (1 + i) = (len Fr1) - (1 + i) by XREAL_1:233;
then P . x1 = (len Fr1) - (1 + i) by A7, A8;
hence x1 = x2 by A10, A11; :: thesis: verum

end;

then A12: P is one-to-one by FUNCT_2:56;
then P is onto by A3, FINSEQ_4:63;
then reconsider P = P as Permutation of (dom Fr1) by A12;

A13: now :: thesis: for x being object st x in dom Fr1 holds
Fr1 . x = Fr2 . (P . x)

let x be object ; :: thesis: ( x in dom Fr1 implies Fr1 . x = Fr2 . (P . x) )
assume A14: x in dom Fr1 ; :: thesis: Fr1 . x = Fr2 . (P . x)
reconsider k = x as Nat by A14;
P . k = (len Fr1) -' (1 + k) by A7, A14;
hence Fr1 . x = Fr2 . (P . x) by A2, A14; :: thesis: verum

end;

A15: for x being object st x in dom Fr1 holds
( x in dom P & P . x in dom Fr2 )

proof

let x be object ; :: thesis: ( x in dom Fr1 implies ( x in dom P & P . x in dom Fr2 ) )
assume x in dom Fr1 ; :: thesis: ( x in dom P & P . x in dom Fr2 )
hence x in dom P by FUNCT_2:52; :: thesis: P . x in dom Fr2
then P . x in rng P by FUNCT_1:3;
then P . x in dom Fr1 ;
then P . x in dom P by FUNCT_2:52;
hence P . x in dom Fr2 by A1; :: thesis: verum

end;

for x being object st x in dom P & P . x in dom Fr2 holds
x in dom Fr1 ;
then Fr1 = Fr2 * P by A15, A13, FUNCT_1:10;
then addreal "**" Fr1 = addreal "**" Fr2 by A1, AFINSQ_2:45
.= Sum Fr2 by AFINSQ_2:48 ;
hence Sum Fr1 = Sum Fr2 by AFINSQ_2:48; :: thesis: verum