let Y be non empty set ; :: thesis: for G being Subset of (PARTITIONS Y)
for a, u being Function of Y,BOOLEAN
for PA being a_partition of Y st u is_independent_of PA,G holds
Ex ((u 'imp' a),PA,G) '<' u 'imp' (Ex (a,PA,G))
let G be Subset of (PARTITIONS Y); :: thesis: for a, u being Function of Y,BOOLEAN
for PA being a_partition of Y st u is_independent_of PA,G holds
Ex ((u 'imp' a),PA,G) '<' u 'imp' (Ex (a,PA,G))
let a, u be Function of Y,BOOLEAN; :: thesis: for PA being a_partition of Y st u is_independent_of PA,G holds
Ex ((u 'imp' a),PA,G) '<' u 'imp' (Ex (a,PA,G))
let PA be a_partition of Y; :: thesis: ( u is_independent_of PA,G implies Ex ((u 'imp' a),PA,G) '<' u 'imp' (Ex (a,PA,G)) )
assume u is_independent_of PA,G ; :: thesis: Ex ((u 'imp' a),PA,G) '<' u 'imp' (Ex (a,PA,G))
then A1: u is_dependent_of CompF (PA,G) by BVFUNC_2:def 8;
let z be Element of Y; :: according to BVFUNC_1:def 12 :: thesis: ( not (Ex ((u 'imp' a),PA,G)) . z = TRUE or (u 'imp' (Ex (a,PA,G))) . z = TRUE )
A2: ( z in EqClass (z,(CompF (PA,G))) & EqClass (z,(CompF (PA,G))) in CompF (PA,G) ) by EQREL_1:def 6;
assume A3: (Ex ((u 'imp' a),PA,G)) . z = TRUE ; :: thesis: (u 'imp' (Ex (a,PA,G))) . z = TRUE

now :: thesis: ex x being Element of Y st
( x in EqClass (z,(CompF (PA,G))) & (u 'imp' a) . x = TRUE )

assume for x being Element of Y holds
( not x in EqClass (z,(CompF (PA,G))) or not (u 'imp' a) . x = TRUE ) ; :: thesis: contradiction
then (B_SUP ((u 'imp' a),(CompF (PA,G)))) . z = FALSE by BVFUNC_1:def 17;
hence contradiction by A3, BVFUNC_2:def 10; :: thesis: verum

end;

then consider x1 being Element of Y such that
A4: x1 in EqClass (z,(CompF (PA,G))) and
A5: (u 'imp' a) . x1 = TRUE ;
A6: ('not' (u . x1)) 'or' (a . x1) = TRUE by A5, BVFUNC_1:def 8;
A7: ( 'not' (u . x1) = TRUE or 'not' (u . x1) = FALSE ) by XBOOLEAN:def 3;

per cases ( 'not' (u . x1) = TRUE or a . x1 = TRUE ) by A6, A7, BINARITH:3;

suppose A8: 'not' (u . x1) = TRUE ; :: thesis: (u 'imp' (Ex (a,PA,G))) . z = TRUE

u . x1 = u . z by A1, A4, A2;
then u . z = FALSE by A8, MARGREL1:11;
hence (u 'imp' (Ex (a,PA,G))) . z = ('not' FALSE) 'or' ((Ex (a,PA,G)) . z) by BVFUNC_1:def 8
.= TRUE 'or' ((Ex (a,PA,G)) . z) by MARGREL1:11
.= TRUE by BINARITH:10 ;
:: thesis: verum

end;

suppose a . x1 = TRUE ; :: thesis: (u 'imp' (Ex (a,PA,G))) . z = TRUE

then (B_SUP (a,(CompF (PA,G)))) . z = TRUE by A4, BVFUNC_1:def 17;
then (Ex (a,PA,G)) . z = TRUE by BVFUNC_2:def 10;
hence (u 'imp' (Ex (a,PA,G))) . z = ('not' (u . z)) 'or' TRUE by BVFUNC_1:def 8
.= TRUE by BINARITH:10 ;
:: thesis: verum

end;

end;