let Y be non empty set ; :: thesis: for G being Subset of (PARTITIONS Y)
for a, b being Function of Y,BOOLEAN
for PA being a_partition of Y holds Ex (a,PA,G) '<' 'not' ((All ((a 'imp' b),PA,G)) '&' (All ((a 'imp' ('not' b)),PA,G)))
let G be Subset of (PARTITIONS Y); :: thesis: for a, b being Function of Y,BOOLEAN
for PA being a_partition of Y holds Ex (a,PA,G) '<' 'not' ((All ((a 'imp' b),PA,G)) '&' (All ((a 'imp' ('not' b)),PA,G)))
let a, b be Function of Y,BOOLEAN; :: thesis: for PA being a_partition of Y holds Ex (a,PA,G) '<' 'not' ((All ((a 'imp' b),PA,G)) '&' (All ((a 'imp' ('not' b)),PA,G)))
let PA be a_partition of Y; :: thesis: Ex (a,PA,G) '<' 'not' ((All ((a 'imp' b),PA,G)) '&' (All ((a 'imp' ('not' b)),PA,G)))
let z be Element of Y; :: according to BVFUNC_1:def 12 :: thesis: ( not (Ex (a,PA,G)) . z = TRUE or ('not' ((All ((a 'imp' b),PA,G)) '&' (All ((a 'imp' ('not' b)),PA,G)))) . z = TRUE )
A1: ('not' ((All ((a 'imp' b),PA,G)) '&' (All ((a 'imp' ('not' b)),PA,G)))) . z = 'not' (((All ((a 'imp' b),PA,G)) '&' (All ((a 'imp' ('not' b)),PA,G))) . z) by MARGREL1:def 19
.= 'not' (((All ((a 'imp' b),PA,G)) . z) '&' ((All ((a 'imp' ('not' b)),PA,G)) . z)) by MARGREL1:def 20 ;
assume A2: (Ex (a,PA,G)) . z = TRUE ; :: thesis: ('not' ((All ((a 'imp' b),PA,G)) '&' (All ((a 'imp' ('not' b)),PA,G)))) . z = TRUE

now :: thesis: ex x being Element of Y st
( x in EqClass (z,(CompF (PA,G))) & a . x = TRUE )

assume for x being Element of Y holds
( not x in EqClass (z,(CompF (PA,G))) or not a . x = TRUE ) ; :: thesis: contradiction
then (B_SUP (a,(CompF (PA,G)))) . z = FALSE by BVFUNC_1:def 17;
hence contradiction by A2, BVFUNC_2:def 10; :: thesis: verum

end;

then consider x1 being Element of Y such that
A3: x1 in EqClass (z,(CompF (PA,G))) and
A4: a . x1 = TRUE ;
A5: (a 'imp' b) . x1 = ('not' TRUE) 'or' (b . x1) by A4, BVFUNC_1:def 8
.= FALSE 'or' (b . x1) by MARGREL1:11
.= b . x1 by BINARITH:3 ;
A6: (a 'imp' ('not' b)) . x1 = ('not' TRUE) 'or' (('not' b) . x1) by A4, BVFUNC_1:def 8
.= FALSE 'or' (('not' b) . x1) by MARGREL1:11
.= ('not' b) . x1 by BINARITH:3 ;

per cases ( b . x1 = TRUE or b . x1 = FALSE ) by XBOOLEAN:def 3;

suppose b . x1 = TRUE ; :: thesis: ('not' ((All ((a 'imp' b),PA,G)) '&' (All ((a 'imp' ('not' b)),PA,G)))) . z = TRUE

then (a 'imp' ('not' b)) . x1 = 'not' TRUE by A6, MARGREL1:def 19
.= FALSE by MARGREL1:11 ;
then (B_INF ((a 'imp' ('not' b)),(CompF (PA,G)))) . z = FALSE by A3, BVFUNC_1:def 16;
hence ('not' ((All ((a 'imp' b),PA,G)) '&' (All ((a 'imp' ('not' b)),PA,G)))) . z = 'not' (((All ((a 'imp' b),PA,G)) . z) '&' FALSE) by A1, BVFUNC_2:def 9
.= 'not' FALSE by MARGREL1:12
.= TRUE by MARGREL1:11 ;
:: thesis: verum

end;

suppose b . x1 = FALSE ; :: thesis: ('not' ((All ((a 'imp' b),PA,G)) '&' (All ((a 'imp' ('not' b)),PA,G)))) . z = TRUE

then (B_INF ((a 'imp' b),(CompF (PA,G)))) . z = FALSE by A3, A5, BVFUNC_1:def 16;
hence ('not' ((All ((a 'imp' b),PA,G)) '&' (All ((a 'imp' ('not' b)),PA,G)))) . z = 'not' (FALSE '&' ((All ((a 'imp' ('not' b)),PA,G)) . z)) by A1, BVFUNC_2:def 9
.= 'not' FALSE by MARGREL1:12
.= TRUE by MARGREL1:11 ;
:: thesis: verum

end;

end;