let x, y be object ; :: thesis: for p being XFinSequence holds
( p = <%x,y%> iff ( len p = 2 & p . 0 = x & p . 1 = y ) )
let p be XFinSequence; :: thesis: ( p = <%x,y%> iff ( len p = 2 & p . 0 = x & p . 1 = y ) )
thus ( p = <%x,y%> implies ( len p = 2 & p . 0 = x & p . 1 = y ) ) :: thesis: ( len p = 2 & p . 0 = x & p . 1 = y implies p = <%x,y%> )

proof

assume A1: p = <%x,y%> ; :: thesis: ( len p = 2 & p . 0 = x & p . 1 = y )
hence len p = (len <%x%>) + (len <%y%>) by Def3
.= 1 + (len <%y%>) by Th30
.= 1 + 1 by Th30
.= 2 ;
:: thesis: ( p . 0 = x & p . 1 = y )
0 in {0} by TARSKI:def 1;
then A3: 0 in dom <%y%> ;
0 in dom <%x%> by TARSKI:def 1;
hence p . 0 = <%x%> . 0 by A1, Def3
.= x ;
:: thesis: p . 1 = y
thus p . 1 = (<%x%> ^ <%y%>) . ((len <%x%>) + 0) by A1, Th30
.= <%y%> . 0 by A3, Def3
.= y ; :: thesis: verum

end;

assume that
A4: len p = 2 and
A5: p . 0 = x and
A6: p . 1 = y ; :: thesis: p = <%x,y%>
A7: for k being Nat st k in dom <%y%> holds
p . ((len <%x%>) + k) = <%y%> . k

proof

let k be Nat; :: thesis: ( k in dom <%y%> implies p . ((len <%x%>) + k) = <%y%> . k )
assume a8: k in dom <%y%> ; :: thesis: p . ((len <%x%>) + k) = <%y%> . k
thus p . ((len <%x%>) + k) = p . (1 + k) by Th30
.= p . (1 + 0) by a8, TARSKI:def 1
.= <%y%> . 0 by A6
.= <%y%> . k by a8, TARSKI:def 1 ; :: thesis: verum

end;

A9: for k being Nat st k in dom <%x%> holds
p . k = <%x%> . k

proof

let k be Nat; :: thesis: ( k in dom <%x%> implies p . k = <%x%> . k )
assume k in dom <%x%> ; :: thesis: p . k = <%x%> . k
then k = 0 by TARSKI:def 1;
hence p . k = <%x%> . k by A5; :: thesis: verum

end;

dom p = 1 + 1 by A4
.= (len <%x%>) + 1 by Th30
.= (len <%x%>) + (len <%y%>) by Th30 ;
hence p = <%x,y%> by A9, A7, Def3; :: thesis: verum