let Y be non empty set ; :: thesis: for G being Subset of (PARTITIONS Y)
for a, u being Function of Y,BOOLEAN
for PA being a_partition of Y st u is_independent_of PA,G holds
All ((u 'or' a),PA,G) = u 'or' (All (a,PA,G))
let G be Subset of (PARTITIONS Y); :: thesis: for a, u being Function of Y,BOOLEAN
for PA being a_partition of Y st u is_independent_of PA,G holds
All ((u 'or' a),PA,G) = u 'or' (All (a,PA,G))
let a, u be Function of Y,BOOLEAN; :: thesis: for PA being a_partition of Y st u is_independent_of PA,G holds
All ((u 'or' a),PA,G) = u 'or' (All (a,PA,G))
let PA be a_partition of Y; :: thesis: ( u is_independent_of PA,G implies All ((u 'or' a),PA,G) = u 'or' (All (a,PA,G)) )
assume A1: u is_independent_of PA,G ; :: thesis: All ((u 'or' a),PA,G) = u 'or' (All (a,PA,G))
let z be Element of Y; :: according to FUNCT_2:def 8 :: thesis: (All ((u 'or' a),PA,G)) . z = (u 'or' (All (a,PA,G))) . z
A2: (u 'or' (B_INF (a,(CompF (PA,G))))) . z = (u . z) 'or' ((B_INF (a,(CompF (PA,G)))) . z) by BVFUNC_1:def 4;

per cases ( for x being Element of Y st x in EqClass (z,(CompF (PA,G))) holds
a . x = TRUE or ( ex x being Element of Y st
( x in EqClass (z,(CompF (PA,G))) & not a . x = TRUE ) & ( for x being Element of Y st x in EqClass (z,(CompF (PA,G))) holds
u . x = TRUE ) ) or ( ex x being Element of Y st
( x in EqClass (z,(CompF (PA,G))) & not a . x = TRUE ) & ex x being Element of Y st
( x in EqClass (z,(CompF (PA,G))) & not u . x = TRUE ) ) ) ;

suppose A3: for x being Element of Y st x in EqClass (z,(CompF (PA,G))) holds
a . x = TRUE ; :: thesis: (All ((u 'or' a),PA,G)) . z = (u 'or' (All (a,PA,G))) . z

A4: for x being Element of Y st x in EqClass (z,(CompF (PA,G))) holds
(u 'or' a) . x = TRUE

proof

let x be Element of Y; :: thesis: ( x in EqClass (z,(CompF (PA,G))) implies (u 'or' a) . x = TRUE )
assume A5: x in EqClass (z,(CompF (PA,G))) ; :: thesis: (u 'or' a) . x = TRUE
(u 'or' a) . x = (u . x) 'or' (a . x) by BVFUNC_1:def 4
.= (u . x) 'or' TRUE by A3, A5
.= TRUE by BINARITH:10 ;
hence (u 'or' a) . x = TRUE ; :: thesis: verum

end;

(B_INF (a,(CompF (PA,G)))) . z = TRUE by A3, BVFUNC_1:def 16;
then (u 'or' (B_INF (a,(CompF (PA,G))))) . z = TRUE by A2, BINARITH:10;
hence (All ((u 'or' a),PA,G)) . z = (u 'or' (All (a,PA,G))) . z by A4, BVFUNC_1:def 16; :: thesis: verum

end;

suppose A6: ( ex x being Element of Y st
( x in EqClass (z,(CompF (PA,G))) & not a . x = TRUE ) & ( for x being Element of Y st x in EqClass (z,(CompF (PA,G))) holds
u . x = TRUE ) ) ; :: thesis: (All ((u 'or' a),PA,G)) . z = (u 'or' (All (a,PA,G))) . z

A7: for x being Element of Y st x in EqClass (z,(CompF (PA,G))) holds
(u 'or' a) . x = TRUE

proof

let x be Element of Y; :: thesis: ( x in EqClass (z,(CompF (PA,G))) implies (u 'or' a) . x = TRUE )
assume A8: x in EqClass (z,(CompF (PA,G))) ; :: thesis: (u 'or' a) . x = TRUE
(u 'or' a) . x = (u . x) 'or' (a . x) by BVFUNC_1:def 4
.= TRUE 'or' (a . x) by A6, A8
.= TRUE by BINARITH:10 ;
hence (u 'or' a) . x = TRUE ; :: thesis: verum

end;

(u 'or' (B_INF (a,(CompF (PA,G))))) . z = TRUE 'or' ((B_INF (a,(CompF (PA,G)))) . z) by A2, A6, EQREL_1:def 6;
then (u 'or' (B_INF (a,(CompF (PA,G))))) . z = TRUE by BINARITH:10;
hence (All ((u 'or' a),PA,G)) . z = (u 'or' (All (a,PA,G))) . z by A7, BVFUNC_1:def 16; :: thesis: verum

end;

suppose A9: ( ex x being Element of Y st
( x in EqClass (z,(CompF (PA,G))) & not a . x = TRUE ) & ex x being Element of Y st
( x in EqClass (z,(CompF (PA,G))) & not u . x = TRUE ) ) ; :: thesis: (All ((u 'or' a),PA,G)) . z = (u 'or' (All (a,PA,G))) . z

then consider x2 being Element of Y such that
A10: x2 in EqClass (z,(CompF (PA,G))) and
A11: u . x2 <> TRUE ;
consider x1 being Element of Y such that
A12: x1 in EqClass (z,(CompF (PA,G))) and
A13: a . x1 <> TRUE by A9;
u . x1 = u . x2 by A1, A12, A10, BVFUNC_1:def 15;
then A14: u . x1 = FALSE by A11, XBOOLEAN:def 3;
A15: (B_INF (a,(CompF (PA,G)))) . z = FALSE by A9, BVFUNC_1:def 16;
z in EqClass (z,(CompF (PA,G))) by EQREL_1:def 6;
then A16: u . x1 = u . z by A1, A12, BVFUNC_1:def 15;
a . x1 = FALSE by A13, XBOOLEAN:def 3;
then (u 'or' a) . x1 = FALSE 'or' FALSE by A14, BVFUNC_1:def 4;
hence (All ((u 'or' a),PA,G)) . z = (u 'or' (All (a,PA,G))) . z by A2, A15, A12, A14, A16, BVFUNC_1:def 16; :: thesis: verum

end;

end;