let x, y be Element of REAL+ ; :: thesis: ( x in RAT+ & y in RAT+ implies ex x9, y9 being Element of RAT+ st
( x = x9 & y = y9 & x *' y = x9 *' y9 ) )
assume that
A1: x in RAT+ and
A2: y in RAT+ ; :: thesis: ex x9, y9 being Element of RAT+ st
( x = x9 & y = y9 & x *' y = x9 *' y9 )

per cases ( x = {} or y = {} or ( y <> {} & x <> {} ) ) ;

suppose A3: x = {} ; :: thesis: ex x9, y9 being Element of RAT+ st
( x = x9 & y = y9 & x *' y = x9 *' y9 )

reconsider y9 = y as Element of RAT+ by A2;
take {} ; :: thesis: ex y9 being Element of RAT+ st
( x = {} & y = y9 & x *' y = {} *' y9 )
take y9 ; :: thesis: ( x = {} & y = y9 & x *' y = {} *' y9 )
thus x = {} by A3; :: thesis: ( y = y9 & x *' y = {} *' y9 )
thus y = y9 ; :: thesis: x *' y = {} *' y9
thus x *' y = {} by A3, Th4
.= {} *' y9 by ARYTM_3:48 ; :: thesis: verum

end;

suppose A4: y = {} ; :: thesis: ex x9, y9 being Element of RAT+ st
( x = x9 & y = y9 & x *' y = x9 *' y9 )

reconsider x9 = x as Element of RAT+ by A1;
take x9 ; :: thesis: ex y9 being Element of RAT+ st
( x = x9 & y = y9 & x *' y = x9 *' y9 )
take {} ; :: thesis: ( x = x9 & y = {} & x *' y = x9 *' {} )
thus x = x9 ; :: thesis: ( y = {} & x *' y = x9 *' {} )
thus y = {} by A4; :: thesis: x *' y = x9 *' {}
thus x *' y = {} by A4, Th4
.= x9 *' {} by ARYTM_3:48 ; :: thesis: verum

end;

suppose that y <> {} and
A5: x <> {} ; :: thesis: ex x9, y9 being Element of RAT+ st
( x = x9 & y = y9 & x *' y = x9 *' y9 )

consider y9 being Element of RAT+ such that
A6: y = y9 and
A7: DEDEKIND_CUT y = { s where s is Element of RAT+ : s < y9 } by A2, Def3;
set A = DEDEKIND_CUT x;
set B = DEDEKIND_CUT y;
consider x9 being Element of RAT+ such that
A8: x = x9 and
A9: DEDEKIND_CUT x = { s where s is Element of RAT+ : s < x9 } by A1, Def3;
A10: for s being Element of RAT+ holds
( s in (DEDEKIND_CUT x) *' (DEDEKIND_CUT y) iff s < x9 *' y9 )

proof

let s2 be Element of RAT+ ; :: thesis: ( s2 in (DEDEKIND_CUT x) *' (DEDEKIND_CUT y) iff s2 < x9 *' y9 )
thus ( s2 in (DEDEKIND_CUT x) *' (DEDEKIND_CUT y) implies s2 < x9 *' y9 ) :: thesis: ( s2 < x9 *' y9 implies s2 in (DEDEKIND_CUT x) *' (DEDEKIND_CUT y) )

proof

assume s2 in (DEDEKIND_CUT x) *' (DEDEKIND_CUT y) ; :: thesis: s2 < x9 *' y9
then consider r1, s1 being Element of RAT+ such that
A11: s2 = r1 *' s1 and
A12: r1 in DEDEKIND_CUT x and
A13: s1 in DEDEKIND_CUT y ;
ex s being Element of RAT+ st
( s = r1 & s < x9 ) by A9, A12;
then A14: r1 *' s1 <=' x9 *' s1 by ARYTM_3:82;
A15: ex s being Element of RAT+ st
( s = s1 & s < y9 ) by A7, A13;
then s1 <> y9 ;
then A16: x9 *' s1 <> x9 *' y9 by A5, A8, ARYTM_3:56;
x9 *' s1 <=' x9 *' y9 by A15, ARYTM_3:82;
then x9 *' s1 < x9 *' y9 by A16, ARYTM_3:68;
hence s2 < x9 *' y9 by A11, A14, ARYTM_3:69; :: thesis: verum

end;

assume A17: s2 < x9 *' y9 ; :: thesis: s2 in (DEDEKIND_CUT x) *' (DEDEKIND_CUT y)
then consider t0 being Element of RAT+ such that
A18: s2 = x9 *' t0 and
A19: t0 <=' y9 by ARYTM_3:79;
t0 <> y9 by A17, A18;
then t0 < y9 by A19, ARYTM_3:68;
then consider t1 being Element of RAT+ such that
A20: t0 < t1 and
A21: t1 < y9 by ARYTM_3:93;
s2 <=' t1 *' x9 by A18, A20, ARYTM_3:82;
then consider t2 being Element of RAT+ such that
A22: s2 = t1 *' t2 and
A23: t2 <=' x9 by ARYTM_3:79;

now :: thesis: not t2 = x9

assume t2 = x9 ; :: thesis: contradiction
then t0 = t1 by A5, A8, A18, A22, ARYTM_3:56;
hence contradiction by A20; :: thesis: verum

end;

then t2 < x9 by A23, ARYTM_3:68;
then A24: t2 in DEDEKIND_CUT x by A9;
t1 in DEDEKIND_CUT y by A7, A21;
hence s2 in (DEDEKIND_CUT x) *' (DEDEKIND_CUT y) by A22, A24; :: thesis: verum

end;

then consider r being Element of RAT+ such that
A25: GLUED ((DEDEKIND_CUT x) *' (DEDEKIND_CUT y)) = r and
A26: for s being Element of RAT+ holds
( s in (DEDEKIND_CUT x) *' (DEDEKIND_CUT y) iff s < r ) by Def4;
take x9 ; :: thesis: ex y9 being Element of RAT+ st
( x = x9 & y = y9 & x *' y = x9 *' y9 )
take y9 ; :: thesis: ( x = x9 & y = y9 & x *' y = x9 *' y9 )
thus ( x = x9 & y = y9 ) by A8, A6; :: thesis: x *' y = x9 *' y9
for s being Element of RAT+ holds
( s < x9 *' y9 iff s < r ) by A10, A26;
hence x *' y = x9 *' y9 by A25, Lm6; :: thesis: verum

end;

end;