let X be BCI-algebra; :: thesis: for I being Ideal of X holds
( I is p-ideal of X iff for x, y, z being Element of X st (x \ z) \ (y \ z) in I holds
x \ y in I )
let I be Ideal of X; :: thesis: ( I is p-ideal of X iff for x, y, z being Element of X st (x \ z) \ (y \ z) in I holds
x \ y in I )
thus ( I is p-ideal of X implies for x, y, z being Element of X st (x \ z) \ (y \ z) in I holds
x \ y in I ) :: thesis: ( ( for x, y, z being Element of X st (x \ z) \ (y \ z) in I holds
x \ y in I ) implies I is p-ideal of X )

proof

assume A1: I is p-ideal of X ; :: thesis: for x, y, z being Element of X st (x \ z) \ (y \ z) in I holds
x \ y in I
let x, y, z be Element of X; :: thesis: ( (x \ z) \ (y \ z) in I implies x \ y in I )
assume A2: (x \ z) \ (y \ z) in I ; :: thesis: x \ y in I
((x \ z) \ (y \ z)) \ (x \ y) = 0. X by BCIALG_1:def 3;
then (x \ z) \ (y \ z) <= x \ y ;
hence x \ y in I by A1, A2, Th21; :: thesis: verum

end;

assume A3: for x, y, z being Element of X st (x \ z) \ (y \ z) in I holds
x \ y in I ; :: thesis: I is p-ideal of X
A4: for x, y, z being Element of X st (x \ z) \ (y \ z) in I & y in I holds
x in I

proof

let x, y, z be Element of X; :: thesis: ( (x \ z) \ (y \ z) in I & y in I implies x in I )
assume that
A5: (x \ z) \ (y \ z) in I and
A6: y in I ; :: thesis: x in I
x \ y in I by A3, A5;
hence x in I by A6, BCIALG_1:def 18; :: thesis: verum

end;

0. X in I by BCIALG_1:def 18;
hence I is p-ideal of X by A4, Def5; :: thesis: verum