let X be BCI-algebra; :: thesis: for x, y being Element of X
for n being Nat holds (((x,(x \ y)) to_power n),(y \ x)) to_power n <= x
let x, y be Element of X; :: thesis: for n being Nat holds (((x,(x \ y)) to_power n),(y \ x)) to_power n <= x
let n be Nat; :: thesis: (((x,(x \ y)) to_power n),(y \ x)) to_power n <= x
defpred S₁[ set ] means for m being Nat st m = $1 & m <= n holds
(((x,(x \ y)) to_power m),(y \ x)) to_power m <= x;
A1: for k being Nat st S₁[k] holds
S₁[k + 1]

proof

let k be Nat; :: thesis: ( S₁[k] implies S₁[k + 1] )
assume A2: for m being Nat st m = k & m <= n holds
(((x,(x \ y)) to_power m),(y \ x)) to_power m <= x ; :: thesis: S₁[k + 1]
let m be Nat; :: thesis: ( m = k + 1 & m <= n implies (((x,(x \ y)) to_power m),(y \ x)) to_power m <= x )
assume that
A3: m = k + 1 and
A4: m <= n ; :: thesis: (((x,(x \ y)) to_power m),(y \ x)) to_power m <= x
k <= n by A3, A4, NAT_1:13;
then (((x,(x \ y)) to_power k),(y \ x)) to_power k <= x by A2;
then ((((x,(x \ y)) to_power k),(y \ x)) to_power k) \ x = 0. X ;
then (((((x,(x \ y)) to_power k) \ x),(y \ x)) to_power k) \ (y \ x) = (y \ x) ` by Th7;
then (((((x,(x \ y)) to_power k) \ x),(y \ x)) to_power (k + 1)) \ (x \ y) = ((y \ x) `) \ (x \ y) by Th4;
then (((((x,(x \ y)) to_power k) \ x) \ (x \ y)),(y \ x)) to_power (k + 1) = ((y \ x) `) \ (x \ y) by Th7;
then (((((x,(x \ y)) to_power k) \ (x \ y)) \ x),(y \ x)) to_power (k + 1) = ((y \ x) `) \ (x \ y) by BCIALG_1:7;
then ((((x,(x \ y)) to_power (k + 1)) \ x),(y \ x)) to_power (k + 1) = ((y \ x) `) \ (x \ y) by Th4;
then ((((x,(x \ y)) to_power (k + 1)) \ x),(y \ x)) to_power (k + 1) = ((y \ y) \ (y \ x)) \ (x \ y) by BCIALG_1:def 5;
then ((((x,(x \ y)) to_power (k + 1)) \ x),(y \ x)) to_power (k + 1) = 0. X by BCIALG_1:1;
then ((((x,(x \ y)) to_power (k + 1)),(y \ x)) to_power (k + 1)) \ x = 0. X by Th7;
hence (((x,(x \ y)) to_power m),(y \ x)) to_power m <= x by A3; :: thesis: verum

end;

x \ x = 0. X by BCIALG_1:def 5;
then x <= x ;
then (x,(y \ x)) to_power 0 <= x by Th1;
then A5: S₁[ 0 ] by Th1;
for n being Nat holds S₁[n] from NAT_1:sch 2(A5, A1);
hence (((x,(x \ y)) to_power n),(y \ x)) to_power n <= x ; :: thesis: verum